LAPACK  3.10.1
LAPACK: Linear Algebra PACKage
zlangb.f
Go to the documentation of this file.
1 *> \brief \b ZLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of general band matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZLANGB + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlangb.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlangb.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlangb.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * DOUBLE PRECISION FUNCTION ZLANGB( NORM, N, KL, KU, AB, LDAB,
22 * WORK )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER NORM
26 * INTEGER KL, KU, LDAB, N
27 * ..
28 * .. Array Arguments ..
29 * DOUBLE PRECISION WORK( * )
30 * COMPLEX*16 AB( LDAB, * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> ZLANGB returns the value of the one norm, or the Frobenius norm, or
40 *> the infinity norm, or the element of largest absolute value of an
41 *> n by n band matrix A, with kl sub-diagonals and ku super-diagonals.
42 *> \endverbatim
43 *>
44 *> \return ZLANGB
45 *> \verbatim
46 *>
47 *> ZLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
48 *> (
49 *> ( norm1(A), NORM = '1', 'O' or 'o'
50 *> (
51 *> ( normI(A), NORM = 'I' or 'i'
52 *> (
53 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
54 *>
55 *> where norm1 denotes the one norm of a matrix (maximum column sum),
56 *> normI denotes the infinity norm of a matrix (maximum row sum) and
57 *> normF denotes the Frobenius norm of a matrix (square root of sum of
58 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
59 *> \endverbatim
60 *
61 * Arguments:
62 * ==========
63 *
64 *> \param[in] NORM
65 *> \verbatim
66 *> NORM is CHARACTER*1
67 *> Specifies the value to be returned in ZLANGB as described
68 *> above.
69 *> \endverbatim
70 *>
71 *> \param[in] N
72 *> \verbatim
73 *> N is INTEGER
74 *> The order of the matrix A. N >= 0. When N = 0, ZLANGB is
75 *> set to zero.
76 *> \endverbatim
77 *>
78 *> \param[in] KL
79 *> \verbatim
80 *> KL is INTEGER
81 *> The number of sub-diagonals of the matrix A. KL >= 0.
82 *> \endverbatim
83 *>
84 *> \param[in] KU
85 *> \verbatim
86 *> KU is INTEGER
87 *> The number of super-diagonals of the matrix A. KU >= 0.
88 *> \endverbatim
89 *>
90 *> \param[in] AB
91 *> \verbatim
92 *> AB is COMPLEX*16 array, dimension (LDAB,N)
93 *> The band matrix A, stored in rows 1 to KL+KU+1. The j-th
94 *> column of A is stored in the j-th column of the array AB as
95 *> follows:
96 *> AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
97 *> \endverbatim
98 *>
99 *> \param[in] LDAB
100 *> \verbatim
101 *> LDAB is INTEGER
102 *> The leading dimension of the array AB. LDAB >= KL+KU+1.
103 *> \endverbatim
104 *>
105 *> \param[out] WORK
106 *> \verbatim
107 *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
108 *> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
109 *> referenced.
110 *> \endverbatim
111 *
112 * Authors:
113 * ========
114 *
115 *> \author Univ. of Tennessee
116 *> \author Univ. of California Berkeley
117 *> \author Univ. of Colorado Denver
118 *> \author NAG Ltd.
119 *
120 *> \ingroup complex16GBauxiliary
121 *
122 * =====================================================================
123  DOUBLE PRECISION FUNCTION zlangb( NORM, N, KL, KU, AB, LDAB,
124  $ WORK )
125 *
126 * -- LAPACK auxiliary routine --
127 * -- LAPACK is a software package provided by Univ. of Tennessee, --
128 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
129 *
130 * .. Scalar Arguments ..
131  CHARACTER norm
132  INTEGER kl, ku, ldab, n
133 * ..
134 * .. Array Arguments ..
135  DOUBLE PRECISION work( * )
136  COMPLEX*16 ab( ldab, * )
137 * ..
138 *
139 * =====================================================================
140 *
141 * .. Parameters ..
142  DOUBLE PRECISION one, zero
143  parameter( one = 1.0d+0, zero = 0.0d+0 )
144 * ..
145 * .. Local Scalars ..
146  INTEGER i, j, k, l
147  DOUBLE PRECISION scale, sum, VALUE, temp
148 * ..
149 * .. External Functions ..
150  LOGICAL lsame, disnan
151  EXTERNAL lsame, disnan
152 * ..
153 * .. External Subroutines ..
154  EXTERNAL zlassq
155 * ..
156 * .. Intrinsic Functions ..
157  INTRINSIC abs, max, min, sqrt
158 * ..
159 * .. Executable Statements ..
160 *
161  IF( n.EQ.0 ) THEN
162  VALUE = zero
163  ELSE IF( lsame( norm, 'M' ) ) THEN
164 *
165 * Find max(abs(A(i,j))).
166 *
167  VALUE = zero
168  DO 20 j = 1, n
169  DO 10 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
170  temp = abs( ab( i, j ) )
171  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
172  10 CONTINUE
173  20 CONTINUE
174  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
175 *
176 * Find norm1(A).
177 *
178  VALUE = zero
179  DO 40 j = 1, n
180  sum = zero
181  DO 30 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
182  sum = sum + abs( ab( i, j ) )
183  30 CONTINUE
184  IF( VALUE.LT.sum .OR. disnan( sum ) ) VALUE = sum
185  40 CONTINUE
186  ELSE IF( lsame( norm, 'I' ) ) THEN
187 *
188 * Find normI(A).
189 *
190  DO 50 i = 1, n
191  work( i ) = zero
192  50 CONTINUE
193  DO 70 j = 1, n
194  k = ku + 1 - j
195  DO 60 i = max( 1, j-ku ), min( n, j+kl )
196  work( i ) = work( i ) + abs( ab( k+i, j ) )
197  60 CONTINUE
198  70 CONTINUE
199  VALUE = zero
200  DO 80 i = 1, n
201  temp = work( i )
202  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
203  80 CONTINUE
204  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
205 *
206 * Find normF(A).
207 *
208  scale = zero
209  sum = one
210  DO 90 j = 1, n
211  l = max( 1, j-ku )
212  k = ku + 1 - j + l
213  CALL zlassq( min( n, j+kl )-l+1, ab( k, j ), 1, scale, sum )
214  90 CONTINUE
215  VALUE = scale*sqrt( sum )
216  END IF
217 *
218  zlangb = VALUE
219  RETURN
220 *
221 * End of ZLANGB
222 *
223  END
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine zlassq(n, x, incx, scl, sumsq)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f90:137
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function zlangb(NORM, N, KL, KU, AB, LDAB, WORK)
ZLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: zlangb.f:125