clarnd()

complex function clarnd	(	integer	idist,
		integer, dimension( 4 )	iseed
	)

Definition at line 1 of file clarnd.f.

*
*  -- LAPACK auxiliary routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            IDIST
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
*     ..
*
*  Purpose
*  =======
*
*  CLARND returns a random complex number from a uniform or normal
*  distribution.
*
*  Arguments
*  =========
*
*  IDIST   (input) INTEGER
*          Specifies the distribution of the random numbers:
*          = 1:  real and imaginary parts each uniform (0,1)
*          = 2:  real and imaginary parts each uniform (-1,1)
*          = 3:  real and imaginary parts each normal (0,1)
*          = 4:  uniformly distributed on the disc abs(z) <= 1
*          = 5:  uniformly distributed on the circle abs(z) = 1
*
*  ISEED   (input/output) INTEGER array, dimension (4)
*          On entry, the seed of the random number generator; the array
*          elements must be between 0 and 4095, and ISEED(4) must be
*          odd.
*          On exit, the seed is updated.
*
*  Further Details
*  ===============
*
*  This routine calls the auxiliary routine SLARAN to generate a random
*  real number from a uniform (0,1) distribution. The Box-Muller method
*  is used to transform numbers from a uniform to a normal distribution.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TWO
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0 )
      REAL               TWOPI
      parameter( twopi = 6.2831853071795864769252867663e+0 )
*     ..
*     .. Local Scalars ..
      REAL               T1, T2
*     ..
*     .. External Functions ..
      REAL               SLARAN
      EXTERNAL           slaran
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, exp, log, sqrt
*     ..
*     .. Executable Statements ..
*
*     Generate a pair of real random numbers from a uniform (0,1)
*     distribution
*
      t1 = slaran( iseed )
      t2 = slaran( iseed )
*
      IF( idist.EQ.1 ) THEN
*
*        real and imaginary parts each uniform (0,1)
*
         clarnd = cmplx( t1, t2 )
      ELSE IF( idist.EQ.2 ) THEN
*
*        real and imaginary parts each uniform (-1,1)
*
         clarnd = cmplx( two*t1-one, two*t2-one )
      ELSE IF( idist.EQ.3 ) THEN
*
*        real and imaginary parts each normal (0,1)
*
         clarnd = sqrt( -two*log( t1 ) )*exp( cmplx( zero, twopi*t2 ) )
      ELSE IF( idist.EQ.4 ) THEN
*
*        uniform distribution on the unit disc abs(z) <= 1
*
         clarnd = sqrt( t1 )*exp( cmplx( zero, twopi*t2 ) )
      ELSE IF( idist.EQ.5 ) THEN
*
*        uniform distribution on the unit circle abs(z) = 1
*
         clarnd = exp( cmplx( zero, twopi*t2 ) )
      ELSE
         clarnd = cmplx(zero,zero)         
      END IF
      RETURN
*
*     End of CLARND
*

Here is the call graph for this function:

Here is the caller graph for this function: