pcnepfchk.f

Go to the documentation of this file.

      SUBROUTINE pcnepfchk( N, A, IA, JA, DESCA, IASEED, Z, IZ, JZ,
     $                      DESCZ, ANORM, FRESID, WORK )
*
*  -- ScaLAPACK testing routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     March, 2000
*
*     .. Scalar Arguments ..
      INTEGER            IA, IASEED, IZ, JA, JZ, N
      REAL               ANORM, FRESID
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCZ( * )
      COMPLEX            A( * ), WORK( * ), Z( * )
*     ..
*
*  Purpose
*  =======
*
*  PCNEPFCHK computes the residual
*  || sub(Z)*sub( A )*sub(Z)**T - sub( Ao ) || / (||sub( Ao )||*eps*N),
*  where Ao will be regenerated by the parallel random matrix generator,
*  sub( A ) = A(IA:IA+M-1,JA:JA+N-1), sub( Z ) = Z(IZ:IZ+N-1,JZ:JZ+N-1)
*  and ||.|| stands for the infinity norm.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  N       (global input) INTEGER
*          The order of sub( A ) and sub( Z ). N >= 0.
*
*  A       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the N-by-N
*          distributed matrix sub( A ) to be checked. On exit, this
*          array contains the local pieces of the difference
*          sub(Z)*sub( A )*sub(Z)**T - sub( Ao ).
*
*  IA      (global input) INTEGER
*          A's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JA      (global input) INTEGER
*          A's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  IASEED  (global input) INTEGER
*          The seed number to generate the original matrix Ao.
*
*  Z       (local input) COMPLEX pointer into the local memory
*          to an array of dimension (LLD_Z,LOCc(JZ+N-1)). On entry, this
*          array contains the local pieces of the N-by-N distributed
*          matrix sub( Z ).
*
*  IZ      (global input) INTEGER
*          Z's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JZ      (global input) INTEGER
*          Z's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCZ   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix Z.
*
*  ANORM   (global input) REAL
*          The Infinity norm of sub( A ).
*
*  FRESID  (global output) REAL
*          The maximum (worst) factorizational error.
*
*  WORK    (local workspace) COMPLEX array, dimension (LWORK).
*          LWORK >= MAX( NpA0 * NB_A, MB_A * NqA0 ) where
*
*          IROFFA = MOD( IA-1, MB_A ),
*          ICOFFA = MOD( JA-1, NB_A ),
*          IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
*          IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
*          NpA0 = NUMROC( N+IROFFA, MB_A, MYROW, IAROW, NPROW ),
*          NqA0 = NUMROC( N+ICOFFA, NB_A, MYCOL, IACOL, NPCOL ),
*
*          WORK is used to store a block of rows and a block of columns
*          of sub( A ).
*          INDXG2P and NUMROC are ScaLAPACK tool functions; MYROW,
*          MYCOL, NPROW and NPCOL can be determined by calling the
*          subroutine BLACS_GRIDINFO.
*
*  Further Details
*  ===============
*
*  Contributed by Mark Fahey, March, 2000.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX            ONE, ZERO
      parameter( one = ( 1.0e+0, 0.0e+0 ),
     $                   zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IACOL, IAROW, IB, ICTXT, IIA, IOFFA, IROFF,
     $                   iw, j, jb, jja, jn, lda, ldw, mycol, myrow, np,
     $                   npcol, nprow
      REAL   EPS
*     ..
*     .. Local Arrays ..
      INTEGER            DESCW( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, infog2l, pcgemm,
     $                   pclacpy, pclaset, pcmatgen, cmatadd
*     ..
*     .. External Functions ..
      INTEGER            ICEIL, NUMROC
      REAL               PSLAMCH, PCLANGE
      EXTERNAL           iceil, numroc, pslamch, pclange
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, mod
*     ..
*     .. Executable Statements ..
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
      eps = pslamch( ictxt, 'eps' )
*
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia, jja,
     $              iarow, iacol )
      iroff = mod( ia-1, desca( mb_ ) )
      np = numroc( n+iroff, desca( mb_ ), myrow, iarow, nprow )
      IF( myrow.EQ.iarow )
     $   np = np - iroff
      ldw = max( 1, np )
*
*     First compute H <- H * Z**T
*
      CALL descset( descw, desca( mb_ ), n, desca( mb_ ), desca( nb_ ),
     $              iarow, iacol, ictxt, desca( mb_ ) )
*
      DO 10 i = ia, ia + n - 1, desca( mb_ )
         ib = min( ia+n-i, desca( mb_ ) )
*
         CALL pclacpy( 'All', ib, n, a, i, ja, desca, work, 1, 1,
     $                 descw )
         CALL pcgemm( 'No transpose', 'Cong Tran', ib, n, n, one, work,
     $                1, 1, descw, z, iz, jz, descz, zero, a, i, ja,
     $                desca )
*
         descw( rsrc_ ) = mod( descw( rsrc_ )+1, nprow )
*
   10 CONTINUE
*
*     Then compute H <- Z * H = Z * H0 * Z**T
*
      CALL descset( descw, n, desca( nb_ ), desca( mb_ ), desca( nb_ ),
     $              iarow, iacol, ictxt, ldw )
*
      DO 20 j = ja, ja + n - 1, desca( nb_ )
         jb = min( ja+n-j, desca( nb_ ) )
*
         CALL pclacpy( 'All', n, jb, a, ia, j, desca, work, 1, 1,
     $                 descw )
         CALL pcgemm( 'No transpose', 'No transpose', n, jb, n, one, z,
     $                iz, jz, descz, work, 1, 1, descw, zero, a, ia, j,
     $                desca )
*
         descw( csrc_ ) = mod( descw( csrc_ )+1, npcol )
*
   20 CONTINUE
*
*     Compute H - H0
*
      jn = min( iceil( ja, desca( nb_ ) )*desca( nb_ ), ja+n-1 )
      lda = desca( lld_ )
      ioffa = iia + ( jja-1 )*lda
      iw = 1
      jb = jn - ja + 1
      descw( csrc_ ) = iacol
*
*     Handle first block of columns separately
*
      IF( mycol.EQ.descw( csrc_ ) ) THEN
         CALL pcmatgen( ictxt, 'N', 'N', desca( m_ ), desca( n_ ),
     $                  desca( mb_ ), desca( nb_ ), work, ldw,
     $                  desca( rsrc_ ), desca( csrc_ ), iaseed, iia-1,
     $                  np, jja-1, jb, myrow, mycol, nprow, npcol )
         CALL pclaset( 'Lower', max( 0, n-2 ), jb, zero, zero, work,
     $                 min( iw+2, n ), 1, descw )
         CALL cmatadd( np, jb, -one, work, ldw, one, a( ioffa ), lda )
         jja = jja + jb
         ioffa = ioffa + jb*lda
      END IF
*
      iw = iw + desca( mb_ )
      descw( csrc_ ) = mod( descw( csrc_ )+1, npcol )
*
      DO 30 j = jn + 1, ja + n - 1, desca( nb_ )
         jb = min( ja+n-j, desca( nb_ ) )
*
         IF( mycol.EQ.descw( csrc_ ) ) THEN
            CALL pcmatgen( ictxt, 'N', 'N', desca( m_ ), desca( n_ ),
     $                     desca( mb_ ), desca( nb_ ), work, ldw,
     $                     desca( rsrc_ ), desca( csrc_ ), iaseed,
     $                     iia-1, np, jja-1, jb, myrow, mycol, nprow,
     $                     npcol )
            CALL pclaset( 'Lower', max( 0, n-iw-1 ), jb, zero, zero,
     $                    work, min( n, iw+2 ), 1, descw )
            CALL cmatadd( np, jb, -one, work, ldw, one, a( ioffa ),
     $                    lda )
            jja = jja + jb
            ioffa = ioffa + jb*lda
         END IF
         iw = iw + desca( mb_ )
         descw( csrc_ ) = mod( descw( csrc_ )+1, npcol )
   30 CONTINUE
*
*     Calculate factor residual
*
      fresid = pclange( 'I', n, n, a, ia, ja, desca, work ) /
     $         ( n*eps*anorm )
*
      RETURN
*
*     End PCNEPFCHK
*
      END