clarf1f()

subroutine clarf1f	(	character	side,
		integer	m,
		integer	n,
		complex, dimension( * )	v,
		integer	incv,
		complex	tau,
		complex, dimension( ldc, * )	c,
		integer	ldc,
		complex, dimension( * )	work )

CLARF1F applies an elementary reflector to a general rectangular

Download CLARF1F + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CLARF1F applies a complex elementary reflector H to a complex m by n matrix
!> C, from either the left or the right. H is represented in the form
!>
!>       H = I - tau * v * v**H
!>
!> where tau is a complex scalar and v is a complex vector assuming v(1) = 1.
!>
!> If tau = 0, then H is taken to be the unit matrix.
!>
!> To apply H**H (the conjugate transpose of H), supply conjg(tau) instead
!> tau.
!> 

Parameters

[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'L': form H * C !> = 'R': form C * H !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix C. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix C. !>
[in]	V	!> V is COMPLEX array, dimension !> (1 + (M-1)*abs(INCV)) if SIDE = 'L' !> or (1 + (N-1)*abs(INCV)) if SIDE = 'R' !> The vector v in the representation of H. V is not used if !> TAU = 0. !>
[in]	INCV	!> INCV is INTEGER !> The increment between elements of v. INCV <> 0. !>
[in]	TAU	!> TAU is COMPLEX !> The value tau in the representation of H. !>
[in,out]	C	!> C is COMPLEX array, dimension (LDC,N) !> On entry, the m by n matrix C. !> On exit, C is overwritten by the matrix H * C if SIDE = 'L', !> or C * H if SIDE = 'R'. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[out]	WORK	!> WORK is COMPLEX array, dimension !> (N) if SIDE = 'L' !> or (M) if SIDE = 'R' !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 125 of file clarf1f.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE
      INTEGER            INCV, LDC, M, N
      COMPLEX            TAU
*     ..
*     .. Array Arguments ..
      COMPLEX            C( LDC, * ), V( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE, ZERO
      parameter( one = ( 1.0e+0, 0.0e+0 ),
     $                   zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            APPLYLEFT
      INTEGER            I, LASTV, LASTC
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemv, cger, cscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILACLR, ILACLC
      EXTERNAL           lsame, ilaclr, ilaclc
*     ..
*     .. Executable Statements ..
*
      applyleft = lsame( side, 'L' )
      lastv = 1
      lastc = 0
      IF( tau.NE.zero ) THEN
!     Set up variables for scanning V.  LASTV begins pointing to the end
!     of V up to V(1).
         IF( applyleft ) THEN
            lastv = m
         ELSE
            lastv = n
         END IF
         IF( incv.GT.0 ) THEN
            i = 1 + (lastv-1) * incv
         ELSE
            i = 1
         END IF
!     Look for the last non-zero row in V.
         DO WHILE( lastv.GT.1 .AND. v( i ).EQ.zero )
            lastv = lastv - 1
            i = i - incv
         END DO
         IF( applyleft ) THEN
!     Scan for the last non-zero column in C(1:lastv,:).
            lastc = ilaclc(lastv, n, c, ldc)
         ELSE
!     Scan for the last non-zero row in C(:,1:lastv).
            lastc = ilaclr(m, lastv, c, ldc)
         END IF
      END IF
      IF( lastc.EQ.0 ) THEN
         RETURN
      END IF
      IF( applyleft ) THEN
*
*        Form  H * C
*
         IF( lastv.EQ.1 ) THEN
*
*           C(1,1:lastc) := ( 1 - tau ) * C(1,1:lastc)
*
            CALL cscal( lastc, one - tau, c, ldc )
         ELSE
*
*        w(1:lastc,1) := C(2:lastv,1:lastc)**H * v(2:lastv,1)
*
         CALL cgemv( 'Conjugate transpose', lastv - 1, lastc, one,
     $               c( 2, 1 ), ldc, v( 1 + incv ), incv, zero,
     $               work, 1 )
*
*        w(1:lastc,1) += v(1,1) * C(1,1:lastc)**H
*
         DO i = 1, lastc
            work( i ) = work( i ) + conjg( c( 1, i ) )
         END DO
*
*        C(1, 1:lastc) += - tau * v(1,1) * w(1:lastc,1)**H
*
         DO i = 1, lastc
            c( 1, i ) = c( 1, i ) - tau * conjg( work( i ) )
         END DO
*
*        C(2:lastv,1:lastc) += - tau * v(2:lastv,1) * w(1:lastc,1)**H
*
         CALL cgerc( lastv - 1, lastc, -tau, v( 1 + incv ), incv,
     $               work, 1, c( 2, 1 ), ldc )
            END IF
      ELSE
*
*        Form  C * H
*
         IF( lastv.EQ.1 ) THEN
*
*           C(1:lastc,1) := ( 1 - tau ) * C(1:lastc,1)
*
            CALL cscal( lastc, one - tau, c, 1 )
         ELSE
*
*           w(1:lastc,1) := C(1:lastc,2:lastv) * v(2:lastv,1)
*
            CALL cgemv( 'No transpose', lastc, lastv - 1, one,
     $                  c( 1, 2 ), ldc, v( 1 + incv ), incv, zero,
     $                  work, 1 )
*
*           w(1:lastc,1) += v(1,1) * C(1:lastc,1)
*
            CALL caxpy( lastc, one, c, 1, work, 1 )
*
*           C(1:lastc,1) += - tau * v(1,1) * w(1:lastc,1)
*
            CALL caxpy( lastc, -tau, work, 1, c, 1 )
*
*           C(1:lastc,2:lastv) += - tau * w(1:lastc,1) * v(2:lastv)**H
*
            CALL cgerc( lastc, lastv - 1, -tau, work, 1,
     $                  v( 1 + incv ), incv, c( 1, 2 ), ldc )
         END IF
      END IF
      RETURN
*
*     End of CLARF1F
*

Here is the call graph for this function:

Here is the caller graph for this function: