psgsepchk.f

Go to the documentation of this file.

*
*
      SUBROUTINE psgsepchk( IBTYPE, MS, NV, A, IA, JA, DESCA, B, IB, JB,
     $                      DESCB, THRESH, Q, IQ, JQ, DESCQ, C, IC, JC,
     $                      DESCC, W, WORK, LWORK, TSTNRM, RESULT )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 15, 1997
*
*     .. Scalar Arguments ..
      INTEGER            IA, IB, IBTYPE, IC, IQ, JA, JB, JC, JQ, LWORK,
     $                   MS, NV, RESULT
      REAL               THRESH, TSTNRM
*     ..
*     .. Array Arguments ..
*
      INTEGER            DESCA( * ), DESCB( * ), DESCC( * ), DESCQ( * )
      REAL               A( * ), B( * ), C( * ), Q( * ), W( * ),
     $                   work( * )
*     ..
*
*
*  Purpose
*  =======
*
*  PSGSEPCHK checks a decomposition of the form
*
*     A Q   =  B Q D or
*     A B Q =  Q D or
*     B A Q =  Q D
*
*  where A is a symmetric matrix, B is
*  symmetric positive definite, Q is orthogonal, and D is diagonal.
*
*  One of the following test ratios is computed:
*
*  IBTYPE = 1:  TSTNRM = | A Q - B Q D | / ( |A| |Q| n ulp )
*
*  IBTYPE = 2:  TSTNRM = | A B Q - Q D | / ( |A| |Q| n ulp )
*
*  IBTYPE = 3:  TSTNRM = | B A Q - Q D | / ( |A| |Q| n ulp )
*
*
*  Notes
*  =====
*
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*
*  Arguments
*  =========
*
*     MP = number of local rows in A, B and Q
*     MQ = number of local columns in A
*     NQ = number of local columns in B and Q
*
*  IBTYPE   (input) INTEGER
*          The form of the symmetric generalized eigenproblem.
*          = 1:  A*Q = (lambda)*B*Q
*          = 2:  A*B*Q = (lambda)*Q
*          = 3:  B*A*Q = (lambda)*Q
*
*  MS      (global input) INTEGER
*          Matrix size.
*          The number of global rows in A, B, C and Q
*          Also, the number of columns in A
*
*  NV      (global input) INTEGER
*          Number of eigenvectors
*          The number of global columns in C and Q.
*
*  A       (local input) REAL pointer to an
*          array in local memory of dimension (LLD_A, LOCc(JA+N-1)).
*          This array contains the local pieces of the M-by-N
*          distributed test matrix A
*
*  IA      (global input) INTEGER
*          A's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JA      (global input) INTEGER
*          A's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCA   (global and local input) INTEGER array of dimension 8
*          The array descriptor for the distributed matrix A.
*
*  B       (local input) REAL pointer to an
*          array in local memory of dimension (LLD_B, LOCc(JB+N-1)).
*          This array contains the local pieces of the M-by-N
*          distributed test matrix B
*
*  IB      (global input) INTEGER
*          B's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JB      (global input) INTEGER
*          B's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCB   (global and local input) INTEGER array of dimension 8
*          The array descriptor for the distributed matrix B.
*
*  THRESH  (input) REAL
*          A test will count as "failed" if the "error", computed as
*          described below, exceeds THRESH.  Note that the error
*          is scaled to be O(1), so THRESH should be a reasonably
*          small multiple of 1, e.g., 10 or 100.  In particular,
*          it should not depend on the precision (single vs. double)
*          or the size of the matrix.  It must be at least zero.
*
*  Q       (local input) REAL array
*          global dimension (MS, NV),
*          local dimension (DESCA( DLEN_ ), NQ)
*
*          Contains the eigenvectors as computed by PSSYEVX
*
*  IQ      (global input) INTEGER
*          Q's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JQ      (global input) INTEGER
*          Q's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCQ   (global and local input) INTEGER array of dimension 8
*          The array descriptor for the distributed matrix Q.
*
*  C       (local workspace) REAL array,
*          global dimension (MS, NV),
*          local dimension (DESCA( DLEN_ ), MQ)
*
*          Accumulator for computing AQ -QL
*
*  IC      (global input) INTEGER
*          C's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JC      (global input) INTEGER
*          C's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCC   (global and local input) INTEGER array of dimension 8
*          The array descriptor for the distributed matrix C.
*
*  W       (global input) REAL array, dimension (NV)
*
*          Contains the computed eigenvalues
*
*  WORK    (local workspace) REAL array,
*                            dimension (LWORK)
*
*  LWORK   (local input) INTEGER
*          The length of the array WORK.
*          LWORK >= NUMROC( NV, DESCA( NB_ ), MYCOL, 0, NPCOL )
*
*  TSTNRM  (global output) REAL
*
*  RESULT  (global output) INTEGER
*          0 if the test passes
*          1 if the test fails
*
*     .. Local Scalars ..
*
      INTEGER            I, INFO, MYCOL, MYROW, NPCOL, NPROW, NQ
      REAL               ANORM, ULP
*     ..
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   MB_, NB_, RSRC_, CSRC_, LLD_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ONE, ZERO
      PARAMETER          ( ONE = 1.0e+0, zero = 0.0e+0 )
      REAL               CONE, CNEGONE, CZERO
      parameter( cone = 1.0e+0, cnegone = -1.0e+0,
     $                   czero = 0.0e+0 )
*     ..
*     .. External Functions ..
      INTEGER            NUMROC
      REAL               PSLANGE, SLAMCH
      EXTERNAL           numroc, pslange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, psgemm, psscal,
     $                   pxerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*       This is just to keep ftnchek happy
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*
      result = 0
*
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
*
      info = 0
      CALL chk1mat( ms, 1, ms, 2, ia, ja, desca, 7, info )
      CALL chk1mat( ms, 1, ms, 2, ib, jb, descb, 11, info )
      CALL chk1mat( ms, 1, nv, 2, iq, jq, descq, 16, info )
      CALL chk1mat( ms, 1, nv, 2, ib, jb, descb, 20, info )
*
      IF( info.EQ.0 ) THEN
*
         nq = numroc( nv, desca( nb_ ), mycol, 0, npcol )
*
         IF( iq.NE.1 ) THEN
            info = -14
         ELSE IF( jq.NE.1 ) THEN
            info = -15
         ELSE IF( ia.NE.1 ) THEN
            info = -5
         ELSE IF( ja.NE.1 ) THEN
            info = -6
         ELSE IF( ib.NE.1 ) THEN
            info = -9
         ELSE IF( jb.NE.1 ) THEN
            info = -10
         ELSE IF( lwork.LT.nq ) THEN
            info = -23
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( desca( ctxt_ ), 'PSGSEPCHK', -info )
         RETURN
      END IF
*
      result = 0
      ulp = slamch( 'Epsilon' )
*
*     Compute product of Max-norms of A and Q.
*
      anorm = pslange( 'M', ms, ms, a, ia, ja, desca, work )*
     $        pslange( 'M', ms, nv, q, iq, jq, descq, work )
      IF( anorm.EQ.zero )
     $   anorm = one
*
      IF( ibtype.EQ.1 ) THEN
*
*        Norm of AQ - BQD
*
*        C = AQ
*
         CALL psgemm( 'N', 'N', ms, nv, ms, cone, a, ia, ja, desca, q,
     $                iq, jq, descq, czero, c, ic, jc, descc )
*
*        Q = QD
*
         DO 10 i = 1, nv
            CALL psscal( ms, w( i ), q, iq, jq+i-1, descq, 1 )
   10    CONTINUE
*
*        C = C - BQ  (i.e. AQ-BQD)
*
         CALL psgemm( 'N', 'N', ms, nv, ms, cone, b, ib, jb, descb, q,
     $                iq, jq, descq, cnegone, c, ic, jc, descc )
*
         tstnrm = ( pslange( 'M', ms, nv, c, ic, jc, descc, work ) /
     $            anorm ) / ( max( ms, 1 )*ulp )
*
*
      ELSE IF( ibtype.EQ.2 ) THEN
*
*        Norm of ABQ - QD
*
*
*        C = BQ
*
         CALL psgemm( 'N', 'N', ms, nv, ms, cone, b, ib, jb, descb, q,
     $                iq, jq, descq, czero, c, ic, jc, descc )
*
*        Q = QD
*
         DO 20 i = 1, nv
            CALL psscal( ms, w( i ), q, iq, jq+i-1, descq, 1 )
   20    CONTINUE
*
*        Q = AC - Q
*
         CALL psgemm( 'N', 'N', ms, nv, ms, cone, a, ia, ja, desca, c,
     $                ic, jc, descc, cnegone, q, iq, jq, descq )
*
         tstnrm = ( pslange( 'M', ms, nv, q, iq, jq, descq, work ) /
     $            anorm ) / ( max( ms, 1 )*ulp )
*
      ELSE IF( ibtype.EQ.3 ) THEN
*
*        Norm of BAQ - QD
*
*
*        C = AQ
*
         CALL psgemm( 'N', 'N', ms, nv, ms, cone, a, ia, ja, desca, q,
     $                iq, jq, descq, czero, c, ic, jc, descc )
*
*        Q = QD
*
         DO 30 i = 1, nv
            CALL psscal( ms, w( i ), q, iq, jq+i-1, descq, 1 )
   30    CONTINUE
*
*        Q = BC - Q
*
         CALL psgemm( 'N', 'N', ms, nv, ms, cone, b, ib, jb, descb, c,
     $                ic, jc, descc, cnegone, q, iq, jq, descq )
*
         tstnrm = ( pslange( 'M', ms, nv, q, iq, jq, descq, work ) /
     $            anorm ) / ( max( ms, 1 )*ulp )
*
      END IF
*
      IF( tstnrm.GT.thresh .OR. ( tstnrm-tstnrm.NE.0.0e0 ) ) THEN
         result = 1
      END IF
      RETURN
*
*     End of PSGSEPCHK
*
      END