pcunm2l()

subroutine pcunm2l	(	character	side,
		character	trans,
		integer	m,
		integer	n,
		integer	k,
		complex, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		complex, dimension( * )	tau,
		complex, dimension( * )	c,
		integer	ic,
		integer	jc,
		integer, dimension( * )	descc,
		complex, dimension( * )	work,
		integer	lwork,
		integer	info
	)

Definition at line 1 of file pcunm2l.f.

*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 25, 2001
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            IA, IC, INFO, JA, JC, K, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCC( * )
      COMPLEX            A( * ), C( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PCUNM2L overwrites the general complex M-by-N distributed matrix
*  sub( C ) = C(IC:IC+M-1,JC:JC+N-1) with
*
*                      SIDE = 'L'           SIDE = 'R'
*  TRANS = 'N':      Q * sub( C )         sub( C ) * Q
*  TRANS = 'C':      Q**H * sub( C )      sub( C ) * Q**H
*
*  where Q is a complex unitary distributed matrix defined as the
*  product of K elementary reflectors
*
*        Q = H(k) . . . H(2) H(1)
*
*  as returned by PCGEQLF. Q is of order M if SIDE = 'L' and of order N
*  if SIDE = 'R'.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  SIDE    (global input) CHARACTER
*          = 'L': apply Q or Q**H from the Left;
*          = 'R': apply Q or Q**H from the Right.
*
*  TRANS   (global input) CHARACTER
*          = 'N':  No transpose, apply Q;
*          = 'C':  Conjugate transpose, apply Q**H.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on i.e the number of rows
*          of the distributed submatrix sub( C ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on i.e the number of
*          columns of the distributed submatrix sub( C ). N >= 0.
*
*  K       (global input) INTEGER
*          The number of elementary reflectors whose product defines the
*          matrix Q.  If SIDE = 'L', M >= K >= 0, if SIDE = 'R',
*          N >= K >= 0.
*
*  A       (local input) COMPLEX pointer into the local memory
*          to an array of dimension (LLD_A,LOCc(JA+K-1)). On entry, the
*          j-th column must contain the vector which defines the elemen-
*          tary reflector H(j), JA <= j <= JA+K-1, as returned by
*          PCGEQLF in the K columns of its distributed matrix
*          argument A(IA:*,JA:JA+K-1). A(IA:*,JA:JA+K-1) is modified by
*          the routine but restored on exit.
*          If SIDE = 'L', LLD_A >= MAX( 1, LOCr(IA+M-1) ),
*          if SIDE = 'R', LLD_A >= MAX( 1, LOCr(IA+N-1) ).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local input) COMPLEX, array, dimension LOCc(JA+N-1)
*          This array contains the scalar factors TAU(j) of the
*          elementary reflectors H(j) as returned by PCGEQLF.
*          TAU is tied to the distributed matrix A.
*
*  C       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_C,LOCc(JC+N-1)).
*          On entry, the local pieces of the distributed matrix sub(C).
*          On exit, sub( C ) is overwritten by Q*sub( C ) or Q'*sub( C )
*          or sub( C )*Q' or sub( C )*Q.
*
*  IC      (global input) INTEGER
*          The row index in the global array C indicating the first
*          row of sub( C ).
*
*  JC      (global input) INTEGER
*          The column index in the global array C indicating the
*          first column of sub( C ).
*
*  DESCC   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix C.
*
*  WORK    (local workspace/local output) COMPLEX array,
*                                                    dimension (LWORK)
*          On exit, WORK(1) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          If SIDE = 'L', LWORK >= MpC0 + MAX( 1, NqC0 );
*          if SIDE = 'R', LWORK >= NqC0 + MAX( MAX( 1, MpC0 ), NUMROC(
*                   NUMROC( N+ICOFFC,NB_A,0,0,NPCOL ),NB_A,0,0,LCMQ ) );
*
*          where LCMQ = LCM / NPCOL with LCM = ICLM( NPROW, NPCOL ),
*
*          IROFFC = MOD( IC-1, MB_C ), ICOFFC = MOD( JC-1, NB_C ),
*          ICROW = INDXG2P( IC, MB_C, MYROW, RSRC_C, NPROW ),
*          ICCOL = INDXG2P( JC, NB_C, MYCOL, CSRC_C, NPCOL ),
*          MpC0 = NUMROC( M+IROFFC, MB_C, MYROW, ICROW, NPROW ),
*          NqC0 = NUMROC( N+ICOFFC, NB_C, MYCOL, ICCOL, NPCOL ),
*
*          ILCM, INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*
*  INFO    (local output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrices A(IA:*, JA:*) and C(IC:IC+M-1,JC:JC+N-1)
*  must verify some alignment properties, namely the following
*  expressions should be true:
*
*  If SIDE = 'L',
*    ( MB_A.EQ.MB_C .AND. IROFFA.EQ.IROFFC .AND. IAROW.EQ.ICROW )
*  If SIDE = 'R',
*    ( MB_A.EQ.NB_C .AND. IROFFA.EQ.ICOFFC )
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX            ONE
      parameter( one  = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, LQUERY, NOTRAN
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            IACOL, IAROW, ICCOL, ICOFFC, ICROW, ICTXT, ICC,
     $                   II, IROFFA, IROFFC, J, J1, J2, J3, JCC, JJ,
     $                   LCM, LCMQ, LWMIN, MI, MP, MPC0, MYCOL, MYROW,
     $                   NI, NPCOL, NPROW, NQ, NQC0
      COMPLEX            AJJ
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_abort, blacs_gridinfo, cgebr2d,
     $                   cgebs2d, cgerv2d, cgesd2d, chk1mat,
     $                   cscal, infog2l, pcelset, pcelset2,
     $                   pclarf, pclarfc, pb_topget, pb_topset, pxerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILCM, INDXG2P, NUMROC
      EXTERNAL           ilcm, indxg2p, lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, conjg, max, mod, real
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(900+ctxt_)
      ELSE
         left = lsame( side, 'L' )
         notran = lsame( trans, 'N' )
*
*        NQ is the order of Q
*
         IF( left ) THEN
            nq = m
            CALL chk1mat( m, 3, k, 5, ia, ja, desca, 9, info )
         ELSE
            nq = n
            CALL chk1mat( n, 4, k, 5, ia, ja, desca, 9, info )
         END IF
         CALL chk1mat( m, 3, n, 4, ic, jc, descc, 14, info )
         IF( info.EQ.0 ) THEN
            iroffa = mod( ia-1, desca( mb_ ) )
            iroffc = mod( ic-1, descc( mb_ ) )
            icoffc = mod( jc-1, descc( nb_ ) )
            iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
     $                       nprow )
            icrow = indxg2p( ic, descc( mb_ ), myrow, descc( rsrc_ ),
     $                       nprow )
            iccol = indxg2p( jc, descc( nb_ ), mycol, descc( csrc_ ),
     $                       npcol )
            mpc0 = numroc( m+iroffc, descc( mb_ ), myrow, icrow, nprow )
            nqc0 = numroc( n+icoffc, descc( nb_ ), mycol, iccol, npcol )
*
            IF( left ) THEN
               lwmin = mpc0 + max( 1, nqc0 )
            ELSE
               lcm = ilcm( nprow, npcol )
               lcmq = lcm / npcol
               lwmin = nqc0 + max( max( 1, mpc0 ), numroc( numroc(
     $                 n+icoffc, desca( nb_ ), 0, 0, npcol ),
     $                 desca( nb_ ), 0, 0, lcmq ) )
            END IF
*
            work( 1 ) = cmplx( real( lwmin ) )
            lquery = ( lwork.EQ.-1 )
            IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
               info = -1
            ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
                info = -2
            ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
               info = -5
            ELSE IF( .NOT.left .AND. desca( mb_ ).NE.descc( nb_ ) ) THEN
               info = -(900+nb_)
            ELSE IF( left .AND. iroffa.NE.iroffc ) THEN
               info = -12
            ELSE IF( left .AND. iarow.NE.icrow ) THEN
               info = -12
            ELSE IF( .NOT.left .AND. iroffa.NE.icoffc ) THEN
               info = -13
            ELSE IF( left .AND. desca( mb_ ).NE.descc( mb_ ) ) THEN
               info = -(1400+mb_)
            ELSE IF( ictxt.NE.descc( ctxt_ ) ) THEN
               info = -(1400+ctxt_)
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -16
            END IF
         END IF
      END IF
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PCUNM2L', -info )
         CALL blacs_abort( ictxt, 1 )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
     $   RETURN
*
      IF( desca( m_ ).EQ.1 ) THEN
         CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, ii,
     $                 jj, iarow, iacol )
         CALL infog2l( ic, jc, descc, nprow, npcol, myrow, mycol, icc,
     $                 jcc, icrow, iccol )
         IF( left ) THEN
            IF( myrow.EQ.iarow ) THEN
               nq = numroc( jc+n-1, descc( nb_ ), mycol, descc( csrc_ ),
     $                      npcol )
               IF( mycol.EQ.iacol ) THEN
                  IF( notran ) THEN
                     ajj = one - tau( jj )
                  ELSE
                     ajj = one - conjg( tau( jj ) )
                  END IF
                  CALL cgebs2d( ictxt, 'Rowwise', ' ', 1, 1, ajj, 1 )
                  CALL cscal( nq-jcc+1, ajj,
     $                        c( icc+(jcc-1)*descc( lld_ ) ),
     $                        descc( lld_ ) )
               ELSE
                  CALL cgebr2d( ictxt, 'Rowwise', ' ', 1, 1, ajj, 1,
     $                          iarow, iacol )
                  CALL cscal( nq-jcc+1, ajj,
     $                        c( icc+(jcc-1)*descc( lld_ ) ),
     $                        descc( lld_ ) )
               END IF
            END IF
         ELSE
            IF( mycol.EQ.iacol ) THEN
               IF( notran ) THEN
                  ajj = one - tau( jj )
               ELSE
                  ajj = one - conjg( tau( jj ) )
               END IF
            END IF
*
            IF( iacol.NE.iccol ) THEN
               IF( mycol.EQ.iacol )
     $            CALL cgesd2d( ictxt, 1, 1, ajj, 1, myrow, iccol )
               IF( mycol.EQ.iccol )
     $            CALL cgerv2d( ictxt, 1, 1, ajj, 1, myrow, iacol )
            END IF
*
            IF( mycol.EQ.iccol ) THEN
               mp = numroc( ic+m-1, descc( mb_ ), myrow, descc( rsrc_ ),
     $                      nprow )
               CALL cscal( mp-icc+1, ajj, c( icc+(jcc-1)*
     $                     descc( lld_ ) ), 1 )
            END IF
*
         END IF
*
      ELSE
*
         CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
         CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
         IF( left .AND. notran .OR. .NOT.left .AND. .NOT.notran ) THEN
            j1 = ja
            j2 = ja+k-1
            j3 = 1
         ELSE
            j1 = ja+k-1
            j2 = ja
            j3 = -1
         END IF
*
         IF( left ) THEN
            ni = n
            IF( notran ) THEN
               CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'I-ring' )
            ELSE
               CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'D-ring' )
            END IF
            CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', ' ' )
         ELSE
            mi = m
         END IF
*
         DO 10 j = j1, j2, j3
*
            IF( left ) THEN
*
*              H(j) or H(j)' is applied to C(ic:ic+m-k+j-ja,jc:jc+n-1)
*
               mi = m - k + j - ja + 1
            ELSE
*
*              H(j) or H(j)' is applied to C(ic:ic+m-1,jc:jc+n-k+j-ja)
*
               ni = n - k + j - ja + 1
            END IF
*
*           Apply H(j) or H(j)'
*
            CALL pcelset2( ajj, a, ia+nq-k+j-ja, j, desca, one )
            IF( notran ) THEN
               CALL pclarf( side, mi, ni, a, ia, j, desca, 1, tau, c,
     $                      ic, jc, descc, work )
            ELSE
               CALL pclarfc( side, mi, ni, a, ia, j, desca, 1, tau, c,
     $                       ic, jc, descc, work )
            END IF
            CALL pcelset( a, ia+nq-k+j-ja, j, desca, ajj )
*
   10    CONTINUE
*
         CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
         CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      END IF
*
      work( 1 ) = cmplx( real( lwmin ) )
*
      RETURN
*
*     End of PCUNM2L
*

Here is the call graph for this function:

Here is the caller graph for this function: