pb_setlocran()

subroutine pb_setlocran	(	integer	seed,
		integer	ilocblk,
		integer	jlocblk,
		integer	ilocoff,
		integer	jlocoff,
		integer	myrdist,
		integer	mycdist,
		integer	nprow,
		integer	npcol,
		integer, dimension( * )	jmp,
		integer, dimension( 4, * )	imuladd,
		integer, dimension( * )	iran
	)

Definition at line 4299 of file pblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            ILOCBLK, ILOCOFF, JLOCBLK, JLOCOFF, MYCDIST,
     $                   MYRDIST, NPCOL, NPROW, SEED
*     ..
*     .. Array Arguments ..
      INTEGER            IMULADD( 4, * ), IRAN( * ), JMP( * )
*     ..
*
*  Purpose
*  =======
*
*  PB_SETLOCRAN locally initializes the random number generator.
*
*  Arguments
*  =========
*
*  SEED    (global input) INTEGER
*          On entry, SEED specifies a positive integer used to initiali-
*          ze the first number in the random sequence used by the matrix
*          generator. SEED must be at least zero.
*
*  ILOCBLK (local input) INTEGER
*          On entry,  ILOCBLK  specifies  the local row block coordinate
*          corresponding to the first row of the submatrix of  interest.
*          ILOCBLK must be at least zero.
*
*  ILOCOFF (local input) INTEGER
*          On entry, ILOCOFF specifies the local row offset in the block
*          of local coordinate ILOCBLK corresponding to the first row of
*          the submatrix of interest. ILOCOFF must at least zero.
*
*  JLOCBLK (local input) INTEGER
*          On entry, JLOCBLK specifies the local column block coordinate
*          corresponding to the first column of  the  submatrix of inte-
*          rest. JLOCBLK must be at least zero.
*
*  JLOCOFF (local input) INTEGER
*          On entry,  JLOCOFF  specifies  the local column offset in the
*          block of local coordinate  JLOCBLK corresponding to the first
*          column of the submatrix of interest. JLOCOFF must be at least
*          zero.
*
*  MYRDIST (local input) INTEGER
*          On entry, MYRDIST  specifies the relative row process coordi-
*          nate to the process  owning the first row of the submatrix of
*          interest. MYRDIST must be at least zero and stricly less than
*          NPROW (see the subroutine PB_LOCINFO).
*
*  MYCDIST (local input) INTEGER
*          On entry, MYCDIST specifies the relative column process coor-
*          dinate to the  process  owning the first column of the subma-
*          trix of interest.  MYCDIST  must be at least zero and stricly
*          less than NPCOL (see the subroutine PB_LOCINFO).
*
*  NPROW   (global input) INTEGER
*          On entry,  NPROW  specifies  the total number of process rows
*          over which the matrix is distributed.  NPROW must be at least
*          one.
*
*  NPCOL   (global input) INTEGER
*          On entry,  NPCOL  specifies  the  total number of process co-
*          lumns over which the matrix is distributed.  NPCOL must be at
*          least one.
*
*  JMP     (local input) INTEGER array
*          On entry, JMP is an array of dimension JMP_LEN containing the
*          different jump values used by the matrix generator.
*
*  IMULADD (local input) INTEGER array
*          On entry, IMULADD is an array of dimension (4, JMP_LEN).  The
*          jth  column  of this array contains the encoded initial cons-
*          tants a_j and c_j to jump  from  X( n ) to  X( n + JMP( j ) )
*          (= a_j * X( n ) + c_j) in the random sequence. IMULADD(1:2,j)
*          contains respectively the 16-lower and 16-higher bits of  the
*          constant a_j, and IMULADD(3:4,j)  contains  the 16-lower  and
*          16-higher bits of the constant c_j.
*
*  IRAN    (local output) INTEGER array
*          On entry, IRAN is an array of dimension 2. On exit, IRAN con-
*          tains respectively the 16-lower and 32-higher bits of the en-
*          coding of the entry of the  random sequence corresponding lo-
*          cally to the first local array entry to generate.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            JMP_1, JMP_COL, JMP_IMBV, JMP_INBV, JMP_LEN,
     $                   JMP_MB, JMP_NB, JMP_NPIMBLOC, JMP_NPMB,
     $                   JMP_NQINBLOC, JMP_NQNB, JMP_ROW
      parameter( jmp_1 = 1, jmp_row = 2, jmp_col = 3,
     $                   jmp_mb = 4, jmp_imbv = 5, jmp_npmb = 6,
     $                   jmp_npimbloc = 7, jmp_nb = 8, jmp_inbv = 9,
     $                   jmp_nqnb = 10, jmp_nqinbloc = 11,
     $                   jmp_len = 11 )
*     ..
*     .. Local Arrays ..
      INTEGER            IMULADDTMP( 4 ), ITMP( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           pb_jump, pb_setran
*     ..
*     .. Executable Statements ..
*
*     Compute and set the value of IRAN corresponding to A( IA, JA )
*
      itmp( 1 ) = seed
      itmp( 2 ) = 0
*
      CALL pb_jump( jmp( jmp_1 ), imuladd( 1, jmp_1 ), itmp, iran,
     $              imuladdtmp )
*
*     Jump ILOCBLK blocks of rows + ILOCOFF rows
*
      CALL pb_jump( ilocoff, imuladd( 1, jmp_row ), iran, itmp,
     $              imuladdtmp )
      IF( myrdist.GT.0 ) THEN
         CALL pb_jump( jmp( jmp_imbv ), imuladd( 1, jmp_row  ), itmp,
     $                 iran, imuladdtmp )
         CALL pb_jump( myrdist - 1,     imuladd( 1, jmp_mb   ), iran,
     $                 itmp, imuladdtmp )
         CALL pb_jump( ilocblk,         imuladd( 1, jmp_npmb ), itmp,
     $                 iran, imuladdtmp )
      ELSE
         IF( ilocblk.GT.0 ) THEN
            CALL pb_jump( jmp( jmp_imbv ), imuladd( 1, jmp_row  ), itmp,
     $                    iran, imuladdtmp )
            CALL pb_jump( nprow - 1,       imuladd( 1, jmp_mb   ), iran,
     $                    itmp, imuladdtmp )
            CALL pb_jump( ilocblk - 1,     imuladd( 1, jmp_npmb ), itmp,
     $                    iran, imuladdtmp )
         ELSE
            CALL pb_jump( 0,               imuladd( 1, jmp_1    ), itmp,
     $                    iran, imuladdtmp )
         END IF
      END IF
*
*     Jump JLOCBLK blocks of columns + JLOCOFF columns
*
      CALL pb_jump( jlocoff, imuladd( 1, jmp_col ), iran, itmp,
     $              imuladdtmp )
      IF( mycdist.GT.0 ) THEN
         CALL pb_jump( jmp( jmp_inbv ), imuladd( 1, jmp_col  ), itmp,
     $                 iran, imuladdtmp )
         CALL pb_jump( mycdist - 1,     imuladd( 1, jmp_nb   ), iran,
     $                 itmp, imuladdtmp )
         CALL pb_jump( jlocblk,         imuladd( 1, jmp_nqnb ), itmp,
     $                 iran, imuladdtmp )
      ELSE
         IF( jlocblk.GT.0 ) THEN
            CALL pb_jump( jmp( jmp_inbv ), imuladd( 1, jmp_col  ), itmp,
     $                    iran, imuladdtmp )
            CALL pb_jump( npcol - 1,       imuladd( 1, jmp_nb   ), iran,
     $                    itmp, imuladdtmp )
            CALL pb_jump( jlocblk - 1,     imuladd( 1, jmp_nqnb ), itmp,
     $                    iran, imuladdtmp )
         ELSE
            CALL pb_jump( 0,               imuladd( 1, jmp_1    ), itmp,
     $                    iran, imuladdtmp )
         END IF
      END IF
*
      CALL pb_setran( iran, imuladd( 1, jmp_1 ) )
*
      RETURN
*
*     End of PB_SETLOCRAN
*

Here is the caller graph for this function: