pzlaqsy.f

Go to the documentation of this file.

      SUBROUTINE pzlaqsy( UPLO, N, A, IA, JA, DESCA, SR, SC, SCOND,
     $                    AMAX, EQUED )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          EQUED, UPLO
      INTEGER            IA, JA, N
      DOUBLE PRECISION   AMAX, SCOND
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      DOUBLE PRECISION   SC( * ), SR( * )
      COMPLEX*16         A( * )
*     ..
*
*  Purpose
*  =======
*
*  PZLAQSY equilibrates a symmetric distributed matrix
*  sub( A ) = A(IA:IA+N-1,JA:JA+N-1) using the scaling factors in the
*  vectors SR and SC.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          Specifies whether the upper or lower triangular part of the
*          symmetric distributed matrix sub( A ) is to be referenced:
*             = 'U':  Upper triangular
*             = 'L':  Lower triangular
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (input/output) COMPLEX*16 pointer into the local
*          memory to an array of local dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, the local pieces of the distributed symmetric
*          matrix sub( A ). If UPLO = 'U', the leading N-by-N upper
*          triangular part of sub( A ) contains the upper triangular
*          part of the matrix, and the strictly lower triangular part
*          of sub( A ) is not referenced.  If UPLO = 'L', the leading
*          N-by-N lower triangular part of sub( A ) contains the lower
*          triangular part of the matrix, and the strictly upper trian-
*          gular part of sub( A ) is not referenced.
*          On exit, if EQUED = 'Y', the equilibrated matrix:
*              diag(SR(IA:IA+N-1)) * sub( A ) * diag(SC(JA:JA+N-1)).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  SR      (local input) DOUBLE PRECISION array, dimension LOCr(M_A)
*          The scale factors for A(IA:IA+M-1,JA:JA+N-1). SR is aligned
*          with the distributed matrix A, and replicated across every
*          process column. SR is tied to the distributed matrix A.
*
*  SC      (local input) DOUBLE PRECISION array, dimension LOCc(N_A)
*          The scale factors for sub( A ). SC is aligned with the dis-
*          tributed matrix A, and replicated down every process row.
*          SC is tied to the distributed matrix A.
*
*  SCOND   (global input) DOUBLE PRECISION
*          Ratio of the smallest SR(i) (respectively SC(j)) to the
*          largest SR(i) (respectively SC(j)), with IA <= i <= IA+N-1
*          and JA <= j <= JA+N-1.
*
*  AMAX    (global input) DOUBLE PRECISION
*          Absolute value of the largest distributed submatrix entry.
*
*  EQUED   (output) CHARACTER*1
*          Specifies whether or not equilibration was done.
*          = 'N':  No equilibration.
*          = 'Y':  Equilibration was done, i.e., sub( A ) has been re-
*                  placed by:
*                  diag(SR(IA:IA+N-1)) * sub( A ) * diag(SC(JA:JA+N-1)).
*
*  Internal Parameters
*  ===================
*
*  THRESH is a threshold value used to decide if scaling should be done
*  based on the ratio of the scaling factors.  If SCOND < THRESH,
*  scaling is done.
*
*  LARGE and SMALL are threshold values used to decide if scaling should
*  be done based on the absolute size of the largest matrix element.
*  If AMAX > LARGE or AMAX < SMALL, scaling is done.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ONE, THRESH
      parameter( one = 1.0d+0, thresh = 0.1d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            IACOL, IAROW, ICTXT, II, IIA, IOFFA, IROFF, J,
     $                   jb, jj, jja, jn, kk, lda, ll, mycol, myrow, np,
     $                   npcol, nprow
      DOUBLE PRECISION   CJ, LARGE, SMALL
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, infog2l
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL, NUMROC
      DOUBLE PRECISION   PDLAMCH
      EXTERNAL           iceil, lsame, numroc, pdlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min, mod
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         equed = 'N'
         RETURN
      END IF
*
*     Get grid parameters and compute local indexes
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
      lda = desca( lld_ )
*
*     Initialize LARGE and SMALL.
*
      small = pdlamch( ictxt, 'Safe minimum' ) /
     $        pdlamch( ictxt, 'Precision' )
      large = one / small
*
      IF( scond.GE.thresh .AND. amax.GE.small .AND. amax.LE.large ) THEN
*
*        No equilibration
*
         equed = 'N'
*
      ELSE
*
         ii = iia
         jj = jja
         jn = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+n-1 )
         jb = jn-ja+1
*
*        Replace A by diag(S) * A * diag(S).
*
         IF( lsame( uplo, 'U' ) ) THEN
*
*           Upper triangle of A(IA:IA+N-1,JA:JA+N-1) is stored.
*           Handle first block separately
*
            ioffa = (jj-1)*lda
            IF( mycol.EQ.iacol ) THEN
               IF( myrow.EQ.iarow ) THEN
                  DO 20 ll = jj, jj + jb -1
                     cj = sc( ll )
                     DO 10 kk = iia, ii+ll-jj+1
                        a( ioffa + kk ) = cj*sr( kk )*a( ioffa + kk )
   10                CONTINUE
                     ioffa = ioffa + lda
   20             CONTINUE
               ELSE
                  ioffa = ioffa + jb*lda
               END IF
               jj = jj + jb
            END IF
*
            IF( myrow.EQ.iarow )
     $         ii = ii + jb
            iarow = mod( iarow+1, nprow )
            iacol = mod( iacol+1, npcol )
*
*           Loop over remaining block of columns
*
            DO 70 j = jn+1, ja+n-1, desca( nb_ )
               jb = min( ja+n-j, desca( nb_ ) )
*
               IF( mycol.EQ.iacol ) THEN
                  IF( myrow.EQ.iarow ) THEN
                     DO 40 ll = jj, jj + jb -1
                        cj = sc( ll )
                        DO 30 kk = iia, ii+ll-jj+1
                           a( ioffa + kk ) = cj*sr( kk )*a( ioffa + kk )
   30                   CONTINUE
                        ioffa = ioffa + lda
   40                CONTINUE
                  ELSE
                     DO 60 ll = jj, jj + jb -1
                        cj = sc( ll )
                        DO 50 kk = iia, ii-1
                           a( ioffa + kk ) = cj*sr( kk )*a( ioffa + kk )
   50                   CONTINUE
                        ioffa = ioffa + lda
   60                CONTINUE
                  END IF
                  jj = jj + jb
               END IF
*
               IF( myrow.EQ.iarow )
     $            ii = ii + jb
               iarow = mod( iarow+1, nprow )
               iacol = mod( iacol+1, npcol )
*
   70       CONTINUE
*
         ELSE
*
*           Lower triangle of A(IA:IA+N-1,JA:JA+N-1) is stored.
*           Handle first block separately
*
            iroff = mod( ia-1, desca( mb_ ) )
            np = numroc( n+iroff, desca( mb_ ), myrow, iarow, nprow )
            IF( myrow.EQ.iarow )
     $         np = np-iroff
*
            ioffa = (jj-1)*lda
            IF( mycol.EQ.iacol ) THEN
               IF( myrow.EQ.iarow ) THEN
                  DO 90 ll = jj, jj + jb -1
                     cj = sc( ll )
                     DO 80 kk = ii+ll-jj, iia+np-1
                        a( ioffa + kk ) = cj*sr( kk )*a( ioffa + kk )
   80                CONTINUE
                     ioffa = ioffa + lda
   90             CONTINUE
               ELSE
                  DO 110 ll = jj, jj + jb -1
                     cj = sc( ll )
                     DO 100 kk = ii, iia+np-1
                        a( ioffa + kk ) = cj*sr( kk )*a( ioffa + kk )
  100                CONTINUE
                     ioffa = ioffa + lda
  110             CONTINUE
               END IF
               jj = jj + jb
            END IF
*
            IF( myrow.EQ.iarow )
     $         ii = ii + jb
            iarow = mod( iarow+1, nprow )
            iacol = mod( iacol+1, npcol )
*
*           Loop over remaining block of columns
*
            DO 160 j = jn+1, ja+n-1, desca( nb_ )
               jb = min( ja+n-j, desca( nb_ ) )
*
               IF( mycol.EQ.iacol ) THEN
                  IF( myrow.EQ.iarow ) THEN
                     DO 130 ll = jj, jj + jb -1
                        cj = sc( ll )
                        DO 120 kk = ii+ll-jj, iia+np-1
                           a( ioffa + kk ) = cj*sr( kk )*a( ioffa + kk )
  120                   CONTINUE
                        ioffa = ioffa + lda
  130                CONTINUE
                  ELSE
                     DO 150 ll = jj, jj + jb -1
                        cj = sc( ll )
                        DO 140 kk = ii, iia+np-1
                           a( ioffa + kk ) = cj*sr( kk )*a( ioffa + kk )
  140                   CONTINUE
                        ioffa = ioffa + lda
  150                CONTINUE
                  END IF
                  jj = jj + jb
               END IF
*
               IF( myrow.EQ.iarow )
     $            ii = ii + jb
               iarow = mod( iarow+1, nprow )
               iacol = mod( iacol+1, npcol )
*
  160       CONTINUE
*
         END IF
*
         equed = 'Y'
*
      END IF
*
      RETURN
*
*     End of PZLAQSY
*
      END