ztzcnjg.f

Go to the documentation of this file.

      SUBROUTINE ztzcnjg( UPLO, M, N, IOFFD, ALPHA, A, LDA )
*
*  -- PBLAS auxiliary routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      CHARACTER*1        UPLO
      INTEGER            IOFFD, LDA, M, N
      COMPLEX*16         ALPHA
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * )
*     ..
*
*  Purpose
*  =======
*
*  ZTZCNJG  conjugates  a  two-dimensional array A and then scales it by
*  the scalar alpha.
*
*  Arguments
*  =========
*
*  UPLO    (input) CHARACTER*1
*          On entry,  UPLO  specifies  which trapezoidal part of the ar-
*          ray A is to be conjugated and scaled as follows:
*             = 'L' or 'l':          the lower trapezoid of A is scaled,
*             = 'U' or 'u':          the upper trapezoid of A is scaled,
*             = 'D' or 'd':       diagonal specified by IOFFD is scaled,
*             Otherwise:                   all of the array A is scaled.
*
*  M       (input) INTEGER
*          On entry,  M  specifies the number of rows of the array A.  M
*          must be at least zero.
*
*  N       (input) INTEGER
*          On entry,  N  specifies the number of columns of the array A.
*          N must be at least zero.
*
*  IOFFD   (input) INTEGER
*          On entry, IOFFD specifies the position of the offdiagonal de-
*          limiting the upper and lower trapezoidal part of A as follows
*          (see the notes below):
*
*             IOFFD = 0  specifies the main diagonal A( i, i ),
*                        with i = 1 ... MIN( M, N ),
*             IOFFD > 0  specifies the subdiagonal   A( i+IOFFD, i ),
*                        with i = 1 ... MIN( M-IOFFD, N ),
*             IOFFD < 0  specifies the superdiagonal A( i, i-IOFFD ),
*                        with i = 1 ... MIN( M, N+IOFFD ).
*
*  ALPHA   (input) COMPLEX*16
*          On entry,  ALPHA  specifies the scalar alpha, i.e., the value
*          by which the diagonal and offdiagonal entries of the array  A
*          as specified by UPLO and IOFFD are scaled.
*
*  A       (input/output) COMPLEX*16 array
*          On entry, A is an array of dimension  (LDA,N).  Before  entry
*          with  UPLO = 'U' or 'u', the leading m by n part of the array
*          A must contain the upper trapezoidal  part  of the matrix  as
*          specified by  IOFFD to be scaled, and the strictly lower tra-
*          pezoidal part of A is not referenced; When UPLO = 'L' or 'l',
*          the leading m by n part of the array A must contain the lower
*          trapezoidal  part  of  the matrix as specified by IOFFD to be
*          scaled,  and  the strictly upper trapezoidal part of A is not
*          referenced. On exit, the entries of the  trapezoid part of  A
*          determined by UPLO and IOFFD are conjugated and scaled.
*
*  LDA     (input) INTEGER
*          On entry, LDA specifies the leading dimension of the array A.
*          LDA must be at least max( 1, M ).
*
*  Notes
*  =====
*                           N                                    N
*             ----------------------------                  -----------
*            |       d                    |                |           |
*          M |         d        'U'       |                |      'U'  |
*            |  'L'     'D'               |                |d          |
*            |             d              |              M |  d        |
*             ----------------------------                 |   'D'     |
*                                                          |      d    |
*               IOFFD < 0                                  | 'L'    d  |
*                                                          |          d|
*                  N                                       |           |
*             -----------                                   -----------
*            |    d   'U'|
*            |      d    |                                   IOFFD > 0
*          M |       'D' |
*            |          d|                              N
*            |  'L'      |                 ----------------------------
*            |           |                |          'U'               |
*            |           |                |d                           |
*            |           |                | 'D'                        |
*            |           |                |    d                       |
*            |           |                |'L'   d                     |
*             -----------                  ----------------------------
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ONE, ZERO
      parameter( one = ( 1.0d+0, 0.0d+0 ),
     $                   zero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, JTMP, MN
*     ..
*     .. External Subroutines ..
      EXTERNAL           ztzpad
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dconjg, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( ( m.LE.0 ).OR.( n.LE.0 ) )
     $   RETURN
*
*     Start the operations
*
      IF( alpha.EQ.zero ) THEN
*
         CALL ztzpad( uplo, 'N', m, n, ioffd, zero, zero, a, lda )
*
      ELSE IF( alpha.EQ.one ) THEN
*
         IF( lsame( uplo, 'L' ) ) THEN
*
            mn = max( 0, -ioffd )
            DO 20 j = 1, min( mn, n )
               DO 10 i = 1, m
                  a( i, j ) = dconjg( a( i, j ) )
   10          CONTINUE
   20       CONTINUE
*
            DO 40 j = mn + 1, min( m - ioffd, n )
               DO 30 i = j + ioffd, m
                  a( i, j ) = dconjg( a( i, j ) )
   30          CONTINUE
   40       CONTINUE
*
         ELSE IF( lsame( uplo, 'U' ) ) THEN
*
*           Scales the upper triangular part of the array by ALPHA.
*
            mn = min( m - ioffd, n )
            DO 60 j = max( 0, -ioffd ) + 1, mn
               DO 50 i = 1, j + ioffd
                  a( i, j ) = dconjg( a( i, j ) )
   50          CONTINUE
   60       CONTINUE
*
            DO 80 j = max( 0, mn ) + 1, n
               DO 70 i = 1, m
                  a( i, j ) = dconjg( a( i, j ) )
   70          CONTINUE
   80       CONTINUE
*
         ELSE IF( lsame( uplo, 'D' ) ) THEN
*
*           Scales the diagonal entries by ALPHA.
*
            DO 90 j = max( 0, -ioffd ) + 1, min( m - ioffd, n )
               jtmp = j + ioffd
               a( jtmp, j ) = dconjg( a( jtmp, j ) )
   90       CONTINUE
*
         ELSE
*
*           Scales the entire array by ALPHA.
*
            DO 110 j = 1, n
               DO 100 i = 1, m
                  a( i, j ) = dconjg( a( i, j ) )
  100          CONTINUE
  110       CONTINUE
*
         END IF
*
      ELSE
*
         IF( lsame( uplo, 'L' ) ) THEN
*
*           Scales the lower triangular part of the array by ALPHA.
*
            mn = max( 0, -ioffd )
            DO 130 j = 1, min( mn, n )
               DO 120 i = 1, m
                  a( i, j ) = alpha * dconjg( a( i, j ) )
  120          CONTINUE
  130       CONTINUE
*
            DO 150 j = mn + 1, min( m - ioffd, n )
               DO 140 i = j + ioffd, m
                  a( i, j ) = alpha * dconjg( a( i, j ) )
  140          CONTINUE
  150       CONTINUE
*
         ELSE IF( lsame( uplo, 'U' ) ) THEN
*
*           Scales the upper triangular part of the array by ALPHA.
*
            mn = min( m - ioffd, n )
            DO 170 j = max( 0, -ioffd ) + 1, mn
               DO 160 i = 1, j + ioffd
                  a( i, j ) = alpha * dconjg( a( i, j ) )
  160          CONTINUE
  170       CONTINUE
*
            DO 190 j = max( 0, mn ) + 1, n
               DO 180 i = 1, m
                  a( i, j ) = alpha * dconjg( a( i, j ) )
  180          CONTINUE
  190       CONTINUE
*
         ELSE IF( lsame( uplo, 'D' ) ) THEN
*
*           Scales the diagonal entries by ALPHA.
*
            DO 200 j = max( 0, -ioffd ) + 1, min( m - ioffd, n )
               jtmp = j + ioffd
               a( jtmp, j ) = alpha * dconjg( a( jtmp, j ) )
  200       CONTINUE
*
         ELSE
*
*           Scales the entire array by ALPHA.
*
            DO 220 j = 1, n
               DO 210 i = 1, m
                  a( i, j ) = alpha * dconjg( a( i, j ) )
  210          CONTINUE
  220       CONTINUE
*
         END IF
*
      END IF
*
      RETURN
*
*     End of ZTZCNJG
*
      END