LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
dsytrf_rook.f
Go to the documentation of this file.
1*> \brief \b DSYTRF_ROOK
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsytrf_rook.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsytrf_rook.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsytrf_rook.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE DSYTRF_ROOK( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
22*
23* .. Scalar Arguments ..
24* CHARACTER UPLO
25* INTEGER INFO, LDA, LWORK, N
26* ..
27* .. Array Arguments ..
28* INTEGER IPIV( * )
29* DOUBLE PRECISION A( LDA, * ), WORK( * )
30* ..
31*
32*
33*> \par Purpose:
34* =============
35*>
36*> \verbatim
37*>
38*> DSYTRF_ROOK computes the factorization of a real symmetric matrix A
39*> using the bounded Bunch-Kaufman ("rook") diagonal pivoting method.
40*> The form of the factorization is
41*>
42*> A = U*D*U**T or A = L*D*L**T
43*>
44*> where U (or L) is a product of permutation and unit upper (lower)
45*> triangular matrices, and D is symmetric and block diagonal with
46*> 1-by-1 and 2-by-2 diagonal blocks.
47*>
48*> This is the blocked version of the algorithm, calling Level 3 BLAS.
49*> \endverbatim
50*
51* Arguments:
52* ==========
53*
54*> \param[in] UPLO
55*> \verbatim
56*> UPLO is CHARACTER*1
57*> = 'U': Upper triangle of A is stored;
58*> = 'L': Lower triangle of A is stored.
59*> \endverbatim
60*>
61*> \param[in] N
62*> \verbatim
63*> N is INTEGER
64*> The order of the matrix A. N >= 0.
65*> \endverbatim
66*>
67*> \param[in,out] A
68*> \verbatim
69*> A is DOUBLE PRECISION array, dimension (LDA,N)
70*> On entry, the symmetric matrix A. If UPLO = 'U', the leading
71*> N-by-N upper triangular part of A contains the upper
72*> triangular part of the matrix A, and the strictly lower
73*> triangular part of A is not referenced. If UPLO = 'L', the
74*> leading N-by-N lower triangular part of A contains the lower
75*> triangular part of the matrix A, and the strictly upper
76*> triangular part of A is not referenced.
77*>
78*> On exit, the block diagonal matrix D and the multipliers used
79*> to obtain the factor U or L (see below for further details).
80*> \endverbatim
81*>
82*> \param[in] LDA
83*> \verbatim
84*> LDA is INTEGER
85*> The leading dimension of the array A. LDA >= max(1,N).
86*> \endverbatim
87*>
88*> \param[out] IPIV
89*> \verbatim
90*> IPIV is INTEGER array, dimension (N)
91*> Details of the interchanges and the block structure of D.
92*>
93*> If UPLO = 'U':
94*> If IPIV(k) > 0, then rows and columns k and IPIV(k)
95*> were interchanged and D(k,k) is a 1-by-1 diagonal block.
96*>
97*> If IPIV(k) < 0 and IPIV(k-1) < 0, then rows and
98*> columns k and -IPIV(k) were interchanged and rows and
99*> columns k-1 and -IPIV(k-1) were inerchaged,
100*> D(k-1:k,k-1:k) is a 2-by-2 diagonal block.
101*>
102*> If UPLO = 'L':
103*> If IPIV(k) > 0, then rows and columns k and IPIV(k)
104*> were interchanged and D(k,k) is a 1-by-1 diagonal block.
105*>
106*> If IPIV(k) < 0 and IPIV(k+1) < 0, then rows and
107*> columns k and -IPIV(k) were interchanged and rows and
108*> columns k+1 and -IPIV(k+1) were inerchaged,
109*> D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
110*> \endverbatim
111*>
112*> \param[out] WORK
113*> \verbatim
114*> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)).
115*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
116*> \endverbatim
117*>
118*> \param[in] LWORK
119*> \verbatim
120*> LWORK is INTEGER
121*> The length of WORK. LWORK >=1. For best performance
122*> LWORK >= N*NB, where NB is the block size returned by ILAENV.
123*>
124*> If LWORK = -1, then a workspace query is assumed; the routine
125*> only calculates the optimal size of the WORK array, returns
126*> this value as the first entry of the WORK array, and no error
127*> message related to LWORK is issued by XERBLA.
128*> \endverbatim
129*>
130*> \param[out] INFO
131*> \verbatim
132*> INFO is INTEGER
133*> = 0: successful exit
134*> < 0: if INFO = -i, the i-th argument had an illegal value
135*> > 0: if INFO = i, D(i,i) is exactly zero. The factorization
136*> has been completed, but the block diagonal matrix D is
137*> exactly singular, and division by zero will occur if it
138*> is used to solve a system of equations.
139*> \endverbatim
140*
141* Authors:
142* ========
143*
144*> \author Univ. of Tennessee
145*> \author Univ. of California Berkeley
146*> \author Univ. of Colorado Denver
147*> \author NAG Ltd.
148*
149*> \ingroup hetrf_rook
150*
151*> \par Further Details:
152* =====================
153*>
154*> \verbatim
155*>
156*> If UPLO = 'U', then A = U*D*U**T, where
157*> U = P(n)*U(n)* ... *P(k)U(k)* ...,
158*> i.e., U is a product of terms P(k)*U(k), where k decreases from n to
159*> 1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
160*> and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
161*> defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
162*> that if the diagonal block D(k) is of order s (s = 1 or 2), then
163*>
164*> ( I v 0 ) k-s
165*> U(k) = ( 0 I 0 ) s
166*> ( 0 0 I ) n-k
167*> k-s s n-k
168*>
169*> If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
170*> If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
171*> and A(k,k), and v overwrites A(1:k-2,k-1:k).
172*>
173*> If UPLO = 'L', then A = L*D*L**T, where
174*> L = P(1)*L(1)* ... *P(k)*L(k)* ...,
175*> i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
176*> n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
177*> and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
178*> defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
179*> that if the diagonal block D(k) is of order s (s = 1 or 2), then
180*>
181*> ( I 0 0 ) k-1
182*> L(k) = ( 0 I 0 ) s
183*> ( 0 v I ) n-k-s+1
184*> k-1 s n-k-s+1
185*>
186*> If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
187*> If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
188*> and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).
189*> \endverbatim
190*
191*> \par Contributors:
192* ==================
193*>
194*> \verbatim
195*>
196*> April 2012, Igor Kozachenko,
197*> Computer Science Division,
198*> University of California, Berkeley
199*>
200*> September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
201*> School of Mathematics,
202*> University of Manchester
203*>
204*> \endverbatim
205*
206* =====================================================================
207 SUBROUTINE dsytrf_rook( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
208*
209* -- LAPACK computational routine --
210* -- LAPACK is a software package provided by Univ. of Tennessee, --
211* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
212*
213* .. Scalar Arguments ..
214 CHARACTER UPLO
215 INTEGER INFO, LDA, LWORK, N
216* ..
217* .. Array Arguments ..
218 INTEGER IPIV( * )
219 DOUBLE PRECISION A( LDA, * ), WORK( * )
220* ..
221*
222* =====================================================================
223*
224* .. Local Scalars ..
225 LOGICAL LQUERY, UPPER
226 INTEGER IINFO, IWS, J, K, KB, LDWORK, LWKOPT, NB, NBMIN
227* ..
228* .. External Functions ..
229 LOGICAL LSAME
230 INTEGER ILAENV
231 EXTERNAL lsame, ilaenv
232* ..
233* .. External Subroutines ..
235* ..
236* .. Intrinsic Functions ..
237 INTRINSIC max
238* ..
239* .. Executable Statements ..
240*
241* Test the input parameters.
242*
243 info = 0
244 upper = lsame( uplo, 'U' )
245 lquery = ( lwork.EQ.-1 )
246 IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
247 info = -1
248 ELSE IF( n.LT.0 ) THEN
249 info = -2
250 ELSE IF( lda.LT.max( 1, n ) ) THEN
251 info = -4
252 ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
253 info = -7
254 END IF
255*
256 IF( info.EQ.0 ) THEN
257*
258* Determine the block size
259*
260 nb = ilaenv( 1, 'DSYTRF_ROOK', uplo, n, -1, -1, -1 )
261 lwkopt = max( 1, n*nb )
262 work( 1 ) = lwkopt
263 END IF
264*
265 IF( info.NE.0 ) THEN
266 CALL xerbla( 'DSYTRF_ROOK', -info )
267 RETURN
268 ELSE IF( lquery ) THEN
269 RETURN
270 END IF
271*
272 nbmin = 2
273 ldwork = n
274 IF( nb.GT.1 .AND. nb.LT.n ) THEN
275 iws = ldwork*nb
276 IF( lwork.LT.iws ) THEN
277 nb = max( lwork / ldwork, 1 )
278 nbmin = max( 2, ilaenv( 2, 'DSYTRF_ROOK',
279 \$ uplo, n, -1, -1, -1 ) )
280 END IF
281 ELSE
282 iws = 1
283 END IF
284 IF( nb.LT.nbmin )
285 \$ nb = n
286*
287 IF( upper ) THEN
288*
289* Factorize A as U*D*U**T using the upper triangle of A
290*
291* K is the main loop index, decreasing from N to 1 in steps of
292* KB, where KB is the number of columns factorized by DLASYF_ROOK;
293* KB is either NB or NB-1, or K for the last block
294*
295 k = n
296 10 CONTINUE
297*
298* If K < 1, exit from loop
299*
300 IF( k.LT.1 )
301 \$ GO TO 40
302*
303 IF( k.GT.nb ) THEN
304*
305* Factorize columns k-kb+1:k of A and use blocked code to
306* update columns 1:k-kb
307*
308 CALL dlasyf_rook( uplo, k, nb, kb, a, lda,
309 \$ ipiv, work, ldwork, iinfo )
310 ELSE
311*
312* Use unblocked code to factorize columns 1:k of A
313*
314 CALL dsytf2_rook( uplo, k, a, lda, ipiv, iinfo )
315 kb = k
316 END IF
317*
318* Set INFO on the first occurrence of a zero pivot
319*
320 IF( info.EQ.0 .AND. iinfo.GT.0 )
321 \$ info = iinfo
322*
323* No need to adjust IPIV
324*
325* Decrease K and return to the start of the main loop
326*
327 k = k - kb
328 GO TO 10
329*
330 ELSE
331*
332* Factorize A as L*D*L**T using the lower triangle of A
333*
334* K is the main loop index, increasing from 1 to N in steps of
335* KB, where KB is the number of columns factorized by DLASYF_ROOK;
336* KB is either NB or NB-1, or N-K+1 for the last block
337*
338 k = 1
339 20 CONTINUE
340*
341* If K > N, exit from loop
342*
343 IF( k.GT.n )
344 \$ GO TO 40
345*
346 IF( k.LE.n-nb ) THEN
347*
348* Factorize columns k:k+kb-1 of A and use blocked code to
349* update columns k+kb:n
350*
351 CALL dlasyf_rook( uplo, n-k+1, nb, kb, a( k, k ), lda,
352 \$ ipiv( k ), work, ldwork, iinfo )
353 ELSE
354*
355* Use unblocked code to factorize columns k:n of A
356*
357 CALL dsytf2_rook( uplo, n-k+1, a( k, k ), lda, ipiv( k ),
358 \$ iinfo )
359 kb = n - k + 1
360 END IF
361*
362* Set INFO on the first occurrence of a zero pivot
363*
364 IF( info.EQ.0 .AND. iinfo.GT.0 )
365 \$ info = iinfo + k - 1
366*
368*
369 DO 30 j = k, k + kb - 1
370 IF( ipiv( j ).GT.0 ) THEN
371 ipiv( j ) = ipiv( j ) + k - 1
372 ELSE
373 ipiv( j ) = ipiv( j ) - k + 1
374 END IF
375 30 CONTINUE
376*
377* Increase K and return to the start of the main loop
378*
379 k = k + kb
380 GO TO 20
381*
382 END IF
383*
384 40 CONTINUE
385 work( 1 ) = lwkopt
386 RETURN
387*
388* End of DSYTRF_ROOK
389*
390 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine dsytf2_rook(uplo, n, a, lda, ipiv, info)
DSYTF2_ROOK computes the factorization of a real symmetric indefinite matrix using the bounded Bunch-...
subroutine dsytrf_rook(uplo, n, a, lda, ipiv, work, lwork, info)
DSYTRF_ROOK
subroutine dlasyf_rook(uplo, n, nb, kb, a, lda, ipiv, w, ldw, info)
DLASYF_ROOK *> DLASYF_ROOK computes a partial factorization of a real symmetric matrix using the boun...