btsend()

subroutine btsend	(	integer	dtype,
		integer	n,
		real, dimension(*)	buff,
		integer	dest,
		integer	msgid
	)

Definition at line 114 of file btprim.f.

*
*  -- BLACS tester (version 1.0) --
*  University of Tennessee
*  December 15, 1994
*
*     .. Scalar Arguments ..
      INTEGER N, DTYPE, DEST, MSGID
*     ..
*     .. Array Arguments ..
      REAL BUFF(*)
*     ..
*
*     PURPOSE
*     =======
*     BTSEND: Communication primitive used to send messages independent
*     of the BLACS.  May safely be either locally or globally blocking.
*
*     Arguments
*     =========
*     DTYPE    (input) INTEGER
*              Indicates what data type BUFF is (same as PVM):
*                1  =  RAW BYTES
*                3  =  INTEGER
*                4  =  SINGLE PRECISION REAL
*                6  =  DOUBLE PRECISION REAL
*                5  =  SINGLE PRECISION COMPLEX
*                7  =  DOUBLE PRECISION COMPLEX
*
*     N        (input) INTEGER
*              The number of elements of type DTYPE in BUFF.
*
*     BUFF     (input) accepted as INTEGER array
*              The array to be communicated.  Its true data type is
*              indicated by DTYPE.
*
*     DEST      (input) INTEGER
*               The destination of the message.
*
*     MSGID     (input) INTEGER
*               The message ID (AKA message tag or type).
*
* =====================================================================
*     .. External Functions ..
      INTEGER  IBTMYPROC, IBTNPROCS, IBTSIZEOF
      EXTERNAL ibtmyproc, ibtnprocs, ibtsizeof
*     ..
*     .. Local Scalars ..
      INTEGER I, IAM, MPIDTYPE
*     ..
*     .. Include Files ..
      include 'mpif.h'
*     ..
*     .. Common Blocks ..
      COMMON /btmpi/ btcomm, ierr
      INTEGER BTCOMM, IERR
*
      IF( dtype .EQ. 1 ) THEN
         mpidtype = mpi_byte
      ELSE IF( dtype .EQ. 3 ) THEN
         mpidtype = mpi_integer
      ELSE IF( dtype .EQ. 4 ) THEN
         mpidtype = mpi_real
      ELSE IF( dtype .EQ. 5 ) THEN
         mpidtype = mpi_complex
      ELSE IF( dtype .EQ. 6 ) THEN
         mpidtype = mpi_double_precision
      ELSE IF( dtype .EQ. 7 ) THEN
         mpidtype = mpi_double_complex
      END IF
*
*     Send the message
*
      IF( dest .EQ. -1 ) THEN
         iam = ibtmyproc()
         DO 10 i = 0, ibtnprocs()-1
            IF( i .NE. iam ) THEN
               CALL mpi_send(buff, n, mpidtype, i, 0, btcomm, ierr)
               IF (ierr.NE.0) CALL btmpierr("MPI_SEND", ierr)
            END IF
   10    CONTINUE
      ELSE
         CALL mpi_send(buff, n, mpidtype, dest, 0, btcomm, ierr)
         IF (ierr.NE.0) CALL btmpierr("MPI_SEND", ierr)
      END IF
*
      RETURN
*
*     End BTSEND
*

Here is the call graph for this function:

Here is the caller graph for this function: