LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
cunbdb2.f
Go to the documentation of this file.
1 *> \brief \b CUNBDB2
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CUNBDB2 + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunbdb2.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunbdb2.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunbdb2.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CUNBDB2( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
22 * TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
26 * ..
27 * .. Array Arguments ..
28 * REAL PHI(*), THETA(*)
29 * COMPLEX TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
30 * $ X11(LDX11,*), X21(LDX21,*)
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *>\verbatim
38 *>
39 *> CUNBDB2 simultaneously bidiagonalizes the blocks of a tall and skinny
40 *> matrix X with orthonomal columns:
41 *>
42 *> [ B11 ]
43 *> [ X11 ] [ P1 | ] [ 0 ]
44 *> [-----] = [---------] [-----] Q1**T .
45 *> [ X21 ] [ | P2 ] [ B21 ]
46 *> [ 0 ]
47 *>
48 *> X11 is P-by-Q, and X21 is (M-P)-by-Q. P must be no larger than M-P,
49 *> Q, or M-Q. Routines CUNBDB1, CUNBDB3, and CUNBDB4 handle cases in
50 *> which P is not the minimum dimension.
51 *>
52 *> The unitary matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
53 *> and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
54 *> Householder vectors.
55 *>
56 *> B11 and B12 are P-by-P bidiagonal matrices represented implicitly by
57 *> angles THETA, PHI.
58 *>
59 *>\endverbatim
60 *
61 * Arguments:
62 * ==========
63 *
64 *> \param[in] M
65 *> \verbatim
66 *> M is INTEGER
67 *> The number of rows X11 plus the number of rows in X21.
68 *> \endverbatim
69 *>
70 *> \param[in] P
71 *> \verbatim
72 *> P is INTEGER
73 *> The number of rows in X11. 0 <= P <= min(M-P,Q,M-Q).
74 *> \endverbatim
75 *>
76 *> \param[in] Q
77 *> \verbatim
78 *> Q is INTEGER
79 *> The number of columns in X11 and X21. 0 <= Q <= M.
80 *> \endverbatim
81 *>
82 *> \param[in,out] X11
83 *> \verbatim
84 *> X11 is COMPLEX array, dimension (LDX11,Q)
85 *> On entry, the top block of the matrix X to be reduced. On
86 *> exit, the columns of tril(X11) specify reflectors for P1 and
87 *> the rows of triu(X11,1) specify reflectors for Q1.
88 *> \endverbatim
89 *>
90 *> \param[in] LDX11
91 *> \verbatim
92 *> LDX11 is INTEGER
93 *> The leading dimension of X11. LDX11 >= P.
94 *> \endverbatim
95 *>
96 *> \param[in,out] X21
97 *> \verbatim
98 *> X21 is COMPLEX array, dimension (LDX21,Q)
99 *> On entry, the bottom block of the matrix X to be reduced. On
100 *> exit, the columns of tril(X21) specify reflectors for P2.
101 *> \endverbatim
102 *>
103 *> \param[in] LDX21
104 *> \verbatim
105 *> LDX21 is INTEGER
106 *> The leading dimension of X21. LDX21 >= M-P.
107 *> \endverbatim
108 *>
109 *> \param[out] THETA
110 *> \verbatim
111 *> THETA is REAL array, dimension (Q)
112 *> The entries of the bidiagonal blocks B11, B21 are defined by
113 *> THETA and PHI. See Further Details.
114 *> \endverbatim
115 *>
116 *> \param[out] PHI
117 *> \verbatim
118 *> PHI is REAL array, dimension (Q-1)
119 *> The entries of the bidiagonal blocks B11, B21 are defined by
120 *> THETA and PHI. See Further Details.
121 *> \endverbatim
122 *>
123 *> \param[out] TAUP1
124 *> \verbatim
125 *> TAUP1 is COMPLEX array, dimension (P)
126 *> The scalar factors of the elementary reflectors that define
127 *> P1.
128 *> \endverbatim
129 *>
130 *> \param[out] TAUP2
131 *> \verbatim
132 *> TAUP2 is COMPLEX array, dimension (M-P)
133 *> The scalar factors of the elementary reflectors that define
134 *> P2.
135 *> \endverbatim
136 *>
137 *> \param[out] TAUQ1
138 *> \verbatim
139 *> TAUQ1 is COMPLEX array, dimension (Q)
140 *> The scalar factors of the elementary reflectors that define
141 *> Q1.
142 *> \endverbatim
143 *>
144 *> \param[out] WORK
145 *> \verbatim
146 *> WORK is COMPLEX array, dimension (LWORK)
147 *> \endverbatim
148 *>
149 *> \param[in] LWORK
150 *> \verbatim
151 *> LWORK is INTEGER
152 *> The dimension of the array WORK. LWORK >= M-Q.
153 *>
154 *> If LWORK = -1, then a workspace query is assumed; the routine
155 *> only calculates the optimal size of the WORK array, returns
156 *> this value as the first entry of the WORK array, and no error
157 *> message related to LWORK is issued by XERBLA.
158 *> \endverbatim
159 *>
160 *> \param[out] INFO
161 *> \verbatim
162 *> INFO is INTEGER
163 *> = 0: successful exit.
164 *> < 0: if INFO = -i, the i-th argument had an illegal value.
165 *> \endverbatim
166 *>
167 *
168 * Authors:
169 * ========
170 *
171 *> \author Univ. of Tennessee
172 *> \author Univ. of California Berkeley
173 *> \author Univ. of Colorado Denver
174 *> \author NAG Ltd.
175 *
176 *> \ingroup complexOTHERcomputational
177 *
178 *> \par Further Details:
179 * =====================
180 *>
181 *> \verbatim
182 *>
183 *> The upper-bidiagonal blocks B11, B21 are represented implicitly by
184 *> angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
185 *> in each bidiagonal band is a product of a sine or cosine of a THETA
186 *> with a sine or cosine of a PHI. See [1] or CUNCSD for details.
187 *>
188 *> P1, P2, and Q1 are represented as products of elementary reflectors.
189 *> See CUNCSD2BY1 for details on generating P1, P2, and Q1 using CUNGQR
190 *> and CUNGLQ.
191 *> \endverbatim
192 *
193 *> \par References:
194 * ================
195 *>
196 *> [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
197 *> Algorithms, 50(1):33-65, 2009.
198 *>
199 * =====================================================================
200  SUBROUTINE cunbdb2( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
201  $ TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
202 *
203 * -- LAPACK computational routine --
204 * -- LAPACK is a software package provided by Univ. of Tennessee, --
205 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
206 *
207 * .. Scalar Arguments ..
208  INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
209 * ..
210 * .. Array Arguments ..
211  REAL PHI(*), THETA(*)
212  COMPLEX TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
213  $ x11(ldx11,*), x21(ldx21,*)
214 * ..
215 *
216 * ====================================================================
217 *
218 * .. Parameters ..
219  COMPLEX NEGONE, ONE
220  parameter( negone = (-1.0e0,0.0e0),
221  $ one = (1.0e0,0.0e0) )
222 * ..
223 * .. Local Scalars ..
224  REAL C, S
225  INTEGER CHILDINFO, I, ILARF, IORBDB5, LLARF, LORBDB5,
226  $ lworkmin, lworkopt
227  LOGICAL LQUERY
228 * ..
229 * .. External Subroutines ..
230  EXTERNAL clarf, clarfgp, cunbdb5, csrot, cscal, clacgv,
231  $ xerbla
232 * ..
233 * .. External Functions ..
234  REAL SCNRM2
235  EXTERNAL scnrm2
236 * ..
237 * .. Intrinsic Function ..
238  INTRINSIC atan2, cos, max, sin, sqrt
239 * ..
240 * .. Executable Statements ..
241 *
242 * Test input arguments
243 *
244  info = 0
245  lquery = lwork .EQ. -1
246 *
247  IF( m .LT. 0 ) THEN
248  info = -1
249  ELSE IF( p .LT. 0 .OR. p .GT. m-p ) THEN
250  info = -2
251  ELSE IF( q .LT. 0 .OR. q .LT. p .OR. m-q .LT. p ) THEN
252  info = -3
253  ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
254  info = -5
255  ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
256  info = -7
257  END IF
258 *
259 * Compute workspace
260 *
261  IF( info .EQ. 0 ) THEN
262  ilarf = 2
263  llarf = max( p-1, m-p, q-1 )
264  iorbdb5 = 2
265  lorbdb5 = q-1
266  lworkopt = max( ilarf+llarf-1, iorbdb5+lorbdb5-1 )
267  lworkmin = lworkopt
268  work(1) = lworkopt
269  IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
270  info = -14
271  END IF
272  END IF
273  IF( info .NE. 0 ) THEN
274  CALL xerbla( 'CUNBDB2', -info )
275  RETURN
276  ELSE IF( lquery ) THEN
277  RETURN
278  END IF
279 *
280 * Reduce rows 1, ..., P of X11 and X21
281 *
282  DO i = 1, p
283 *
284  IF( i .GT. 1 ) THEN
285  CALL csrot( q-i+1, x11(i,i), ldx11, x21(i-1,i), ldx21, c,
286  $ s )
287  END IF
288  CALL clacgv( q-i+1, x11(i,i), ldx11 )
289  CALL clarfgp( q-i+1, x11(i,i), x11(i,i+1), ldx11, tauq1(i) )
290  c = real( x11(i,i) )
291  x11(i,i) = one
292  CALL clarf( 'R', p-i, q-i+1, x11(i,i), ldx11, tauq1(i),
293  $ x11(i+1,i), ldx11, work(ilarf) )
294  CALL clarf( 'R', m-p-i+1, q-i+1, x11(i,i), ldx11, tauq1(i),
295  $ x21(i,i), ldx21, work(ilarf) )
296  CALL clacgv( q-i+1, x11(i,i), ldx11 )
297  s = sqrt( scnrm2( p-i, x11(i+1,i), 1 )**2
298  $ + scnrm2( m-p-i+1, x21(i,i), 1 )**2 )
299  theta(i) = atan2( s, c )
300 *
301  CALL cunbdb5( p-i, m-p-i+1, q-i, x11(i+1,i), 1, x21(i,i), 1,
302  $ x11(i+1,i+1), ldx11, x21(i,i+1), ldx21,
303  $ work(iorbdb5), lorbdb5, childinfo )
304  CALL cscal( p-i, negone, x11(i+1,i), 1 )
305  CALL clarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
306  IF( i .LT. p ) THEN
307  CALL clarfgp( p-i, x11(i+1,i), x11(i+2,i), 1, taup1(i) )
308  phi(i) = atan2( real( x11(i+1,i) ), real( x21(i,i) ) )
309  c = cos( phi(i) )
310  s = sin( phi(i) )
311  x11(i+1,i) = one
312  CALL clarf( 'L', p-i, q-i, x11(i+1,i), 1, conjg(taup1(i)),
313  $ x11(i+1,i+1), ldx11, work(ilarf) )
314  END IF
315  x21(i,i) = one
316  CALL clarf( 'L', m-p-i+1, q-i, x21(i,i), 1, conjg(taup2(i)),
317  $ x21(i,i+1), ldx21, work(ilarf) )
318 *
319  END DO
320 *
321 * Reduce the bottom-right portion of X21 to the identity matrix
322 *
323  DO i = p + 1, q
324  CALL clarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
325  x21(i,i) = one
326  CALL clarf( 'L', m-p-i+1, q-i, x21(i,i), 1, conjg(taup2(i)),
327  $ x21(i,i+1), ldx21, work(ilarf) )
328  END DO
329 *
330  RETURN
331 *
332 * End of CUNBDB2
333 *
334  END
335 
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine cscal(N, CA, CX, INCX)
CSCAL
Definition: cscal.f:78
subroutine csrot(N, CX, INCX, CY, INCY, C, S)
CSROT
Definition: csrot.f:98
subroutine clarfgp(N, ALPHA, X, INCX, TAU)
CLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: clarfgp.f:104
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:74
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:128
subroutine cunbdb2(M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI, TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO)
CUNBDB2
Definition: cunbdb2.f:202
subroutine cunbdb5(M1, M2, N, X1, INCX1, X2, INCX2, Q1, LDQ1, Q2, LDQ2, WORK, LWORK, INFO)
CUNBDB5
Definition: cunbdb5.f:156