pdsepchk()

subroutine pdsepchk	(	integer	ms,
		integer	nv,
		double precision, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		double precision	epsnorma,
		double precision	thresh,
		double precision, dimension( * )	q,
		integer	iq,
		integer	jq,
		integer, dimension( * )	descq,
		double precision, dimension( * )	c,
		integer	ic,
		integer	jc,
		integer, dimension( * )	descc,
		double precision, dimension( * )	w,
		double precision, dimension( * )	work,
		integer	lwork,
		double precision	tstnrm,
		integer	result
	)

Definition at line 3 of file pdsepchk.f.

*
*  -- ScaLAPACK routine (version 2.0.2) --
*     Univ. of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver
*     May 1 2012
*
*     .. Scalar Arguments ..
      INTEGER            IA, IC, IQ, JA, JC, JQ, LWORK, MS, NV, RESULT
      DOUBLE PRECISION   EPSNORMA, THRESH, TSTNRM
*     ..
*     .. Array Arguments ..
*
      INTEGER            DESCA( * ), DESCC( * ), DESCQ( * )
      DOUBLE PRECISION   A( * ), C( * ), Q( * ), W( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  Compute |AQ- QL| / (EPSNORMA * N)
*  where EPSNORMA = (abstol + eps)*norm(A) when called by pdsqpsubtst.
*
*  Notes
*  =====
*
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*
*  Arguments
*  =========
*
*     MP = number of local rows in A, C and Q
*     MQ = number of local columns in A
*     NQ = number of local columns in C and Q
*
*  MS      (global input) INTEGER
*          Matrix size.
*          The number of global rows in A, C and Q
*          Also, the number of global columns in A
*
*  NV      (global input) INTEGER
*          Number of eigenvectors
*          The number of global columns in C and Q.
*
*  A       (local input) DOUBLE PRECISION pointer to an
*          array in local memory of dimension (LLD_A, LOCc(JA+N-1)).
*          This array contains the local pieces of the MS-by-MS
*          distributed test matrix A
*
*  IA      (global input) INTEGER
*          A's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JA      (global input) INTEGER
*          A's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  EPSNORMA (input) DOUBLE PRECISION
*          abstol + eps * inf.norm(A)
*          Abstol is absolute tolerence for the eigenvalues and is set
*          in the calling routines, pdsepsubtst and pdsqpsubtst.
*
*  THRESH  (input) DOUBLE PRECISION
*          A test will count as "failed" if the "error", computed as
*          described below, exceeds THRESH.  Note that the error
*          is scaled to be O(1), so THRESH should be a reasonably
*          small multiple of 1, e.g., 10 or 100.  In particular,
*          it should not depend on the precision (single vs. double)
*          or the size of the matrix.  It must be at least zero.
*
*  Q       (local input) DOUBLE PRECISION array
*          global dimension (MS, NV), local dimension (DESCA(DLEN_), NQ)
*
*          Contains the eigenvectors as computed by PDSYEVX
*
*  IQ      (global input) INTEGER
*          Q's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JQ      (global input) INTEGER
*          Q's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCQ   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix Q.
*
*  C       (local workspace) DOUBLE PRECISION array,
*          global dimension (NV, NV), local dimension (DESCA(DLEN_), MQ)
*
*          Accumulator for computing AQ -QL
*
*  IC      (global input) INTEGER
*          C's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JC      (global input) INTEGER
*          C's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCC   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix C.
*
*  W       (global input) DOUBLE PRECISION array, dimension (NV)
*
*          Contains the computed eigenvalues
*
*  WORK    (local workspace) DOUBLE PRECISION array,
*                            dimension (LWORK)
*
*  LWORK   (local input) INTEGER
*          The length of the array WORK.
*          LWORK >= NUMROC( NV, DESCA( NB_ ), MYCOL, 0, NPCOL )
*
*  TSTNRM  (global output) DOUBLE PRECISION
*          |AQ- QL| / ( EPSNROMA * MS )
*
*  RESULT  (global output) INTEGER
*          0 if the test passes i.e.
*            |AQ -QL| / (abstol + eps * norm(A) ) <= n* THRESH
*          1 if the test fails  i.e.
*            |AQ -QL| / (abstol + eps * norm(A) ) > n * THRESH
*
*     .. Local Scalars ..
*
      INTEGER            INFO, J, LOCALCOL, MP, MYCOL, MYROW, NPCOL,
     $                   NPROW, NQ, PCOL
      DOUBLE PRECISION   NORM
*     ..
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   MB_, NB_, RSRC_, CSRC_, LLD_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ONE, NEGONE
      parameter( one = 1.0d+0, negone = -1.0d+0 )
*     ..
*     .. External Functions ..
      INTEGER            INDXG2L, INDXG2P, NUMROC
      DOUBLE PRECISION   PDLANGE
      EXTERNAL           indxg2l, indxg2p, numroc, pdlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, dlacpy, dscal, pdgemm,
     $                   pxerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*       This is just to keep ftnchek happy
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*
      result = 0
*
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
*
      info = 0
      CALL chk1mat( ms, 1, ms, 1, ia, ja, desca, 6, info )
      CALL chk1mat( ms, 1, nv, 2, iq, jq, descq, 12, info )
      CALL chk1mat( ms, 1, nv, 2, ic, jc, descc, 16, info )
*
      IF( info.EQ.0 ) THEN
*
         mp = numroc( ms, desca( mb_ ), myrow, 0, nprow )
         nq = numroc( nv, desca( nb_ ), mycol, 0, npcol )
*
         IF( iq.NE.1 ) THEN
            info = -10
         ELSE IF( jq.NE.1 ) THEN
            info = -11
         ELSE IF( ia.NE.1 ) THEN
            info = -4
         ELSE IF( ja.NE.1 ) THEN
            info = -5
         ELSE IF( ic.NE.1 ) THEN
            info = -14
         ELSE IF( jc.NE.1 ) THEN
            info = -15
         ELSE IF( lwork.LT.nq ) THEN
            info = -19
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( desca( ctxt_ ), 'PDSEPCHK', -info )
         RETURN
      END IF
*
*     C = Q * W
*
      CALL dlacpy( 'A', mp, nq, q, descq( lld_ ), c, descc( lld_ ) )
*
*
      DO 10 j = 1, nv
         pcol = indxg2p( j, descc( nb_ ), 0, 0, npcol )
         localcol = indxg2l( j, descc( nb_ ), 0, 0, npcol )
*
         IF( mycol.EQ.pcol ) THEN
            CALL dscal( mp, w( j ), c( ( localcol-1 )*descc( lld_ )+1 ),
     $                  1 )
         END IF
   10 CONTINUE
*
*
*     C = C - A * Q
*
      CALL pdgemm( 'N', 'N', ms, nv, ms, negone, a, 1, 1, desca, q, 1,
     $             1, descq, one, c, 1, 1, descc )
*
*     Compute the norm of C
*
*
      norm = pdlange( 'M', ms, nv, c, 1, 1, descc, work )
*
*
      tstnrm = norm / epsnorma / max( ms, 1 )
*
      IF( tstnrm.GT.thresh .OR. ( tstnrm-tstnrm.NE.0.0d0 ) ) THEN
         result = 1
      END IF
*
*
      RETURN
*
*     End of PDSEPCHK
*

Here is the call graph for this function:

Here is the caller graph for this function: