LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ sorbdb1()

subroutine sorbdb1 ( integer m,
integer p,
integer q,
real, dimension(ldx11,*) x11,
integer ldx11,
real, dimension(ldx21,*) x21,
integer ldx21,
real, dimension(*) theta,
real, dimension(*) phi,
real, dimension(*) taup1,
real, dimension(*) taup2,
real, dimension(*) tauq1,
real, dimension(*) work,
integer lwork,
integer info )

SORBDB1

Download SORBDB1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> SORBDB1 simultaneously bidiagonalizes the blocks of a tall and skinny
!> matrix X with orthonormal columns:
!>
!>                            [ B11 ]
!>      [ X11 ]   [ P1 |    ] [  0  ]
!>      [-----] = [---------] [-----] Q1**T .
!>      [ X21 ]   [    | P2 ] [ B21 ]
!>                            [  0  ]
!>
!> X11 is P-by-Q, and X21 is (M-P)-by-Q. Q must be no larger than P,
!> M-P, or M-Q. Routines SORBDB2, SORBDB3, and SORBDB4 handle cases in
!> which Q is not the minimum dimension.
!>
!> The orthogonal matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
!> and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
!> Householder vectors.
!>
!> B11 and B12 are Q-by-Q bidiagonal matrices represented implicitly by
!> angles THETA, PHI.
!>
!>
Parameters
[in]M
!>          M is INTEGER
!>           The number of rows X11 plus the number of rows in X21.
!> 
[in]P
!>          P is INTEGER
!>           The number of rows in X11. 0 <= P <= M.
!> 
[in]Q
!>          Q is INTEGER
!>           The number of columns in X11 and X21. 0 <= Q <=
!>           MIN(P,M-P,M-Q).
!> 
[in,out]X11
!>          X11 is REAL array, dimension (LDX11,Q)
!>           On entry, the top block of the matrix X to be reduced. On
!>           exit, the columns of tril(X11) specify reflectors for P1 and
!>           the rows of triu(X11,1) specify reflectors for Q1.
!> 
[in]LDX11
!>          LDX11 is INTEGER
!>           The leading dimension of X11. LDX11 >= P.
!> 
[in,out]X21
!>          X21 is REAL array, dimension (LDX21,Q)
!>           On entry, the bottom block of the matrix X to be reduced. On
!>           exit, the columns of tril(X21) specify reflectors for P2.
!> 
[in]LDX21
!>          LDX21 is INTEGER
!>           The leading dimension of X21. LDX21 >= M-P.
!> 
[out]THETA
!>          THETA is REAL array, dimension (Q)
!>           The entries of the bidiagonal blocks B11, B21 are defined by
!>           THETA and PHI. See Further Details.
!> 
[out]PHI
!>          PHI is REAL array, dimension (Q-1)
!>           The entries of the bidiagonal blocks B11, B21 are defined by
!>           THETA and PHI. See Further Details.
!> 
[out]TAUP1
!>          TAUP1 is REAL array, dimension (P)
!>           The scalar factors of the elementary reflectors that define
!>           P1.
!> 
[out]TAUP2
!>          TAUP2 is REAL array, dimension (M-P)
!>           The scalar factors of the elementary reflectors that define
!>           P2.
!> 
[out]TAUQ1
!>          TAUQ1 is REAL array, dimension (Q)
!>           The scalar factors of the elementary reflectors that define
!>           Q1.
!> 
[out]WORK
!>          WORK is REAL array, dimension (LWORK)
!> 
[in]LWORK
!>          LWORK is INTEGER
!>           The dimension of the array WORK. LWORK >= M-Q.
!>
!>           If LWORK = -1, then a workspace query is assumed; the routine
!>           only calculates the optimal size of the WORK array, returns
!>           this value as the first entry of the WORK array, and no error
!>           message related to LWORK is issued by XERBLA.
!> 
[out]INFO
!>          INFO is INTEGER
!>           = 0:  successful exit.
!>           < 0:  if INFO = -i, the i-th argument had an illegal value.
!> 
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  The upper-bidiagonal blocks B11, B21 are represented implicitly by
!>  angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
!>  in each bidiagonal band is a product of a sine or cosine of a THETA
!>  with a sine or cosine of a PHI. See [1] or SORCSD for details.
!>
!>  P1, P2, and Q1 are represented as products of elementary reflectors.
!>  See SORCSD2BY1 for details on generating P1, P2, and Q1 using SORGQR
!>  and SORGLQ.
!> 
References:
[1] Brian D. Sutton. Computing the complete CS decomposition. Numer. Algorithms, 50(1):33-65, 2009.

Definition at line 199 of file sorbdb1.f.

202*
203* -- LAPACK computational routine --
204* -- LAPACK is a software package provided by Univ. of Tennessee, --
205* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
206*
207* .. Scalar Arguments ..
208 INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
209* ..
210* .. Array Arguments ..
211 REAL PHI(*), THETA(*)
212 REAL TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
213 $ X11(LDX11,*), X21(LDX21,*)
214* ..
215*
216* ====================================================================
217*
218* .. Local Scalars ..
219 REAL C, S
220 INTEGER CHILDINFO, I, ILARF, IORBDB5, LLARF, LORBDB5,
221 $ LWORKMIN, LWORKOPT
222 LOGICAL LQUERY
223* ..
224* .. External Subroutines ..
225 EXTERNAL slarf1f, slarfgp, sorbdb5, srot,
226 $ xerbla
227* ..
228* .. External Functions ..
229 REAL SNRM2
230 EXTERNAL snrm2
231* ..
232* .. Intrinsic Function ..
233 INTRINSIC atan2, cos, max, sin, sqrt
234* ..
235* .. Executable Statements ..
236*
237* Test input arguments
238*
239 info = 0
240 lquery = lwork .EQ. -1
241*
242 IF( m .LT. 0 ) THEN
243 info = -1
244 ELSE IF( p .LT. q .OR. m-p .LT. q ) THEN
245 info = -2
246 ELSE IF( q .LT. 0 .OR. m-q .LT. q ) THEN
247 info = -3
248 ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
249 info = -5
250 ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
251 info = -7
252 END IF
253*
254* Compute workspace
255*
256 IF( info .EQ. 0 ) THEN
257 ilarf = 2
258 llarf = max( p-1, m-p-1, q-1 )
259 iorbdb5 = 2
260 lorbdb5 = q-2
261 lworkopt = max( ilarf+llarf-1, iorbdb5+lorbdb5-1 )
262 lworkmin = lworkopt
263 work(1) = real( lworkopt )
264 IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
265 info = -14
266 END IF
267 END IF
268 IF( info .NE. 0 ) THEN
269 CALL xerbla( 'SORBDB1', -info )
270 RETURN
271 ELSE IF( lquery ) THEN
272 RETURN
273 END IF
274*
275* Reduce columns 1, ..., Q of X11 and X21
276*
277 DO i = 1, q
278*
279 CALL slarfgp( p-i+1, x11(i,i), x11(i+1,i), 1, taup1(i) )
280 CALL slarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
281 theta(i) = atan2( x21(i,i), x11(i,i) )
282 c = cos( theta(i) )
283 s = sin( theta(i) )
284 CALL slarf1f( 'L', p-i+1, q-i, x11(i,i), 1, taup1(i), x11(i,
285 $ i+1), ldx11, work(ilarf) )
286 CALL slarf1f( 'L', m-p-i+1, q-i, x21(i,i), 1, taup2(i),
287 $ x21(i,i+1), ldx21, work(ilarf) )
288*
289 IF( i .LT. q ) THEN
290 CALL srot( q-i, x11(i,i+1), ldx11, x21(i,i+1), ldx21, c,
291 $ s )
292 CALL slarfgp( q-i, x21(i,i+1), x21(i,i+2), ldx21,
293 $ tauq1(i) )
294 s = x21(i,i+1)
295 CALL slarf1f( 'R', p-i, q-i, x21(i,i+1), ldx21, tauq1(i),
296 $ x11(i+1,i+1), ldx11, work(ilarf) )
297 CALL slarf1f( 'R', m-p-i, q-i, x21(i,i+1), ldx21,
298 $ tauq1(i), x21(i+1,i+1), ldx21,
299 $ work(ilarf) )
300 c = sqrt( snrm2( p-i, x11(i+1,i+1), 1 )**2
301 $ + snrm2( m-p-i, x21(i+1,i+1), 1 )**2 )
302 phi(i) = atan2( s, c )
303 CALL sorbdb5( p-i, m-p-i, q-i-1, x11(i+1,i+1), 1,
304 $ x21(i+1,i+1), 1, x11(i+1,i+2), ldx11,
305 $ x21(i+1,i+2), ldx21, work(iorbdb5), lorbdb5,
306 $ childinfo )
307 END IF
308*
309 END DO
310*
311 RETURN
312*
313* End of SORBDB1
314*
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine slarfgp(n, alpha, x, incx, tau)
SLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition slarfgp.f:102
real(wp) function snrm2(n, x, incx)
SNRM2
Definition snrm2.f90:89
subroutine srot(n, sx, incx, sy, incy, c, s)
SROT
Definition srot.f:92
subroutine sorbdb5(m1, m2, n, x1, incx1, x2, incx2, q1, ldq1, q2, ldq2, work, lwork, info)
SORBDB5
Definition sorbdb5.f:155
subroutine slarf1f(side, m, n, v, incv, tau, c, ldc, work)
SLARF1F applies an elementary reflector to a general rectangular
Definition slarf1f.f:123
Here is the call graph for this function:
Here is the caller graph for this function: