pdlagen()

subroutine pdlagen	(	logical	inplace,
		character*1	aform,
		character*1	diag,
		integer	offa,
		integer	m,
		integer	n,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		integer	iaseed,
		double precision, dimension( lda, * )	a,
		integer	lda
	)

Definition at line 508 of file pdblastim.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      LOGICAL            INPLACE
      CHARACTER*1        AFORM, DIAG
      INTEGER            IA, IASEED, JA, LDA, M, N, OFFA
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      DOUBLE PRECISION   A( LDA, * )
*     ..
*
*  Purpose
*  =======
*
*  PDLAGEN  generates  (or regenerates)  a  submatrix  sub( A ) denoting
*  A(IA:IA+M-1,JA:JA+N-1).
*
*  Notes
*  =====
*
*  A description  vector  is associated with each 2D block-cyclicly dis-
*  tributed matrix.  This  vector  stores  the  information  required to
*  establish the  mapping  between a  matrix entry and its corresponding
*  process and memory location.
*
*  In  the  following  comments,   the character _  should  be  read  as
*  "of  the  distributed  matrix".  Let  A  be a generic term for any 2D
*  block cyclicly distributed matrix.  Its description vector is DESCA:
*
*  NOTATION         STORED IN       EXPLANATION
*  ---------------- --------------- ------------------------------------
*  DTYPE_A (global) DESCA( DTYPE_ ) The descriptor type.
*  CTXT_A  (global) DESCA( CTXT_  ) The BLACS context handle, indicating
*                                   the NPROW x NPCOL BLACS process grid
*                                   A  is distributed over.  The context
*                                   itself  is  global,  but  the handle
*                                   (the integer value) may vary.
*  M_A     (global) DESCA( M_     ) The  number of rows in the distribu-
*                                   ted matrix A, M_A >= 0.
*  N_A     (global) DESCA( N_     ) The number of columns in the distri-
*                                   buted matrix A, N_A >= 0.
*  IMB_A   (global) DESCA( IMB_   ) The number of rows of the upper left
*                                   block of the matrix A, IMB_A > 0.
*  INB_A   (global) DESCA( INB_   ) The  number  of columns of the upper
*                                   left   block   of   the   matrix  A,
*                                   INB_A > 0.
*  MB_A    (global) DESCA( MB_    ) The blocking factor used to  distri-
*                                   bute the last  M_A-IMB_A rows of  A,
*                                   MB_A > 0.
*  NB_A    (global) DESCA( NB_    ) The blocking factor used to  distri-
*                                   bute the last  N_A-INB_A  columns of
*                                   A, NB_A > 0.
*  RSRC_A  (global) DESCA( RSRC_  ) The process row over which the first
*                                   row of the matrix  A is distributed,
*                                   NPROW > RSRC_A >= 0.
*  CSRC_A  (global) DESCA( CSRC_  ) The  process  column  over which the
*                                   first  column of  A  is distributed.
*                                   NPCOL > CSRC_A >= 0.
*  LLD_A   (local)  DESCA( LLD_   ) The  leading  dimension of the local
*                                   array  storing  the  local blocks of
*                                   the distributed matrix A,
*                                   IF( Lc( 1, N_A ) > 0 )
*                                      LLD_A >= MAX( 1, Lr( 1, M_A ) )
*                                   ELSE
*                                      LLD_A >= 1.
*
*  Let K be the number of  rows of a matrix A starting at the global in-
*  dex IA,i.e, A( IA:IA+K-1, : ). Lr( IA, K ) denotes the number of rows
*  that the process of row coordinate MYROW ( 0 <= MYROW < NPROW ) would
*  receive if these K rows were distributed over NPROW processes.  If  K
*  is the number of columns of a matrix  A  starting at the global index
*  JA, i.e, A( :, JA:JA+K-1, : ), Lc( JA, K ) denotes the number  of co-
*  lumns that the process MYCOL ( 0 <= MYCOL < NPCOL ) would  receive if
*  these K columns were distributed over NPCOL processes.
*
*  The values of Lr() and Lc() may be determined via a call to the func-
*  tion PB_NUMROC:
*  Lr( IA, K ) = PB_NUMROC( K, IA, IMB_A, MB_A, MYROW, RSRC_A, NPROW )
*  Lc( JA, K ) = PB_NUMROC( K, JA, INB_A, NB_A, MYCOL, CSRC_A, NPCOL )
*
*  Arguments
*  =========
*
*  INPLACE (global input) LOGICAL
*          On entry, INPLACE specifies if the matrix should be generated
*          in place or not. If INPLACE is .TRUE., the local random array
*          to be generated  will start in memory at the local memory lo-
*          cation A( 1, 1 ),  otherwise it will start at the local posi-
*          tion induced by IA and JA.
*
*  AFORM   (global input) CHARACTER*1
*          On entry, AFORM specifies the type of submatrix to be genera-
*          ted as follows:
*             AFORM = 'S', sub( A ) is a symmetric matrix,
*             AFORM = 'H', sub( A ) is a Hermitian matrix,
*             AFORM = 'T', sub( A ) is overrwritten  with  the transpose
*                          of what would normally be generated,
*             AFORM = 'C', sub( A ) is overwritten  with  the  conjugate
*                          transpose  of  what would normally be genera-
*                          ted.
*             AFORM = 'N', a random submatrix is generated.
*
*  DIAG    (global input) CHARACTER*1
*          On entry, DIAG specifies if the generated submatrix is diago-
*          nally dominant or not as follows:
*             DIAG = 'D' : sub( A ) is diagonally dominant,
*             DIAG = 'N' : sub( A ) is not diagonally dominant.
*
*  OFFA    (global input) INTEGER
*          On entry, OFFA  specifies  the  offdiagonal of the underlying
*          matrix A(1:DESCA(M_),1:DESCA(N_)) of interest when the subma-
*          trix is symmetric, Hermitian or diagonally dominant. OFFA = 0
*          specifies the main diagonal,  OFFA > 0  specifies a subdiago-
*          nal,  and OFFA < 0 specifies a superdiagonal (see further de-
*          tails).
*
*  M       (global input) INTEGER
*          On entry, M specifies the global number of matrix rows of the
*          submatrix sub( A ) to be generated. M must be at least zero.
*
*  N       (global input) INTEGER
*          On entry,  N specifies the global number of matrix columns of
*          the  submatrix  sub( A )  to be generated. N must be at least
*          zero.
*
*  IA      (global input) INTEGER
*          On entry, IA  specifies A's global row index, which points to
*          the beginning of the submatrix sub( A ).
*
*  JA      (global input) INTEGER
*          On entry, JA  specifies A's global column index, which points
*          to the beginning of the submatrix sub( A ).
*
*  DESCA   (global and local input) INTEGER array
*          On entry, DESCA  is an integer array of dimension DLEN_. This
*          is the array descriptor for the matrix A.
*
*  IASEED  (global input) INTEGER
*          On entry, IASEED  specifies  the  seed number to generate the
*          matrix A. IASEED must be at least zero.
*
*  A       (local output) DOUBLE PRECISION array
*          On entry, A is an array of dimension (LLD_A, Ka), where Ka is
*          at least Lc( 1, JA+N-1 ).  On  exit, this array  contains the
*          local entries of the randomly generated submatrix sub( A ).
*
*  LDA     (local input) INTEGER
*          On entry,  LDA  specifies  the local leading dimension of the
*          array A. When INPLACE is .FALSE., LDA is usually DESCA(LLD_).
*          This restriction is however not enforced, and this subroutine
*          requires only that LDA >= MAX( 1, Mp ) where
*
*          Mp = PB_NUMROC( M, IA, IMB_A, MB_A, MYROW, RSRC_A, NPROW ).
*
*          PB_NUMROC  is  a ScaLAPACK tool function; MYROW, MYCOL, NPROW
*          and NPCOL  can  be determined by calling the BLACS subroutine
*          BLACS_GRIDINFO.
*
*  Further Details
*  ===============
*
*  OFFD  is  tied  to  the matrix described by  DESCA, as opposed to the
*  piece that is currently  (re)generated.  This is a global information
*  independent from the distribution  parameters.  Below are examples of
*  the meaning of OFFD for a global 7 by 5 matrix:
*
*  ---------------------------------------------------------------------
*  OFFD   |  0 -1 -2 -3 -4         0 -1 -2 -3 -4          0 -1 -2 -3 -4
*  -------|-------------------------------------------------------------
*         |     | OFFD=-1          |   OFFD=0                 OFFD=2
*         |     V                  V
*  0      |  .  d  .  .  .      -> d  .  .  .  .          .  .  .  .  .
*  1      |  .  .  d  .  .         .  d  .  .  .          .  .  .  .  .
*  2      |  .  .  .  d  .         .  .  d  .  .       -> d  .  .  .  .
*  3      |  .  .  .  .  d         .  .  .  d  .          .  d  .  .  .
*  4      |  .  .  .  .  .         .  .  .  .  d          .  .  d  .  .
*  5      |  .  .  .  .  .         .  .  .  .  .          .  .  .  d  .
*  6      |  .  .  .  .  .         .  .  .  .  .          .  .  .  .  d
*  ---------------------------------------------------------------------
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D_INB, CSRC_, CTXT_, DLEN_,
     $                   DTYPE_, IMB_, INB_, LLD_, MB_, M_, NB_, N_,
     $                   RSRC_
      parameter( block_cyclic_2d_inb = 2, dlen_ = 11,
     $                   dtype_ = 1, ctxt_ = 2, m_ = 3, n_ = 4,
     $                   imb_ = 5, inb_ = 6, mb_ = 7, nb_ = 8,
     $                   rsrc_ = 9, csrc_ = 10, lld_ = 11 )
      INTEGER            JMP_1, JMP_COL, JMP_IMBV, JMP_INBV, JMP_LEN,
     $                   JMP_MB, JMP_NB, JMP_NPIMBLOC, JMP_NPMB,
     $                   JMP_NQINBLOC, JMP_NQNB, JMP_ROW
      parameter( jmp_1 = 1, jmp_row = 2, jmp_col = 3,
     $                   jmp_mb = 4, jmp_imbv = 5, jmp_npmb = 6,
     $                   jmp_npimbloc = 7, jmp_nb = 8, jmp_inbv = 9,
     $                   jmp_nqnb = 10, jmp_nqinbloc = 11,
     $                   jmp_len = 11 )
*     ..
*     .. Local Scalars ..
      LOGICAL            DIAGDO, SYMM, HERM, NOTRAN
      INTEGER            CSRC, I, IACOL, IAROW, ICTXT, IIA, ILOCBLK,
     $                   ILOCOFF, ILOW, IMB, IMB1, IMBLOC, IMBVIR, INB,
     $                   INB1, INBLOC, INBVIR, INFO, IOFFDA, ITMP, IUPP,
     $                   IVIR, JJA, JLOCBLK, JLOCOFF, JVIR, LCMT00,
     $                   LMBLOC, LNBLOC, LOW, MAXMN, MB, MBLKS, MP,
     $                   MRCOL, MRROW, MYCDIST, MYCOL, MYRDIST, MYROW,
     $                   NB, NBLKS, NPCOL, NPROW, NQ, NVIR, RSRC, UPP
      DOUBLE PRECISION   ALPHA
*     ..
*     .. Local Arrays ..
      INTEGER            DESCA2( DLEN_ ), IMULADD( 4, JMP_LEN ),
     $                   IRAN( 2 ), JMP( JMP_LEN ), MULADD0( 4 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, pb_ainfog2l, pb_binfo,
     $                   pb_chkmat, pb_desctrans, pb_dlagen, pb_initjmp,
     $                   pb_initmuladd, pb_jump, pb_jumpit, pb_locinfo,
     $                   pb_setlocran, pb_setran, pdladom, pxerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Data Statements ..
      DATA               ( muladd0( i ), i = 1, 4 ) / 20077, 16838,
     $                   12345, 0 /
*     ..
*     .. Executable Statements ..
*
*     Convert descriptor
*
      CALL pb_desctrans( desca, desca2 )
*
*     Test the input arguments
*
      ictxt = desca2( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -( 1000 + ctxt_ )
      ELSE
         symm   = lsame( aform, 'S' )
         herm   = lsame( aform, 'H' )
         notran = lsame( aform, 'N' )
         diagdo = lsame( diag, 'D' )
         IF( .NOT.( symm.OR.herm.OR.notran ) .AND.
     $       .NOT.( lsame( aform, 'T' )    ) .AND.
     $       .NOT.( lsame( aform, 'C' )    ) ) THEN
            info = -2
         ELSE IF( ( .NOT.diagdo ) .AND.
     $            ( .NOT.lsame( diag, 'N' ) ) ) THEN
            info = -3
         END IF
         CALL pb_chkmat( ictxt, m, 5, n, 6, ia, ja, desca2, 10, info )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PDLAGEN', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( ( m.LE.0 ).OR.( n.LE.0 ) )
     $   RETURN
*
*     Start the operations
*
      mb   = desca2( mb_   )
      nb   = desca2( nb_   )
      imb  = desca2( imb_  )
      inb  = desca2( inb_  )
      rsrc = desca2( rsrc_ )
      csrc = desca2( csrc_ )
*
*     Figure out local information about the distributed matrix operand
*
      CALL pb_ainfog2l( m, n, ia, ja, desca2, nprow, npcol, myrow,
     $                  mycol, imb1, inb1, mp, nq, iia, jja, iarow,
     $                  iacol, mrrow, mrcol )
*
*     Decide where the entries shall be stored in memory
*
      IF( inplace ) THEN
         iia = 1
         jja = 1
      END IF
*
*     Initialize LCMT00, MBLKS, NBLKS, IMBLOC, INBLOC, LMBLOC, LNBLOC,
*     ILOW, LOW, IUPP, and UPP.
*
      ioffda = ja + offa - ia
      CALL pb_binfo( ioffda, mp, nq, imb1, inb1, mb, nb, mrrow,
     $               mrcol, lcmt00, mblks, nblks, imbloc, inbloc,
     $               lmbloc, lnbloc, ilow, low, iupp, upp )
*
*     Initialize ILOCBLK, ILOCOFF, MYRDIST, JLOCBLK, JLOCOFF, MYCDIST
*     This values correspond to the square virtual underlying matrix
*     of size MAX( M_ + MAX( 0, -OFFA ), N_ + MAX( 0, OFFA ) ) used
*     to set up the random sequence. For practical purposes, the size
*     of this virtual matrix is upper bounded by M_ + N_ - 1.
*
      itmp   = max( 0, -offa )
      ivir   = ia  + itmp
      imbvir = imb + itmp
      nvir   = desca2( m_ ) + itmp
*
      CALL pb_locinfo( ivir, imbvir, mb, myrow, rsrc, nprow, ilocblk,
     $                 ilocoff, myrdist )
*
      itmp   = max( 0, offa )
      jvir   = ja  + itmp
      inbvir = inb + itmp
      nvir   = max( max( nvir, desca2( n_ ) + itmp ),
     $              desca2( m_ ) + desca2( n_ ) - 1 )
*
      CALL pb_locinfo( jvir, inbvir, nb, mycol, csrc, npcol, jlocblk,
     $                 jlocoff, mycdist )
*
      IF( symm .OR. herm .OR. notran ) THEN
*
         CALL pb_initjmp( .true., nvir, imbvir, inbvir, imbloc, inbloc,
     $                    mb, nb, rsrc, csrc, nprow, npcol, 1, jmp )
*
*        Compute constants to jump JMP( * ) numbers in the sequence
*
         CALL pb_initmuladd( muladd0, jmp, imuladd )
*
*        Compute and set the random value corresponding to A( IA, JA )
*
         CALL pb_setlocran( iaseed, ilocblk, jlocblk, ilocoff, jlocoff,
     $                      myrdist, mycdist, nprow, npcol, jmp,
     $                      imuladd, iran )
*
         CALL pb_dlagen( 'Lower', aform, a( iia, jja ), lda, lcmt00,
     $                   iran, mblks, imbloc, mb, lmbloc, nblks, inbloc,
     $                   nb, lnbloc, jmp, imuladd )
*
      END IF
*
      IF( symm .OR. herm .OR. ( .NOT. notran ) ) THEN
*
         CALL pb_initjmp( .false., nvir, imbvir, inbvir, imbloc, inbloc,
     $                    mb, nb, rsrc, csrc, nprow, npcol, 1, jmp )
*
*        Compute constants to jump JMP( * ) numbers in the sequence
*
         CALL pb_initmuladd( muladd0, jmp, imuladd )
*
*        Compute and set the random value corresponding to A( IA, JA )
*
         CALL pb_setlocran( iaseed, ilocblk, jlocblk, ilocoff, jlocoff,
     $                      myrdist, mycdist, nprow, npcol, jmp,
     $                      imuladd, iran )
*
         CALL pb_dlagen( 'Upper', aform, a( iia, jja ), lda, lcmt00,
     $                   iran, mblks, imbloc, mb, lmbloc, nblks, inbloc,
     $                   nb, lnbloc, jmp, imuladd )
*
      END IF
*
      IF( diagdo ) THEN
*
         maxmn = max( desca2( m_ ), desca2( n_ ) )
         alpha = dble( maxmn )
*
         IF( ioffda.GE.0 ) THEN
            CALL pdladom( inplace, min( max( 0, m-ioffda ), n ), alpha,
     $                    a, min( ia+ioffda, ia+m-1 ), ja, desca )
         ELSE
            CALL pdladom( inplace, min( m, max( 0, n+ioffda ) ), alpha,
     $                    a, ia, min( ja-ioffda, ja+n-1 ), desca )
         END IF
*
      END IF
*
      RETURN
*
*     End of PDLAGEN
*

Here is the call graph for this function: