pclabrd.f

Go to the documentation of this file.

      SUBROUTINE pclabrd( M, N, NB, A, IA, JA, DESCA, D, E, TAUQ, TAUP,
     $                    X, IX, JX, DESCX, Y, IY, JY, DESCY, WORK )
*
*  -- ScaLAPACK auxiliary routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER             IA, IX, IY, JA, JX, JY, M, N, NB
*     ..
*     .. Array Arguments ..
      INTEGER             DESCA( * ), DESCX( * ), DESCY( * )
      REAL               D( * ), E( * )
      COMPLEX             A( * ), TAUP( * ), TAUQ( * ), X( * ), Y( * ),
     $                    work( * )
*     ..
*
*  Purpose
*  =======
*
*  PCLABRD reduces the first NB rows and columns of a complex general
*  M-by-N distributed matrix sub( A ) = A(IA:IA+M-1,JA:JA+N-1) to upper
*  or lower bidiagonal form by an unitary transformation Q' * A * P, and
*  returns the matrices X and Y which are needed to apply the transfor-
*  mation to the unreduced part of sub( A ).
*
*  If M >= N, sub( A ) is reduced to upper bidiagonal form; if M < N, to
*  lower bidiagonal form.
*
*  This is an auxiliary routine called by PCGEBRD.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  NB      (global input) INTEGER
*          The number of leading rows and columns of sub( A ) to be
*          reduced.
*
*  A       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          general distributed matrix sub( A ) to be reduced. On exit,
*          the first NB rows and columns of the matrix are overwritten;
*          the rest of the distributed matrix sub( A ) is unchanged.
*          If m >= n, elements on and below the diagonal in the first NB
*            columns, with the array TAUQ, represent the unitary
*            matrix Q as a product of elementary reflectors; and
*            elements above the diagonal in the first NB rows, with the
*            array TAUP, represent the unitary matrix P as a product
*            of elementary reflectors.
*          If m < n, elements below the diagonal in the first NB
*            columns, with the array TAUQ, represent the unitary
*            matrix Q as a product of elementary reflectors, and
*            elements on and above the diagonal in the first NB rows,
*            with the array TAUP, represent the unitary matrix P as
*            a product of elementary reflectors.
*          See Further Details.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  D       (local output) REAL array, dimension
*          LOCr(IA+MIN(M,N)-1) if M >= N; LOCc(JA+MIN(M,N)-1) otherwise.
*          The distributed diagonal elements of the bidiagonal matrix
*          B: D(i) = A(ia+i-1,ja+i-1). D is tied to the distributed
*          matrix A.
*
*  E       (local output) REAL array, dimension
*          LOCr(IA+MIN(M,N)-1) if M >= N; LOCc(JA+MIN(M,N)-2) otherwise.
*          The distributed off-diagonal elements of the bidiagonal
*          distributed matrix B:
*          if m >= n, E(i) = A(ia+i-1,ja+i) for i = 1,2,...,n-1;
*          if m < n, E(i) = A(ia+i,ja+i-1) for i = 1,2,...,m-1.
*          E is tied to the distributed matrix A.
*
*  TAUQ    (local output) COMPLEX array dimension
*          LOCc(JA+MIN(M,N)-1). The scalar factors of the elementary
*          reflectors which represent the unitary matrix Q. TAUQ is
*          tied to the distributed matrix A. See Further Details.
*
*  TAUP    (local output) COMPLEX array, dimension
*          LOCr(IA+MIN(M,N)-1). The scalar factors of the elementary
*          reflectors which represent the unitary matrix P. TAUP is
*          tied to the distributed matrix A. See Further Details.
*
*  X       (local output) COMPLEX pointer into the local memory
*          to an array of dimension (LLD_X,NB). On exit, the local
*          pieces of the distributed M-by-NB matrix
*          X(IX:IX+M-1,JX:JX+NB-1) required to update the unreduced
*          part of sub( A ).
*
*  IX      (global input) INTEGER
*          The row index in the global array X indicating the first
*          row of sub( X ).
*
*  JX      (global input) INTEGER
*          The column index in the global array X indicating the
*          first column of sub( X ).
*
*  DESCX   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix X.
*
*  Y       (local output) COMPLEX pointer into the local memory
*          to an array of dimension (LLD_Y,NB).  On exit, the local
*          pieces of the distributed N-by-NB matrix
*          Y(IY:IY+N-1,JY:JY+NB-1) required to update the unreduced
*          part of sub( A ).
*
*  IY      (global input) INTEGER
*          The row index in the global array Y indicating the first
*          row of sub( Y ).
*
*  JY      (global input) INTEGER
*          The column index in the global array Y indicating the
*          first column of sub( Y ).
*
*  DESCY   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix Y.
*
*  WORK    (local workspace) COMPLEX array, dimension (LWORK)
*          LWORK >= NB_A + NQ, with
*
*          NQ = NUMROC( N+MOD( IA-1, NB_Y ), NB_Y, MYCOL, IACOL, NPCOL )
*          IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL )
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*  Further Details
*  ===============
*
*  The matrices Q and P are represented as products of elementary
*  reflectors:
*
*     Q = H(1) H(2) . . . H(nb)  and  P = G(1) G(2) . . . G(nb)
*
*  Each H(i) and G(i) has the form:
*
*     H(i) = I - tauq * v * v'  and G(i) = I - taup * u * u'
*
*  where tauq and taup are complex scalars, and v and u are complex
*  vectors.
*
*  If m >= n, v(1:i-1) = 0, v(i) = 1, and v(i:m) is stored on exit in
*  A(ia+i-1:ia+m-1,ja+i-1); u(1:i) = 0, u(i+1) = 1, and u(i+1:n) is
*  stored on exit in A(ia+i-1,ja+i:ja+n-1); tauq is stored in
*  TAUQ(ja+i-1) and taup in TAUP(ia+i-1).
*
*  If m < n, v(1:i) = 0, v(i+1) = 1, and v(i+1:m) is stored on exit in
*  A(ia+i+1:ia+m-1,ja+i-1); u(1:i-1) = 0, u(i) = 1, and u(i:n) is
*  stored on exit in A(ia+i-1,ja+i:ja+n-1); tauq is stored in
*  TAUQ(ja+i-1) and taup in TAUP(ia+i-1).
*
*  The elements of the vectors v and u together form the m-by-nb matrix
*  V and the nb-by-n matrix U' which are needed, with X and Y, to apply
*  the transformation to the unreduced part of the matrix, using a block
*  update of the form:  sub( A ) := sub( A ) - V*Y' - X*U'.
*
*  The contents of sub( A ) on exit are illustrated by the following
*  examples with nb = 2:
*
*  m = 6 and n = 5 (m > n):          m = 5 and n = 6 (m < n):
*
*    (  1   1   u1  u1  u1 )           (  1   u1  u1  u1  u1  u1 )
*    (  v1  1   1   u2  u2 )           (  1   1   u2  u2  u2  u2 )
*    (  v1  v2  a   a   a  )           (  v1  1   a   a   a   a  )
*    (  v1  v2  a   a   a  )           (  v1  v2  a   a   a   a  )
*    (  v1  v2  a   a   a  )           (  v1  v2  a   a   a   a  )
*    (  v1  v2  a   a   a  )
*
*  where a denotes an element of the original matrix which is unchanged,
*  vi denotes an element of the vector defining H(i), and ui an element
*  of the vector defining G(i).
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX            ONE, ZERO
      parameter( one = ( 1.0e+0, 0.0e+0 ),
     $                   zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IACOL, IAROW, ICTXT, II, IPY, IW, J, JJ,
     $                   jwy, k, mycol, myrow, npcol, nprow
      COMPLEX            ALPHA, TAU
      INTEGER            DESCD( DLEN_ ), DESCE( DLEN_ ),
     $                   desctp( dlen_ ), desctq( dlen_ ),
     $                   descw( dlen_ ), descwy( dlen_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, infog2l, pccopy,
     $                   pcelget, pcelset, pcgemv, pclacgv,
     $                   pclarfg, pcscal, pselset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, min, mod
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, ii, jj,
     $              iarow, iacol )
      ipy = desca( mb_ ) + 1
      iw = mod( ia-1, desca( nb_ ) ) + 1
      alpha = zero
*
      CALL descset( descwy, 1, n+mod( ia-1, descy( nb_ ) ), 1,
     $              desca( nb_ ), iarow, iacol, ictxt, 1 )
      CALL descset( descw, desca( mb_ ), 1, desca( mb_ ), 1, iarow,
     $              iacol, ictxt, desca( mb_ ) )
      CALL descset( desctq, 1, ja+min(m,n)-1, 1, desca( nb_ ), iarow,
     $              desca( csrc_ ), desca( ctxt_ ), 1 )
      CALL descset( desctp, ia+min(m,n)-1, 1, desca( mb_ ), 1,
     $              desca( rsrc_ ), iacol, desca( ctxt_ ),
     $              desca( lld_ ) )
*
      IF( m.GE.n ) THEN
*
*        Reduce to upper bidiagonal form
*
         CALL descset( descd, 1, ja+min(m,n)-1, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
         CALL descset( desce, ia+min(m,n)-1, 1, desca( mb_ ), 1,
     $                 desca( rsrc_ ), mycol, desca( ctxt_ ),
     $                 desca( lld_ ) )
         DO 10 k = 1, nb
            i = ia + k - 1
            j = ja + k - 1
            jwy = iw + k
*
*           Update A(i:ia+m-1,j)
*
            IF( k.GT.1 ) THEN
               CALL pcgemv( 'No transpose', m-k+1, k-1, -one, a, i, ja,
     $                      desca, y, iy, jy+k-1, descy, 1, one, a, i,
     $                      j, desca, 1 )
               CALL pcgemv( 'No transpose', m-k+1, k-1, -one, x, ix+k-1,
     $                      jx, descx, a, ia, j, desca, 1, one, a, i, j,
     $                      desca, 1 )
               CALL pcelset( a, i-1, j, desca, alpha )
            END IF
*
*           Generate reflection Q(i) to annihilate A(i+1:ia+m-1,j)
*
            CALL pclarfg( m-k+1, alpha, i, j, a, i+1, j, desca, 1,
     $                    tauq )
            CALL pselset( d, 1, j, descd, real( alpha ) )
            CALL pcelset( a, i, j, desca, one )
*
*           Compute Y(IA+I:IA+N-1,J)
*
            CALL pcgemv( 'Conjugate transpose', m-k+1, n-k, one, a, i,
     $                   j+1, desca, a, i, j, desca, 1, zero,
     $                   work( ipy ), 1, jwy, descwy, descwy( m_ ) )
            CALL pcgemv( 'Conjugate transpose', m-k+1, k-1, one, a, i,
     $                   ja, desca, a, i, j, desca, 1, zero, work, iw,
     $                   1, descw, 1 )
            CALL pcgemv( 'Conjugate transpose', k-1, n-k, -one, y, iy,
     $                   jy+k, descy, work, iw, 1, descw, 1, one,
     $                   work( ipy ), 1, jwy, descwy, descwy( m_ ) )
            CALL pcgemv( 'Conjugate transpose', m-k+1, k-1, one, x,
     $                   ix+k-1, jx, descx, a, i, j, desca, 1, zero,
     $                   work, iw, 1, descw, 1 )
            CALL pcgemv( 'Conjugate transpose', k-1, n-k, -one, a, ia,
     $                   j+1, desca, work, iw, 1, descw, 1, one,
     $                   work( ipy ), 1, jwy, descwy, descwy( m_ ) )
*
            CALL pcelget( 'Rowwise', ' ', tau, tauq, 1, j, desctq )
            CALL pcscal( n-k, tau, work( ipy ), 1, jwy, descwy,
     $                   descwy( m_ ) )
            CALL pclacgv( n-k, work( ipy ), 1, jwy, descwy,
     $                    descwy( m_ ) )
            CALL pccopy( n-k, work( ipy ), 1, jwy, descwy, descwy( m_ ),
     $                   y, iy+k-1, jy+k, descy, descy( m_ ) )
*
*           Update A(i,j+1:ja+n-1)
*
            CALL pclacgv( n-k, a, i, j+1, desca, desca( m_ ) )
            CALL pclacgv( k, a, i, ja, desca, desca( m_ ) )
            CALL pcgemv( 'Conjugate transpose', k, n-k, -one, y, iy,
     $                   jy+k, descy, a, i, ja, desca, desca( m_ ), one,
     $                   a, i, j+1, desca, desca( m_ ) )
            CALL pclacgv( k, a, i, ja, desca, desca( m_ ) )
            CALL pclacgv( k-1, x, ix+k-1, jx, descx, descx( m_ ) )
            CALL pcgemv( 'Conjugate transpose', k-1, n-k, -one, a, ia,
     $                   j+1, desca, x, ix+k-1, jx, descx, descx( m_ ),
     $                   one, a, i, j+1, desca, desca( m_ ) )
            CALL pclacgv( k-1, x, ix+k-1, jx, descx, descx( m_ ) )
            CALL pcelset( a, i, j, desca, cmplx( real( alpha ) ) )
*
*           Generate reflection P(i) to annihilate A(i,j+2:ja+n-1)
*
            CALL pclarfg( n-k, alpha, i, j+1, a, i,
     $                    min( j+2, n+ja-1 ), desca, desca( m_ ), taup )
            CALL pselset( e, i, 1, desce, real( alpha ) )
            CALL pcelset( a, i, j+1, desca, one )
*
*           Compute X(I+1:IA+M-1,J)
*
            CALL pcgemv( 'No transpose', m-k, n-k, one, a, i+1, j+1,
     $                   desca, a, i, j+1, desca, desca( m_ ), zero, x,
     $                   ix+k, jx+k-1, descx, 1 )
            CALL pcgemv( 'No transpose', k, n-k, one, y, iy, jy+k,
     $                   descy, a, i, j+1, desca, desca( m_ ), zero,
     $                   work, iw, 1, descw, 1 )
            CALL pcgemv( 'No transpose', m-k, k, -one, a, i+1, ja,
     $                   desca, work, iw, 1, descw, 1, one, x, ix+k,
     $                   jx+k-1, descx, 1 )
            CALL pcgemv( 'No transpose', k-1, n-k, one, a, ia, j+1,
     $                   desca, a, i, j+1, desca, desca( m_ ), zero,
     $                   work, iw, 1, descw, 1 )
            CALL pcgemv( 'No transpose', m-k, k-1, -one, x, ix+k, jx,
     $                   descx, work, iw, 1, descw, 1, one, x, ix+k,
     $                   jx+k-1, descx, 1 )
*
            CALL pcelget( 'Columnwise', ' ', tau, taup, i, 1, desctp )
            CALL pcscal( m-k, tau, x, ix+k, jx+k-1, descx, 1 )
            CALL pclacgv( n-k, a, i, j+1, desca, desca( m_ ) )
   10    CONTINUE
*
      ELSE
*
*        Reduce to lower bidiagonal form
*
         CALL descset( descd, ia+min(m,n)-1, 1, desca( mb_ ), 1,
     $                 desca( rsrc_ ), mycol, desca( ctxt_ ),
     $                 desca( lld_ ) )
         CALL descset( desce, 1, ja+min(m,n)-1, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
         DO 20 k = 1, nb
            i = ia + k - 1
            j = ja + k - 1
            jwy = iw + k
*
*           Update A(i,j:ja+n-1)
*
            CALL pclacgv( n-k+1, a, i, j, desca, desca( m_ ) )
            IF( k.GT.1 ) THEN
               CALL pclacgv( k-1, a, i, ja, desca, desca( m_ ) )
               CALL pcgemv( 'Conjugate transpose', k-1, n-k+1, -one, y,
     $                      iy, jy+k-1, descy, a, i, ja, desca,
     $                      desca( m_ ), one, a, i, j, desca,
     $                      desca( m_ ) )
               CALL pclacgv( k-1, a, i, ja, desca, desca( m_ ) )
               CALL pclacgv( k-1, x, ix+k-1, jx, descx, descx( m_ ) )
               CALL pcgemv( 'Conjugate transpose', k-1, n-k+1, -one, a,
     $                      ia, j, desca, x, ix+k-1, jx, descx,
     $                      descx( m_ ), one, a, i, j, desca,
     $                      desca( m_ ) )
               CALL pclacgv( k-1, x, ix+k-1, jx, descx, descx( m_ ) )
               CALL pcelset( a, i, j-1, desca, cmplx( real( alpha ) ) )
            END IF
*
*           Generate reflection P(i) to annihilate A(i,j+1:ja+n-1)
*
            CALL pclarfg( n-k+1, alpha, i, j, a, i, j+1, desca,
     $                    desca( m_ ), taup )
            CALL pselset( d, i, 1, descd, real( alpha ) )
            CALL pcelset( a, i, j, desca, one )
*
*           Compute X(i+1:ia+m-1,j)
*
            CALL pcgemv( 'No transpose', m-k, n-k+1, one, a, i+1, j,
     $                   desca, a, i, j, desca, desca( m_ ), zero, x,
     $                   ix+k, jx+k-1, descx, 1 )
            CALL pcgemv( 'No transpose', k-1, n-k+1, one, y, iy, jy+k-1,
     $                   descy, a, i, j, desca, desca( m_ ), zero,
     $                   work, iw, 1, descw, 1 )
            CALL pcgemv( 'No transpose', m-k, k-1, -one, a, i+1, ja,
     $                   desca, work, iw, 1, descw, 1, one, x, ix+k,
     $                   jx+k-1, descx, 1 )
            CALL pcgemv( 'No transpose', k-1, n-k+1, one, a, ia, j,
     $                   desca, a, i, j, desca, desca( m_ ), zero,
     $                   work, iw, 1, descw, 1 )
            CALL pcgemv( 'No transpose', m-k, k-1, -one, x, ix+k, jx,
     $                   descx, work, iw, 1, descw, 1, one, x, ix+k,
     $                   jx+k-1, descx, 1 )
*
            CALL pcelget( 'Columnwise', ' ', tau, taup, i, 1, desctp )
            CALL pcscal( m-k, tau, x, ix+k, jx+k-1, descx, 1 )
            CALL pclacgv( n-k+1, a, i, j, desca, desca( m_ ) )
*
*           Update A(i+1:ia+m-1,j)
*
            CALL pcgemv( 'No transpose', m-k, k-1, -one, a, i+1, ja,
     $                   desca, y, iy, jy+k-1, descy, 1, one, a, i+1, j,
     $                   desca, 1 )
            CALL pcgemv( 'No transpose', m-k, k, -one, x, ix+k, jx,
     $                   descx, a, ia, j, desca, 1, one, a, i+1, j,
     $                   desca, 1 )
            CALL pcelset( a, i, j, desca, alpha )
*
*           Generate reflection Q(i) to annihilate A(i+2:ia+m-1,j)
*
            CALL pclarfg( m-k, alpha, i+1, j, a, min( i+2, m+ia-1 ),
     $                    j, desca, 1, tauq )
            CALL pselset( e, 1, j, desce, real( alpha ) )
            CALL pcelset( a, i+1, j, desca, one )
*
*           Compute Y(ia+i:ia+n-1,j)
*
            CALL pcgemv( 'Conjugate transpose', m-k, n-k, one, a, i+1,
     $                   j+1, desca, a, i+1, j, desca, 1, zero,
     $                   work( ipy ), 1, jwy, descwy, descwy( m_ ) )
            CALL pcgemv( 'Conjugate transpose', m-k, k-1, one, a, i+1,
     $                   ja, desca, a, i+1, j, desca, 1, zero, work, iw,
     $                   1, descw, 1 )
            CALL pcgemv( 'Conjugate transpose', k-1, n-k, -one, y, iy,
     $                   jy+k, descy, work, iw, 1, descw, 1, one,
     $                   work( ipy ), 1, jwy, descwy, descwy( m_ ) )
            CALL pcgemv( 'Conjugate transpose', m-k, k, one, x, ix+k,
     $                   jx, descx, a, i+1, j, desca, 1, zero, work, iw,
     $                   1, descw, 1 )
            CALL pcgemv( 'Conjugate transpose', k, n-k, -one, a, ia,
     $                   j+1, desca, work, iw, 1, descw, 1, one,
     $                   work( ipy ), 1, jwy, descwy, descwy( m_ ) )
*
            CALL pcelget( 'Rowwise', ' ', tau, tauq, 1, j, desctq )
            CALL pcscal( n-k, tau, work( ipy ), 1, jwy, descwy,
     $                   descwy( m_ ) )
            CALL pclacgv( n-k, work( ipy ), 1, jwy, descwy,
     $                    descwy( m_ ) )
            CALL pccopy( n-k, work( ipy ), 1, jwy, descwy, descwy( m_ ),
     $                   y, iy+k-1, jy+k, descy, descy( m_ ) )
   20    CONTINUE
      END IF
*
      RETURN
*
*     End of PCLABRD
*
      SUBROUTINE pclabrd( M, N, NB, A, IA, JA, DESCA, D, E, TAUQ, TAUP, …
      END