LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
sspgvd.f
Go to the documentation of this file.
1 *> \brief \b SSPGVD
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SSPGVD + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sspgvd.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sspgvd.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sspgvd.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SSPGVD( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
22 * LWORK, IWORK, LIWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER JOBZ, UPLO
26 * INTEGER INFO, ITYPE, LDZ, LIWORK, LWORK, N
27 * ..
28 * .. Array Arguments ..
29 * INTEGER IWORK( * )
30 * REAL AP( * ), BP( * ), W( * ), WORK( * ),
31 * $ Z( LDZ, * )
32 * ..
33 *
34 *
35 *> \par Purpose:
36 * =============
37 *>
38 *> \verbatim
39 *>
40 *> SSPGVD computes all the eigenvalues, and optionally, the eigenvectors
41 *> of a real generalized symmetric-definite eigenproblem, of the form
42 *> A*x=(lambda)*B*x, A*Bx=(lambda)*x, or B*A*x=(lambda)*x. Here A and
43 *> B are assumed to be symmetric, stored in packed format, and B is also
44 *> positive definite.
45 *> If eigenvectors are desired, it uses a divide and conquer algorithm.
46 *>
47 *> The divide and conquer algorithm makes very mild assumptions about
48 *> floating point arithmetic. It will work on machines with a guard
49 *> digit in add/subtract, or on those binary machines without guard
50 *> digits which subtract like the Cray X-MP, Cray Y-MP, Cray C-90, or
51 *> Cray-2. It could conceivably fail on hexadecimal or decimal machines
52 *> without guard digits, but we know of none.
53 *> \endverbatim
54 *
55 * Arguments:
56 * ==========
57 *
58 *> \param[in] ITYPE
59 *> \verbatim
60 *> ITYPE is INTEGER
61 *> Specifies the problem type to be solved:
62 *> = 1: A*x = (lambda)*B*x
63 *> = 2: A*B*x = (lambda)*x
64 *> = 3: B*A*x = (lambda)*x
65 *> \endverbatim
66 *>
67 *> \param[in] JOBZ
68 *> \verbatim
69 *> JOBZ is CHARACTER*1
70 *> = 'N': Compute eigenvalues only;
71 *> = 'V': Compute eigenvalues and eigenvectors.
72 *> \endverbatim
73 *>
74 *> \param[in] UPLO
75 *> \verbatim
76 *> UPLO is CHARACTER*1
77 *> = 'U': Upper triangles of A and B are stored;
78 *> = 'L': Lower triangles of A and B are stored.
79 *> \endverbatim
80 *>
81 *> \param[in] N
82 *> \verbatim
83 *> N is INTEGER
84 *> The order of the matrices A and B. N >= 0.
85 *> \endverbatim
86 *>
87 *> \param[in,out] AP
88 *> \verbatim
89 *> AP is REAL array, dimension (N*(N+1)/2)
90 *> On entry, the upper or lower triangle of the symmetric matrix
91 *> A, packed columnwise in a linear array. The j-th column of A
92 *> is stored in the array AP as follows:
93 *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
94 *> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
95 *>
96 *> On exit, the contents of AP are destroyed.
97 *> \endverbatim
98 *>
99 *> \param[in,out] BP
100 *> \verbatim
101 *> BP is REAL array, dimension (N*(N+1)/2)
102 *> On entry, the upper or lower triangle of the symmetric matrix
103 *> B, packed columnwise in a linear array. The j-th column of B
104 *> is stored in the array BP as follows:
105 *> if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j;
106 *> if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n.
107 *>
108 *> On exit, the triangular factor U or L from the Cholesky
109 *> factorization B = U**T*U or B = L*L**T, in the same storage
110 *> format as B.
111 *> \endverbatim
112 *>
113 *> \param[out] W
114 *> \verbatim
115 *> W is REAL array, dimension (N)
116 *> If INFO = 0, the eigenvalues in ascending order.
117 *> \endverbatim
118 *>
119 *> \param[out] Z
120 *> \verbatim
121 *> Z is REAL array, dimension (LDZ, N)
122 *> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
123 *> eigenvectors. The eigenvectors are normalized as follows:
124 *> if ITYPE = 1 or 2, Z**T*B*Z = I;
125 *> if ITYPE = 3, Z**T*inv(B)*Z = I.
126 *> If JOBZ = 'N', then Z is not referenced.
127 *> \endverbatim
128 *>
129 *> \param[in] LDZ
130 *> \verbatim
131 *> LDZ is INTEGER
132 *> The leading dimension of the array Z. LDZ >= 1, and if
133 *> JOBZ = 'V', LDZ >= max(1,N).
134 *> \endverbatim
135 *>
136 *> \param[out] WORK
137 *> \verbatim
138 *> WORK is REAL array, dimension (MAX(1,LWORK))
139 *> On exit, if INFO = 0, WORK(1) returns the required LWORK.
140 *> \endverbatim
141 *>
142 *> \param[in] LWORK
143 *> \verbatim
144 *> LWORK is INTEGER
145 *> The dimension of the array WORK.
146 *> If N <= 1, LWORK >= 1.
147 *> If JOBZ = 'N' and N > 1, LWORK >= 2*N.
148 *> If JOBZ = 'V' and N > 1, LWORK >= 1 + 6*N + 2*N**2.
149 *>
150 *> If LWORK = -1, then a workspace query is assumed; the routine
151 *> only calculates the required sizes of the WORK and IWORK
152 *> arrays, returns these values as the first entries of the WORK
153 *> and IWORK arrays, and no error message related to LWORK or
154 *> LIWORK is issued by XERBLA.
155 *> \endverbatim
156 *>
157 *> \param[out] IWORK
158 *> \verbatim
159 *> IWORK is INTEGER array, dimension (MAX(1,LIWORK))
160 *> On exit, if INFO = 0, IWORK(1) returns the required LIWORK.
161 *> \endverbatim
162 *>
163 *> \param[in] LIWORK
164 *> \verbatim
165 *> LIWORK is INTEGER
166 *> The dimension of the array IWORK.
167 *> If JOBZ = 'N' or N <= 1, LIWORK >= 1.
168 *> If JOBZ = 'V' and N > 1, LIWORK >= 3 + 5*N.
169 *>
170 *> If LIWORK = -1, then a workspace query is assumed; the
171 *> routine only calculates the required sizes of the WORK and
172 *> IWORK arrays, returns these values as the first entries of
173 *> the WORK and IWORK arrays, and no error message related to
174 *> LWORK or LIWORK is issued by XERBLA.
175 *> \endverbatim
176 *>
177 *> \param[out] INFO
178 *> \verbatim
179 *> INFO is INTEGER
180 *> = 0: successful exit
181 *> < 0: if INFO = -i, the i-th argument had an illegal value
182 *> > 0: SPPTRF or SSPEVD returned an error code:
183 *> <= N: if INFO = i, SSPEVD failed to converge;
184 *> i off-diagonal elements of an intermediate
185 *> tridiagonal form did not converge to zero;
186 *> > N: if INFO = N + i, for 1 <= i <= N, then the leading
187 *> minor of order i of B is not positive definite.
188 *> The factorization of B could not be completed and
189 *> no eigenvalues or eigenvectors were computed.
190 *> \endverbatim
191 *
192 * Authors:
193 * ========
194 *
195 *> \author Univ. of Tennessee
196 *> \author Univ. of California Berkeley
197 *> \author Univ. of Colorado Denver
198 *> \author NAG Ltd.
199 *
200 *> \ingroup realOTHEReigen
201 *
202 *> \par Contributors:
203 * ==================
204 *>
205 *> Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
206 *
207 * =====================================================================
208  SUBROUTINE sspgvd( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
209  $ LWORK, IWORK, LIWORK, INFO )
210 *
211 * -- LAPACK driver routine --
212 * -- LAPACK is a software package provided by Univ. of Tennessee, --
213 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
214 *
215 * .. Scalar Arguments ..
216  CHARACTER JOBZ, UPLO
217  INTEGER INFO, ITYPE, LDZ, LIWORK, LWORK, N
218 * ..
219 * .. Array Arguments ..
220  INTEGER IWORK( * )
221  REAL AP( * ), BP( * ), W( * ), WORK( * ),
222  $ z( ldz, * )
223 * ..
224 *
225 * =====================================================================
226 *
227 * .. Local Scalars ..
228  LOGICAL LQUERY, UPPER, WANTZ
229  CHARACTER TRANS
230  INTEGER J, LIWMIN, LWMIN, NEIG
231 * ..
232 * .. External Functions ..
233  LOGICAL LSAME
234  EXTERNAL lsame
235 * ..
236 * .. External Subroutines ..
237  EXTERNAL spptrf, sspevd, sspgst, stpmv, stpsv, xerbla
238 * ..
239 * .. Intrinsic Functions ..
240  INTRINSIC max, real
241 * ..
242 * .. Executable Statements ..
243 *
244 * Test the input parameters.
245 *
246  wantz = lsame( jobz, 'V' )
247  upper = lsame( uplo, 'U' )
248  lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 )
249 *
250  info = 0
251  IF( itype.LT.1 .OR. itype.GT.3 ) THEN
252  info = -1
253  ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
254  info = -2
255  ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
256  info = -3
257  ELSE IF( n.LT.0 ) THEN
258  info = -4
259  ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
260  info = -9
261  END IF
262 *
263  IF( info.EQ.0 ) THEN
264  IF( n.LE.1 ) THEN
265  liwmin = 1
266  lwmin = 1
267  ELSE
268  IF( wantz ) THEN
269  liwmin = 3 + 5*n
270  lwmin = 1 + 6*n + 2*n**2
271  ELSE
272  liwmin = 1
273  lwmin = 2*n
274  END IF
275  END IF
276  work( 1 ) = lwmin
277  iwork( 1 ) = liwmin
278  IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
279  info = -11
280  ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
281  info = -13
282  END IF
283  END IF
284 *
285  IF( info.NE.0 ) THEN
286  CALL xerbla( 'SSPGVD', -info )
287  RETURN
288  ELSE IF( lquery ) THEN
289  RETURN
290  END IF
291 *
292 * Quick return if possible
293 *
294  IF( n.EQ.0 )
295  $ RETURN
296 *
297 * Form a Cholesky factorization of BP.
298 *
299  CALL spptrf( uplo, n, bp, info )
300  IF( info.NE.0 ) THEN
301  info = n + info
302  RETURN
303  END IF
304 *
305 * Transform problem to standard eigenvalue problem and solve.
306 *
307  CALL sspgst( itype, uplo, n, ap, bp, info )
308  CALL sspevd( jobz, uplo, n, ap, w, z, ldz, work, lwork, iwork,
309  $ liwork, info )
310  lwmin = max( real( lwmin ), real( work( 1 ) ) )
311  liwmin = max( real( liwmin ), real( iwork( 1 ) ) )
312 *
313  IF( wantz ) THEN
314 *
315 * Backtransform eigenvectors to the original problem.
316 *
317  neig = n
318  IF( info.GT.0 )
319  $ neig = info - 1
320  IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
321 *
322 * For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
323 * backtransform eigenvectors: x = inv(L)**T *y or inv(U)*y
324 *
325  IF( upper ) THEN
326  trans = 'N'
327  ELSE
328  trans = 'T'
329  END IF
330 *
331  DO 10 j = 1, neig
332  CALL stpsv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
333  $ 1 )
334  10 CONTINUE
335 *
336  ELSE IF( itype.EQ.3 ) THEN
337 *
338 * For B*A*x=(lambda)*x;
339 * backtransform eigenvectors: x = L*y or U**T *y
340 *
341  IF( upper ) THEN
342  trans = 'T'
343  ELSE
344  trans = 'N'
345  END IF
346 *
347  DO 20 j = 1, neig
348  CALL stpmv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
349  $ 1 )
350  20 CONTINUE
351  END IF
352  END IF
353 *
354  work( 1 ) = lwmin
355  iwork( 1 ) = liwmin
356 *
357  RETURN
358 *
359 * End of SSPGVD
360 *
361  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine sspgst(ITYPE, UPLO, N, AP, BP, INFO)
SSPGST
Definition: sspgst.f:113
subroutine spptrf(UPLO, N, AP, INFO)
SPPTRF
Definition: spptrf.f:119
subroutine sspevd(JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, LWORK, IWORK, LIWORK, INFO)
SSPEVD computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrice...
Definition: sspevd.f:178
subroutine sspgvd(ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK, LWORK, IWORK, LIWORK, INFO)
SSPGVD
Definition: sspgvd.f:210
subroutine stpmv(UPLO, TRANS, DIAG, N, AP, X, INCX)
STPMV
Definition: stpmv.f:142
subroutine stpsv(UPLO, TRANS, DIAG, N, AP, X, INCX)
STPSV
Definition: stpsv.f:144