pslapv2()

subroutine pslapv2	(	character	direc,
		character	rowcol,
		integer	m,
		integer	n,
		real, dimension( * )	a,
		integer	ia,
		integer	ja,
		integer, dimension( * )	desca,
		integer, dimension( * )	ipiv,
		integer	ip,
		integer	jp,
		integer, dimension( * )	descip
	)

Definition at line 1 of file pslapv2.f.

*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          DIREC, ROWCOL
      INTEGER            IA, IP, JA, JP, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCIP( * ), IPIV( * )
      REAL               A( * )
*     ..
*
*  Purpose
*  =======
*
*  PSLAPV2 applies either P (permutation matrix indicated by IPIV)
*  or inv( P ) to a M-by-N distributed matrix sub( A ) denoting
*  A(IA:IA+M-1,JA:JA+N-1), resulting in row or column pivoting.  The
*  pivot vector should be aligned with the distributed matrix A.  For
*  pivoting the rows of sub( A ), IPIV should be distributed along a
*  process column and replicated over all process rows.  Similarly,
*  IPIV should be distributed along a process row and replicated over
*  all process columns for column pivoting.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  DIREC   (global input) CHARACTER
*          Specifies in which order the permutation is applied:
*            = 'F' (Forward) Applies pivots Forward from top of matrix.
*                  Computes P * sub( A );
*            = 'B' (Backward) Applies pivots Backward from bottom of
*                  matrix. Computes inv( P ) * sub( A ).
*
*  ROWCOL  (global input) CHARACTER
*          Specifies if the rows or columns are to be permuted:
*            = 'R' Rows will be permuted,
*            = 'C' Columns will be permuted.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) REAL pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, this local array contains the local pieces of the
*          distributed matrix sub( A ) to which the row or columns
*          interchanges will be applied. On exit, this array contains
*          the local pieces of the permuted distributed matrix.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  IPIV    (input) INTEGER array, dimension >= LOCr(M_A)+MB_A if
*          ROWCOL = 'R', LOCc(N_A)+NB_A otherwise. It contains
*          the pivoting information. IPIV(i) is the global row (column),
*          local row (column) i was swapped with.  The last piece of the
*          array of size MB_A (resp. NB_A) is used as workspace. IPIV is
*          tied to the distributed matrix A.
*
*  IP      (global input) INTEGER
*          IPIV's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JP      (global input) INTEGER
*          IPIV's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCIP  (global and local input) INTEGER array of dimension 8
*          The array descriptor for the distributed matrix IPIV.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      LOGICAL            FORWRD, ROWPVT
      INTEGER            I, IB, ICTXT, ICURCOL, ICURROW, IIP, IP1, ITMP,
     $                   IPVWRK, J, JB, JJP, JP1, K, MA, MBA, MYCOL,
     $                   MYROW, NBA, NPCOL, NPROW
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, igebs2d, igebr2d, infog2l,
     $                   psswap
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL, NUMROC
      EXTERNAL           iceil, lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min, mod
*     ..
*     .. Executable Statements ..
*
      rowpvt = lsame( rowcol, 'R' )
      IF( rowpvt ) THEN
         IF( m.LE.1 .OR. n.LT.1 )
     $      RETURN
      ELSE
         IF( m.LT.1 .OR. n.LE.1 )
     $      RETURN
      END IF
      forwrd = lsame( direc, 'F' )
*
*
*     Get grid and matrix parameters
*
      ma    = desca( m_ )
      mba   = desca( mb_ )
      nba   = desca( nb_ )
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     If I'm applying pivots from beginning to end (e.g., repeating
*     pivoting done earlier).  Thus this section computes P * sub( A ).
*
      IF( forwrd ) THEN
         CALL infog2l( ip, jp, descip, nprow, npcol, myrow, mycol,
     $                 iip, jjp, icurrow, icurcol )
*
*        If I'm pivoting the rows of sub( A )
*
         IF( rowpvt ) THEN
            ipvwrk = numroc( descip( m_ ), descip( mb_ ), myrow,
     $                       descip( rsrc_ ), nprow ) + 1 -
     $                       descip( mb_ )
*
*          Loop over rows of sub( A )
*
            i = ia
            ib = min( m, iceil( ia, mba ) * mba - ia + 1 )
   10       CONTINUE
*
*              Find local pointer into IPIV, and broadcast this block's
*              pivot information to everyone in process column
*
               IF( myrow.EQ.icurrow ) THEN
                  CALL igebs2d( ictxt, 'Columnwise', ' ', ib, 1,
     $                          ipiv( iip ), ib )
                  itmp = iip
                  iip = iip + ib
               ELSE
                  itmp = ipvwrk
                  CALL igebr2d( ictxt, 'Columnwise', ' ', ib, 1,
     $                          ipiv( itmp ), ib, icurrow, mycol )
               END IF
*
*              Pivot the block of rows
*
               DO 20 k = i, i+ib-1
                  ip1 = ipiv( itmp ) - ip + ia
                  IF( ip1.NE.k )
     $               CALL psswap( n, a, k, ja, desca, ma, a, ip1, ja,
     $                            desca, ma )
                  itmp = itmp + 1
   20          CONTINUE
*
*              Go on to next row of processes, increment row counter,
*              and figure number of rows to pivot next
*
               icurrow = mod( icurrow+1, nprow )
               i = i + ib
               ib = min( mba, m-i+ia )
            IF( ib .GT. 0 ) GOTO 10
*
*        If I am pivoting the columns of sub( A )
*
         ELSE
            ipvwrk = numroc( descip( n_ ), descip( nb_ ), mycol,
     $                       descip( csrc_ ), npcol ) + 1 -
     $                       descip( nb_ )
*
*          Loop over columns of sub( A )
*
            j = ja
            jb = min( n, iceil( ja, nba ) * nba - ja + 1 )
   30       CONTINUE
*
*              Find local pointer into IPIV, and broadcast this block's
*              pivot information to everyone in process row
*
               IF( mycol.EQ.icurcol ) THEN
                  CALL igebs2d( ictxt, 'Rowwise', ' ', jb, 1,
     $                          ipiv( jjp ), jb )
                  itmp = jjp
                  jjp = jjp + jb
               ELSE
                  itmp = ipvwrk
                  CALL igebr2d( ictxt, 'Rowwise', ' ', jb, 1,
     $                          ipiv( itmp ), jb, myrow, icurcol )
               END IF
*
*              Pivot the block of columns
*
               DO 40 k = j, j+jb-1
                  jp1 = ipiv( itmp ) - jp + ja
                  IF( jp1.NE.k )
     $               CALL psswap( m, a, ia, k, desca, 1, a, ia, jp1,
     $                            desca, 1 )
                  itmp = itmp + 1
   40          CONTINUE
*
*              Go on to next column of processes, increment column
*              counter, and figure number of columns to pivot next
*
               icurcol = mod( icurcol+1, npcol )
               j = j + jb
               jb = min( nba, n-j+ja )
            IF( jb .GT. 0 ) GOTO 30
         END IF
*
*     If I want to apply pivots in reverse order, i.e. reversing
*     pivoting done earlier.  Thus this section computes
*     inv( P ) * sub( A ).
*
      ELSE
*
*        If I'm pivoting the rows of sub( A )
*
         IF( rowpvt ) THEN
            CALL infog2l( ip+m-1, jp, descip, nprow, npcol, myrow,
     $                    mycol, iip, jjp, icurrow, icurcol )
*
            ipvwrk = numroc( descip( m_ ), descip( mb_ ), myrow,
     $                       descip( rsrc_ ), nprow ) + 1 -
     $                       descip( mb_ )
*
*           If I'm not in the current process row, my IIP points out
*           past end of pivot vector (since I don't own a piece of the
*           last row). Adjust IIP so it points at last pivot entry.
*
            IF( myrow.NE.icurrow ) iip = iip - 1
*
*           Loop over rows in reverse order, starting at last row
*
            i = ia + m - 1
            ib = mod( i, mba )
            IF( ib .EQ. 0 ) ib = mba
            ib = min( ib, m )
   50       CONTINUE
*
*              Find local pointer into IPIV, and broadcast this block's
*              pivot information to everyone in process column
*
               IF( myrow.EQ.icurrow ) THEN
                  itmp = iip
                  iip = iip - ib
                  CALL igebs2d( ictxt, 'Columnwise', ' ', ib, 1,
     $                          ipiv( iip+1 ), ib )
               ELSE
                  CALL igebr2d( ictxt, 'Columnwise', ' ', ib, 1,
     $                          ipiv( ipvwrk ), ib, icurrow, mycol )
                  itmp = ipvwrk + ib - 1
               END IF
*
*              Pivot the block of rows
*
               DO 60 k = i, i-ib+1, -1
                  ip1 = ipiv( itmp ) - ip + ia
                  IF( ip1.NE.k )
     $               CALL psswap( n, a, k, ja, desca, ma, a, ip1, ja,
     $                            desca, ma )
                  itmp = itmp - 1
   60          CONTINUE
*
*              Go to previous row of processes, decrement row counter,
*              and figure number of rows to be pivoted next
*
               icurrow = mod( nprow+icurrow-1, nprow )
               i = i - ib
               ib = min( mba, i-ia+1 )
            IF( ib .GT. 0 ) GOTO 50
*
*        Otherwise, I'm pivoting the columns of sub( A )
*
         ELSE
            CALL infog2l( ip, jp+n-1, descip, nprow, npcol, myrow,
     $                    mycol, iip, jjp, icurrow, icurcol )
            ipvwrk = numroc( descip( n_ ), descip( nb_ ), mycol,
     $                       descip( csrc_ ), npcol ) + 1 -
     $                       descip( nb_ )
*
*           If I'm not in the current process column, my JJP points out
*           past end of pivot vector (since I don't own a piece of the
*           last column). Adjust JJP so it points at last pivot entry.
*
            IF( mycol.NE.icurcol ) jjp = jjp - 1
*
*          Loop over columns in reverse order starting at last column
*
            j = ja + n - 1
            jb = mod( j, nba )
            IF( jb .EQ. 0 ) jb = nba
            jb = min( jb, n )
   70       CONTINUE
*
*              Find local pointer into IPIV, and broadcast this block's
*              pivot information to everyone in process row
*
               IF( mycol.EQ.icurcol ) THEN
                  itmp = jjp
                  jjp = jjp - jb
                  CALL igebs2d( ictxt, 'Rowwise', ' ', jb, 1,
     $                          ipiv( jjp+1 ), jb )
               ELSE
                  CALL igebr2d( ictxt, 'Rowwise', ' ', jb, 1,
     $                          ipiv( ipvwrk ), jb, myrow, icurcol )
                  itmp = ipvwrk + jb - 1
               END IF
*
*              Pivot a block of columns
*
               DO 80 k = j, j-jb+1, -1
                  jp1 = ipiv( itmp ) - jp + ja
                  IF( jp1.NE.k )
     $               CALL psswap( m, a, ia, k, desca, 1, a, ia, jp1,
     $                            desca, 1 )
                  itmp = itmp - 1
   80          CONTINUE
*
*              Go to previous row of processes, decrement row counter,
*              and figure number of rows to be pivoted next
*
               icurcol = mod( npcol+icurcol-1, npcol )
               j = j - jb
               jb = min( nba, j-ja+1 )
            IF( jb .GT. 0 ) GOTO 70
         END IF
*
      END IF
*
      RETURN
*
*     End PSLAPV2
*

Here is the call graph for this function:

Here is the caller graph for this function: