ssytrs_aa.f

Go to the documentation of this file.

*> \brief \b SSYTRS_AA
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download SSYTRS_AA + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ssytrs_aa.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ssytrs_aa.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ssytrs_aa.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE SSYTRS_AA( UPLO, N, NRHS, A, LDA, IPIV, B, LDB,
*                             WORK, LWORK, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            N, NRHS, LDA, LDB, LWORK, INFO
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       REAL   A( LDA, * ), B( LDB, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SSYTRS_AA solves a system of linear equations A*X = B with a real
*> symmetric matrix A using the factorization A = U**T*T*U or
*> A = L*T*L**T computed by SSYTRF_AA.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the details of the factorization are stored
*>          as an upper or lower triangular matrix.
*>          = 'U':  Upper triangular, form is A = U**T*T*U;
*>          = 'L':  Lower triangular, form is A = L*T*L**T.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of columns
*>          of the matrix B.  NRHS >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is REAL array, dimension (LDA,N)
*>          Details of factors computed by SSYTRF_AA.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>          Details of the interchanges as computed by SSYTRF_AA.
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is REAL array, dimension (LDB,NRHS)
*>          On entry, the right hand side matrix B.
*>          On exit, the solution matrix X.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (MAX(1,LWORK))
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.
*>          If MIN(N,NRHS) = 0, LWORK >= 1, else LWORK >= 3*N-2.
*>
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the minimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup hetrs_aa
*
*  =====================================================================
      SUBROUTINE ssytrs_aa( UPLO, N, NRHS, A, LDA, IPIV, B, LDB,
     $                      WORK, LWORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
      IMPLICIT NONE
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            N, NRHS, LDA, LDB, LWORK, INFO
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      REAL               A( LDA, * ), B( LDB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, UPPER
      INTEGER            K, KP, LWKMIN
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
      REAL               SROUNDUP_LWORK
      EXTERNAL           sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgtsv, sswap, slacpy, strsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min, max
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      lquery = ( lwork.EQ.-1 )
      IF( min( n, nrhs ).EQ.0 ) THEN
         lwkmin = 1
      ELSE
         lwkmin = 3*n-2
      END IF
*
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( lwork.LT.lwkmin .AND. .NOT.lquery ) THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SSYTRS_AA', -info )
         RETURN
      ELSE IF( lquery ) THEN
         work( 1 ) = sroundup_lwork( lwkmin )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( min( n, nrhs ).EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Solve A*X = B, where A = U**T*T*U.
*
*        1) Forward substitution with U**T
*
         IF( n.GT.1 ) THEN
*
*           Pivot, P**T * B -> B
*
            k = 1
            DO WHILE ( k.LE.n )
               kp = ipiv( k )
               IF( kp.NE.k )
     $             CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ),
     $                         ldb )
               k = k + 1
            END DO
*
*           Compute U**T \ B -> B    [ (U**T \P**T * B) ]
*
            CALL strsm( 'L', 'U', 'T', 'U', n-1, nrhs, one, a( 1,
     $                  2 ),
     $                  lda, b( 2, 1 ), ldb)
         END IF
*
*        2) Solve with triangular matrix T
*
*        Compute T \ B -> B   [ T \ (U**T \P**T * B) ]
*
         CALL slacpy( 'F', 1, n, a(1, 1), lda+1, work(n), 1)
         IF( n.GT.1 ) THEN
             CALL slacpy( 'F', 1, n-1, a(1, 2), lda+1, work(1), 1)
             CALL slacpy( 'F', 1, n-1, a(1, 2), lda+1, work(2*n), 1)
         END IF
         CALL sgtsv(n, nrhs, work(1), work(n), work(2*n), b, ldb,
     $              info)
*
*        3) Backward substitution with U
*
         IF( n.GT.1 ) THEN
*     
*
*           Compute U \ B -> B   [ U \ (T \ (U**T \P**T * B) ) ]
*
            CALL strsm( 'L', 'U', 'N', 'U', n-1, nrhs, one, a( 1,
     $                  2 ),
     $                  lda, b(2, 1), ldb)
*
*           Pivot, P * B -> B  [ P * (U \ (T \ (U**T \P**T * B) )) ]
*
            k = n
            DO WHILE ( k.GE.1 )
               kp = ipiv( k )
               IF( kp.NE.k )
     $            CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               k = k - 1
            END DO
         END IF
*
      ELSE
*
*        Solve A*X = B, where A = L*T*L**T.
*
*        1) Forward substitution with L
*
         IF( n.GT.1 ) THEN
*
*           Pivot, P**T * B -> B
*
            k = 1
            DO WHILE ( k.LE.n )
               kp = ipiv( k )
               IF( kp.NE.k )
     $            CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               k = k + 1
            END DO
*
*           Compute L \ B -> B    [ (L \P**T * B) ]
*
            CALL strsm( 'L', 'L', 'N', 'U', n-1, nrhs, one, a( 2, 1),
     $                  lda, b(2, 1), ldb)
         END IF
*
*        2) Solve with triangular matrix T
*
*        Compute T \ B -> B   [ T \ (L \P**T * B) ]
*
         CALL slacpy( 'F', 1, n, a(1, 1), lda+1, work(n), 1)
         IF( n.GT.1 ) THEN
             CALL slacpy( 'F', 1, n-1, a(2, 1), lda+1, work(1), 1)
             CALL slacpy( 'F', 1, n-1, a(2, 1), lda+1, work(2*n), 1)
         END IF
         CALL sgtsv(n, nrhs, work(1), work(n), work(2*n), b, ldb,
     $              info)
*
*        3) Backward substitution with L**T
*
         IF( n.GT.1 ) THEN
*
*           Compute L**T \ B -> B   [ L**T \ (T \ (L \P**T * B) ) ]
*
            CALL strsm( 'L', 'L', 'T', 'U', n-1, nrhs, one, a( 2,
     $                  1 ),
     $                  lda, b( 2, 1 ), ldb)
*
*           Pivot, P * B -> B  [ P * (L**T \ (T \ (L \P**T * B) )) ]
*
            k = n
            DO WHILE ( k.GE.1 )
               kp = ipiv( k )
               IF( kp.NE.k )
     $            CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               k = k - 1
            END DO
         END IF
*
      END IF
*
      RETURN
*
*     End of SSYTRS_AA
*
      END