pdlassq()

subroutine pdlassq	(	integer	n,
		double precision, dimension( * )	x,
		integer	ix,
		integer	jx,
		integer, dimension( * )	descx,
		integer	incx,
		double precision	scale,
		double precision	sumsq
	)

Definition at line 1 of file pdlassq.f.

*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            IX, INCX, JX, N
      DOUBLE PRECISION   SCALE, SUMSQ
*     ..
*     .. Array Arguments ..
      INTEGER            DESCX( * )
      DOUBLE PRECISION   X( * )
*     ..
*
*  Purpose
*  =======
*
*  PDLASSQ  returns the values  scl  and  smsq  such that
*
*     ( scl**2 )*smsq = x( 1 )**2 +...+ x( n )**2 + ( scale**2 )*sumsq,
*
*  where  x( i ) = sub( X ) = X( IX+(JX-1)*DESCX(M_)+(i-1)*INCX ).
*  The value of sumsq is assumed to be non-negative and scl returns the
*  value
*
*     scl = max( scale, abs( x( i ) ) ).
*
*  scale and sumsq must be supplied in SCALE and SUMSQ respectively.
*  SCALE and SUMSQ are overwritten by scl and ssq respectively.
*
*  The routine makes only one pass through the vector sub( X ).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Because vectors may be viewed as a subclass of matrices, a
*  distributed vector is considered to be a distributed matrix.
*
*  The result are only available in the scope of sub( X ), i.e if
*  sub( X ) is distributed along a process row, the correct results are
*  only available in this process row of the grid. Similarly if sub( X )
*  is distributed along a process column, the correct results are only
*  available in this process column of the grid.
*
*  Arguments
*  =========
*
*  N       (global input) INTEGER
*          The length of the distributed vector sub( X ).
*
*  X       (input) DOUBLE PRECISION
*          The vector for which a scaled sum of squares is computed.
*             x( i )  = X(IX+(JX-1)*M_X +(i-1)*INCX ), 1 <= i <= n.
*
*  IX      (global input) INTEGER
*          The row index in the global array X indicating the first
*          row of sub( X ).
*
*  JX      (global input) INTEGER
*          The column index in the global array X indicating the
*          first column of sub( X ).
*
*  DESCX   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix X.
*
*  INCX    (global input) INTEGER
*          The global increment for the elements of X. Only two values
*          of INCX are supported in this version, namely 1 and M_X.
*          INCX must not be zero.
*
*  SCALE   (local input/local output) DOUBLE PRECISION
*          On entry, the value  scale  in the equation above.
*          On exit, SCALE is overwritten with  scl , the scaling factor
*          for the sum of squares.
*
*  SUMSQ   (local input/local output) DOUBLE PRECISION
*          On entry, the value  sumsq  in the equation above.
*          On exit, SUMSQ is overwritten with  smsq , the basic sum of
*          squares from which  scl  has been factored out.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, ICOFF, ICTXT, IIX, IOFF, IROFF, IXCOL,
     $                   IXROW, JJX, LDX, MYCOL, MYROW, NP, NPCOL,
     $                   NPROW, NQ
      DOUBLE PRECISION   TEMP1
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   WORK( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, dcombssq, infog2l, pdtreecomb
*     ..
*     .. External Functions ..
      INTEGER            NUMROC
      EXTERNAL           numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters.
*
      ictxt = descx( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Figure local indexes
*
      CALL infog2l( ix, jx, descx, nprow, npcol, myrow, mycol, iix, jjx,
     $              ixrow, ixcol )
*
      ldx = descx( lld_ )
      IF( incx.EQ.descx( m_ ) ) THEN
*
*        X is rowwise distributed.
*
         IF( myrow.NE.ixrow )
     $      RETURN
         icoff = mod( jx, descx( nb_ ) )
         nq = numroc( n+icoff, descx( nb_ ), mycol, ixcol, npcol )
         IF( mycol.EQ.ixcol )
     $      nq = nq - icoff
*
*        Code direct from LAPACK's DLASSQ, (save subroutine call)
*
         IF( nq.GT.0 ) THEN
            ioff = iix + ( jjx - 1 ) * ldx
            DO 10 i = 1, nq
               IF( x( ioff ).NE.zero ) THEN
                  temp1 = abs( x( ioff ) )
                  IF( scale.LT.temp1 ) THEN
                     sumsq = 1 + sumsq * ( scale / temp1 )**2
                     scale = temp1
                  ELSE
                     sumsq = sumsq + ( temp1 / scale )**2
                  END IF
               END IF
               ioff = ioff + ldx
   10       CONTINUE
         END IF
*
*        Take local result and find global
*
         work( 1 ) = scale
         work( 2 ) = sumsq
*
         CALL pdtreecomb( ictxt, 'Rowwise', 2, work, -1, ixcol,
     $                    dcombssq )
*
         scale = work( 1 )
         sumsq = work( 2 )
*
      ELSE IF( incx.EQ.1 ) THEN
*
*        X is columnwise distributed.
*
         IF( mycol.NE.ixcol )
     $      RETURN
         iroff = mod( ix, descx( mb_ ) )
         np = numroc( n+iroff, descx( mb_ ), myrow, ixrow, nprow )
         IF( myrow.EQ.ixrow )
     $      np = np - iroff
*
*        Code direct from LAPACK's DLASSQ, (save subroutine call)
*
         IF( np.GT.0 ) THEN
            ioff = iix + ( jjx - 1 ) * ldx
            DO 20 i = 1, np
               IF( x( ioff ).NE.zero ) THEN
                  temp1 = abs( x( ioff ) )
                  IF( scale.LT.temp1 ) THEN
                     sumsq = 1 + sumsq*( scale / temp1 )**2
                     scale = temp1
                  ELSE
                     sumsq = sumsq + ( temp1 / scale )**2
                  END IF
               END IF
               ioff = ioff + 1
   20       CONTINUE
         END IF
*
*        Take local result and find global
*
         work( 1 ) = scale
         work( 2 ) = sumsq
*
         CALL pdtreecomb( ictxt, 'Columnwise', 2, work, -1, ixcol,
     $                    dcombssq )
*
         scale = work( 1 )
         sumsq = work( 2 )
*
      END IF
*
      RETURN
*
*     End of PDLASSQ
*

Here is the call graph for this function: