pdsvdchk.f

Go to the documentation of this file.

      SUBROUTINE pdsvdchk( M, N, A, IA, JA, DESCA, U, IU, JU, DESCU, VT,
     $                     IVT, JVT, DESCVT, S, THRESH, WORK, LWORK,
     $                     RESULT, CHK, MTM )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            IA, IU, IVT, JA, JU, JVT, LWORK, M, N
      DOUBLE PRECISION   CHK, MTM, THRESH
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCU( * ), DESCVT( * ),
     $                   RESULT( * )
      DOUBLE PRECISION   A( * ), S( * ), U( * ), VT( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  For given two-dimensional matrices A, U, VT, and one-dimensional
*  array D compute the following four tests:
*
*  (1)   | A - U*diag(S) VT | / ( |A| max(M,N) ulp )
*
*  (2)   | I - U'*U | / ( M ulp )
*
*  (3)   | I - VT*VT' | / ( N ulp ),
*
*  (4)   S contains SIZE = MIN( M, N )  nonnegative values in
*   decreasing order.
*   It then compares result of computations (1)-(3)
*   with TRESH and returns results of comparisons and test (4) in
*   RESULT(I). When the i-th test fails, value of RESULT( I ) is set
*   to 1.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*     MP = number of local rows in A and  U
*     NQ = number of local columns in A and VT
*     SIZEP = number of local rows in VT
*     SIZEQ = number of local columns in U
*
*  M      (global input) INTEGER
*          Matrix size.
*          The number of global rows in A and U and
*
*  N      (global input) INTEGER
*          The number of global columns in A and VT.
*
*  A       (input) block cyclic distributed DOUBLE PRECISION array,
*          global dimension (M, N), local dimension (DESCA( DLEN_ ), NQ)
*          Contains the original test matrix.
*
*  IA      (global input) INTEGER
*          The global row index of the submatrix of the distributed
*          matrix A to operate on.
*
*  JA      (global input) INTEGER
*          The global column index of the submatrix of the distributed
*          matrix A to operate on.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_
*          The array descriptor for the distributed matrix A.
*
*  U       (local input) DOUBLE PRECISION array
*           global dimension (M, SIZE), local dimension
*          (DESCU( DLEN_ ), SIZEQ)
*           Contains left singular vectors of matrix A.
*
*  IU      (global input) INTEGER
*          The global row index of the submatrix of the distributed
*          matrix U to operate on.
*
*  JU      (global input) INTEGER
*          The global column index of the submatrix of the distributed
*          matrix U to operate on.
*
*  DESCU   (global and local input) INTEGER array of dimension DLEN_
*          The array descriptor for the distributed matrix U.
*
*  VT       (local input) DOUBLE PRECISION array
*           global dimension (SIZE, N), local dimension
*           (DESCVT( DLEN_ ), NQ)
*           Contains right singular vectors of matrix A.
*
*  IVT     (global input) INTEGER
*          The global row index of the submatrix of the distributed
*          matrix VT to operate on.
*
*  JVT      (global input) INTEGER
*          The global column index of the submatrix of the distributed
*          matrix VT to operate on.
*
*  DESCVT   (global and local input) INTEGER array of dimension DLEN_
*          The array descriptor for the distributed matrix VT.
*
*  S       (global input) DOUBLE PRECISION array, dimension (SIZE)
*          Contains the computed singular values
*
*  THRESH  (input) DOUBLE PRECISION
*          A test will count as "failed" if the "error", computed as
*          described below, exceeds THRESH.  Note that the error
*          is scaled to be O(1), so THRESH should be a reasonably
*          small multiple of 1, e.g., 10 or 100.  In particular,
*          it should not depend on the precision (single vs. double)
*          or the size of the matrix.  It must be at least zero.
*
*  WORK    (local workspace) DOUBLE PRECISION array, dimension (LWORK)
*
*  LWORK   (local input) INTEGER
*          The length of the array WORK.
*          LWORK >= 1 + SIZEQ*SIZEP + MAX[WORK(pdlange(size,size)),
*          WORK(pdlange(m,n))],
*          where
*          SIZEQ = NUMROC( SIZE, DESCU( NB_ ), MYCOL, 0, NPCOL ),
*          SIZEP = NUMROC( SIZE, DESCVT( MB_ ), MYROW, 0, NPROW ),
*          and worekspaces required to call pdlange are
*          WORK(pdlange(size,size)) < MAX(SIZEQ0,2) < SIZEB +2,
*          WORK(pdlange(m,n)) < MAX(NQ0,2) < SIZEB +2,
*          SIZEB = MAX(M, N)
*          Finally, upper limit on required workspace is
*          LWORK >  1 + SIZEQ*SIZEP + SIZEB + 2
*
*  RESULT  (global input/output) INTEGER array. Four first elements of
*          the array are set to 0 or 1 depending on passing four
*          respective tests ( see above in Purpose ). The elements of
*          RESULT are set to
*          0 if the test passes i.e.
*            | A - U*diag(S)*VT | / ( |A| max(M,N) ulp ) <= THRESH
*          1 if the test fails  i.e.
*            | A - U*diag(S)*VT | / ( |A| max(M,N) ulp ) >  THRESH
*
*  CHK     (global output) DOUBLE PRECISION
*           value of the | A - U*diag(S) VT | / ( |A| max(M,N) ulp )
*
*  MTM     (global output) DOUBLE PRECISION
*           maximum of the two values:
*            | I - U'*U | / ( M ulp ) and  | I - VT*VT' | / ( N ulp )
*
* ======================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   MB_, NB_, RSRC_, CSRC_, LLD_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ZERO, ONE, MONE
      PARAMETER          ( ZERO = 0.0d+0, one = 1.0d+0, mone = -1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, LDR, LOCALCOL, LWMIN, MP, MX, MYCOL,
     $                   MYROW, NPCOL, NPROW, NQ, PCOL, PTRR, PTRWORK,
     $                   SIZE, sizep, sizepos, sizeq
      DOUBLE PRECISION   FIRST, NORMA, NORMAI, NORMU, NORMVT, SECOND,
     $                   THRESHA, ULP
*     ..
*     .. Local Arrays ..
      INTEGER            DESCR( DLEN_ )
*     ..
*     .. External Functions ..
      INTEGER            INDXG2L, INDXG2P, NUMROC
      DOUBLE PRECISION   PDLAMCH, PDLANGE
      EXTERNAL           indxg2l, indxg2p, numroc, pdlamch, pdlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, descinit, dscal,
     $                   pdelset, pdgemm, pdlaset, pxerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*     This is just to keep ftnchek happy
      IF( block_cyclic_2d*csrc_*dtype_*m_*n_*rsrc_.LT.0 ) RETURN
*
*     Test the input parameters.
*
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
      info = 0
      SIZE = min( m, n )
*
*     Sizepos is a number of parameters to pdsvdchk plus one. It's used
*     for the error reporting.
*
      sizepos = 22
      IF( nprow.EQ.-1 ) THEN
         info = -607
      ELSE
         CALL chk1mat( m, 1, n, 2, ia, ja, desca, 6, info )
         CALL chk1mat( m, 1, SIZE, sizepos, iu, ju, descu, 10, info )
         CALL chk1mat( SIZE, sizepos, n, 2, ivt, jvt, descvt, 14, info )
      END IF
*
      IF( info.EQ.0 ) THEN
*
*     Calculate workspace
*
         mp = numroc( m, desca( mb_ ), myrow, 0, nprow )
         nq = numroc( n, desca( nb_ ), mycol, 0, npcol )
         sizep = numroc( SIZE, descvt( mb_ ), myrow, 0, nprow )
         sizeq = numroc( SIZE, descu( nb_ ), mycol, 0, npcol )
         mx = max( sizeq, nq )
         lwmin = 2 + sizeq*sizep + max( 2, mx )
         work( 1 ) = lwmin
         IF( lwork.EQ.-1 )
     $      GO TO 40
         IF( lwork.LT.lwmin ) THEN
            info = -18
         ELSE IF( thresh.LE.0 ) THEN
            info = -16
         END IF
      END IF
      IF( info.NE.0 ) THEN
         CALL pxerbla( desca( ctxt_ ), 'PDSVDCHK', -info )
         RETURN
      END IF
*
      ldr = max( 1, sizep )
      ulp = pdlamch( desca( ctxt_ ), 'P' )
      normai = pdlange( '1', m, n, a, ia, ja, desca, work )
*
*     Allocate array R of global dimension SIZE x SIZE for testing
*
      ptrr = 2
      ptrwork = ptrr + sizeq*sizep
*
      CALL descinit( descr, SIZE, SIZE, descvt( mb_ ), descu( nb_ ), 0,
     $               0, desca( ctxt_ ), ldr, info )
*
*     Test 2. Form identity matrix R  and make  check norm(U'*U - I )
*
      CALL pdlaset( 'Full', SIZE, SIZE, zero, one, work( ptrr ), 1, 1,
     $              descr )
      CALL pdgemm( 'T', 'N', SIZE, SIZE, m, one, u, iu, ju, descu, u, 
     $             iu, ju, descu, mone, work( ptrr ), 1, 1, descr )
*
      normu = pdlange( '1', SIZE, SIZE, work( ptrr ), 1, 1, descr,
     $        work( ptrwork ) )
*
      normu = normu / ulp / SIZE / thresh
      IF( normu.GT.1. )
     $   result( 2 ) = 1
*
*     Test3. Form identity matrix R  and check norm(VT*VT' - I )
*
      CALL pdlaset( 'Full', SIZE, SIZE, zero, one, work( ptrr ), 1, 1,
     $              descr )
      CALL pdgemm( 'N', 'T', SIZE, SIZE, n, one, vt, ivt, jvt, descvt,
     $             vt, ivt, jvt, descvt, mone, work( ptrr ), 
     $             1, 1, descr )
      normvt = pdlange( '1', SIZE, SIZE, work( ptrr ), 1, 1, descr,
     $         work( ptrwork ) )
*
      normvt = normvt / ulp / SIZE / thresh
      IF( normvt.GT.1. )
     $   result( 3 ) = 1
*
      mtm = max( normvt, normu )*thresh
*
*     Test 1.
*     Initialize R = diag( S )
*
      CALL pdlaset( 'Full', SIZE, SIZE, zero, zero, work( ptrr ), 1, 1,
     $              descr )
*
      DO 10 i = 1, SIZE
         CALL pdelset( work( ptrr ), i, i, descr, s( i ) )
   10 CONTINUE
*
*     Calculate U = U*R
*
      DO 20 i = 1, SIZE
         pcol = indxg2p( i, descu( nb_ ), 0, 0, npcol )
         localcol = indxg2l( i, descu( nb_ ), 0, 0, npcol )
         IF( mycol.EQ.pcol ) THEN
            CALL dscal( mp, s( i ), u( ( localcol-1 )*descu( lld_ )+1 ),
     $                  1 )
         END IF
   20 CONTINUE
*
*     Calculate A = U*VT - A
*
      CALL pdgemm( 'N', 'N', m, n, SIZE, one, u, iu, ju, descu, vt,
     $             ivt, jvt, descvt, mone, a, ia, ja, desca )
*
      norma = pdlange( '1', m, n, a, ia, ja, desca, work( ptrwork ) )
      thresha = normai*max( m, n )*ulp*thresh
*
      IF( norma.GT.thresha )
     $   result( 1 ) = 1
*
      IF( thresha.EQ.0 ) THEN
         chk = 0.0d0
      ELSE
         chk = norma / thresha*thresh
      END IF
*
*     Test 4.
*
      DO 30 i = 1, SIZE - 1
         first = s( i )
         second = s( i+1 )
         IF( first.LT.second )
     $      result( 4 ) = 1
   30 CONTINUE
   40 CONTINUE
      RETURN
      END