dqrt12()

double precision function dqrt12	(	integer	m,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	s,
		double precision, dimension( lwork )	work,
		integer	lwork
	)

DQRT12

Purpose:

 DQRT12 computes the singular values `svlues' of the upper trapezoid
 of A(1:M,1:N) and returns the ratio

      || svlues - s ||/(||s||*eps*max(M,N))

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A.
[in]	N	N is INTEGER The number of columns of the matrix A.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) The M-by-N matrix A. Only the upper trapezoid is referenced.
[in]	LDA	LDA is INTEGER The leading dimension of the array A.
[in]	S	S is DOUBLE PRECISION array, dimension (min(M,N)) The singular values of the matrix A.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= max(M*N + 4*min(M,N) + max(M,N), M*N+2*MIN( M, N )+4*N).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 88 of file dqrt12.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), S( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, ISCL, J, MN
      DOUBLE PRECISION   ANRM, BIGNUM, NRMSVL, SMLNUM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DASUM, DLAMCH, DLANGE, DNRM2
      EXTERNAL           dasum, dlamch, dlange, dnrm2
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dbdsqr, dgebd2, dlascl, dlaset, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   DUMMY( 1 )
*     ..
*     .. Executable Statements ..
*
      dqrt12 = zero
*
*     Test that enough workspace is supplied
*
      IF( lwork.LT.max( m*n+4*min( m, n )+max( m, n ),
     $                  m*n+2*min( m, n )+4*n) ) THEN
         CALL xerbla( 'DQRT12', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      mn = min( m, n )
      IF( mn.LE.zero )
     $   RETURN
*
      nrmsvl = dnrm2( mn, s, 1 )
*
*     Copy upper triangle of A into work
*
      CALL dlaset( 'Full', m, n, zero, zero, work, m )
      DO j = 1, n
         DO i = 1, min( j, m )
            work( ( j-1 )*m+i ) = a( i, j )
         END DO
      END DO
*
*     Get machine parameters
*
      smlnum = dlamch( 'S' ) / dlamch( 'P' )
      bignum = one / smlnum
*
*     Scale work if max entry outside range [SMLNUM,BIGNUM]
*
      anrm = dlange( 'M', m, n, work, m, dummy )
      iscl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL dlascl( 'G', 0, 0, anrm, smlnum, m, n, work, m, info )
         iscl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL dlascl( 'G', 0, 0, anrm, bignum, m, n, work, m, info )
         iscl = 1
      END IF
*
      IF( anrm.NE.zero ) THEN
*
*        Compute SVD of work
*
         CALL dgebd2( m, n, work, m, work( m*n+1 ), work( m*n+mn+1 ),
     $                work( m*n+2*mn+1 ), work( m*n+3*mn+1 ),
     $                work( m*n+4*mn+1 ), info )
         CALL dbdsqr( 'Upper', mn, 0, 0, 0, work( m*n+1 ),
     $                work( m*n+mn+1 ), dummy, mn, dummy, 1, dummy, mn,
     $                work( m*n+2*mn+1 ), info )
*
         IF( iscl.EQ.1 ) THEN
            IF( anrm.GT.bignum ) THEN
               CALL dlascl( 'G', 0, 0, bignum, anrm, mn, 1,
     $                      work( m*n+1 ), mn, info )
            END IF
            IF( anrm.LT.smlnum ) THEN
               CALL dlascl( 'G', 0, 0, smlnum, anrm, mn, 1,
     $                      work( m*n+1 ), mn, info )
            END IF
         END IF
*
      ELSE
*
         DO i = 1, mn
            work( m*n+i ) = zero
         END DO
      END IF
*
*     Compare s and singular values of work
*
      CALL daxpy( mn, -one, s, 1, work( m*n+1 ), 1 )
*
      dqrt12 = dasum( mn, work( m*n+1 ), 1 ) /
     $  ( dlamch('Epsilon') * dble( max( m, n ) ) )
*
      IF( nrmsvl.NE.zero )
     $   dqrt12 = dqrt12 / nrmsvl
*
      RETURN
*
*     End of DQRT12
*

Here is the call graph for this function:

Here is the caller graph for this function: