LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
dlansb.f
Go to the documentation of this file.
1 *> \brief \b DLANSB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a symmetric band matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DLANSB + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlansb.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlansb.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlansb.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * DOUBLE PRECISION FUNCTION DLANSB( NORM, UPLO, N, K, AB, LDAB,
22 * WORK )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER NORM, UPLO
26 * INTEGER K, LDAB, N
27 * ..
28 * .. Array Arguments ..
29 * DOUBLE PRECISION AB( LDAB, * ), WORK( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> DLANSB returns the value of the one norm, or the Frobenius norm, or
39 *> the infinity norm, or the element of largest absolute value of an
40 *> n by n symmetric band matrix A, with k super-diagonals.
41 *> \endverbatim
42 *>
43 *> \return DLANSB
44 *> \verbatim
45 *>
46 *> DLANSB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47 *> (
48 *> ( norm1(A), NORM = '1', 'O' or 'o'
49 *> (
50 *> ( normI(A), NORM = 'I' or 'i'
51 *> (
52 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53 *>
54 *> where norm1 denotes the one norm of a matrix (maximum column sum),
55 *> normI denotes the infinity norm of a matrix (maximum row sum) and
56 *> normF denotes the Frobenius norm of a matrix (square root of sum of
57 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] NORM
64 *> \verbatim
65 *> NORM is CHARACTER*1
66 *> Specifies the value to be returned in DLANSB as described
67 *> above.
68 *> \endverbatim
69 *>
70 *> \param[in] UPLO
71 *> \verbatim
72 *> UPLO is CHARACTER*1
73 *> Specifies whether the upper or lower triangular part of the
74 *> band matrix A is supplied.
75 *> = 'U': Upper triangular part is supplied
76 *> = 'L': Lower triangular part is supplied
77 *> \endverbatim
78 *>
79 *> \param[in] N
80 *> \verbatim
81 *> N is INTEGER
82 *> The order of the matrix A. N >= 0. When N = 0, DLANSB is
83 *> set to zero.
84 *> \endverbatim
85 *>
86 *> \param[in] K
87 *> \verbatim
88 *> K is INTEGER
89 *> The number of super-diagonals or sub-diagonals of the
90 *> band matrix A. K >= 0.
91 *> \endverbatim
92 *>
93 *> \param[in] AB
94 *> \verbatim
95 *> AB is DOUBLE PRECISION array, dimension (LDAB,N)
96 *> The upper or lower triangle of the symmetric band matrix A,
97 *> stored in the first K+1 rows of AB. The j-th column of A is
98 *> stored in the j-th column of the array AB as follows:
99 *> if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
100 *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+k).
101 *> \endverbatim
102 *>
103 *> \param[in] LDAB
104 *> \verbatim
105 *> LDAB is INTEGER
106 *> The leading dimension of the array AB. LDAB >= K+1.
107 *> \endverbatim
108 *>
109 *> \param[out] WORK
110 *> \verbatim
111 *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
112 *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
113 *> WORK is not referenced.
114 *> \endverbatim
115 *
116 * Authors:
117 * ========
118 *
119 *> \author Univ. of Tennessee
120 *> \author Univ. of California Berkeley
121 *> \author Univ. of Colorado Denver
122 *> \author NAG Ltd.
123 *
124 *> \ingroup doubleOTHERauxiliary
125 *
126 * =====================================================================
127  DOUBLE PRECISION FUNCTION dlansb( NORM, UPLO, N, K, AB, LDAB,
128  $ WORK )
129 *
130 * -- LAPACK auxiliary routine --
131 * -- LAPACK is a software package provided by Univ. of Tennessee, --
132 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
133 *
134  IMPLICIT NONE
135 * .. Scalar Arguments ..
136  CHARACTER norm, uplo
137  INTEGER k, ldab, n
138 * ..
139 * .. Array Arguments ..
140  DOUBLE PRECISION ab( ldab, * ), work( * )
141 * ..
142 *
143 * =====================================================================
144 *
145 * .. Parameters ..
146  DOUBLE PRECISION one, zero
147  parameter( one = 1.0d+0, zero = 0.0d+0 )
148 * ..
149 * .. Local Scalars ..
150  INTEGER i, j, l
151  DOUBLE PRECISION absa, sum, value
152 * ..
153 * .. Local Arrays ..
154  DOUBLE PRECISION ssq( 2 ), colssq( 2 )
155 * ..
156 * .. External Functions ..
157  LOGICAL lsame, disnan
158  EXTERNAL lsame, disnan
159 * ..
160 * .. External Subroutines ..
161  EXTERNAL dlassq, dcombssq
162 * ..
163 * .. Intrinsic Functions ..
164  INTRINSIC abs, max, min, sqrt
165 * ..
166 * .. Executable Statements ..
167 *
168  IF( n.EQ.0 ) THEN
169  VALUE = zero
170  ELSE IF( lsame( norm, 'M' ) ) THEN
171 *
172 * Find max(abs(A(i,j))).
173 *
174  VALUE = zero
175  IF( lsame( uplo, 'U' ) ) THEN
176  DO 20 j = 1, n
177  DO 10 i = max( k+2-j, 1 ), k + 1
178  sum = abs( ab( i, j ) )
179  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
180  10 CONTINUE
181  20 CONTINUE
182  ELSE
183  DO 40 j = 1, n
184  DO 30 i = 1, min( n+1-j, k+1 )
185  sum = abs( ab( i, j ) )
186  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
187  30 CONTINUE
188  40 CONTINUE
189  END IF
190  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
191  $ ( norm.EQ.'1' ) ) THEN
192 *
193 * Find normI(A) ( = norm1(A), since A is symmetric).
194 *
195  VALUE = zero
196  IF( lsame( uplo, 'U' ) ) THEN
197  DO 60 j = 1, n
198  sum = zero
199  l = k + 1 - j
200  DO 50 i = max( 1, j-k ), j - 1
201  absa = abs( ab( l+i, j ) )
202  sum = sum + absa
203  work( i ) = work( i ) + absa
204  50 CONTINUE
205  work( j ) = sum + abs( ab( k+1, j ) )
206  60 CONTINUE
207  DO 70 i = 1, n
208  sum = work( i )
209  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
210  70 CONTINUE
211  ELSE
212  DO 80 i = 1, n
213  work( i ) = zero
214  80 CONTINUE
215  DO 100 j = 1, n
216  sum = work( j ) + abs( ab( 1, j ) )
217  l = 1 - j
218  DO 90 i = j + 1, min( n, j+k )
219  absa = abs( ab( l+i, j ) )
220  sum = sum + absa
221  work( i ) = work( i ) + absa
222  90 CONTINUE
223  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
224  100 CONTINUE
225  END IF
226  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
227 *
228 * Find normF(A).
229 * SSQ(1) is scale
230 * SSQ(2) is sum-of-squares
231 * For better accuracy, sum each column separately.
232 *
233  ssq( 1 ) = zero
234  ssq( 2 ) = one
235 *
236 * Sum off-diagonals
237 *
238  IF( k.GT.0 ) THEN
239  IF( lsame( uplo, 'U' ) ) THEN
240  DO 110 j = 2, n
241  colssq( 1 ) = zero
242  colssq( 2 ) = one
243  CALL dlassq( min( j-1, k ), ab( max( k+2-j, 1 ), j ),
244  $ 1, colssq( 1 ), colssq( 2 ) )
245  CALL dcombssq( ssq, colssq )
246  110 CONTINUE
247  l = k + 1
248  ELSE
249  DO 120 j = 1, n - 1
250  colssq( 1 ) = zero
251  colssq( 2 ) = one
252  CALL dlassq( min( n-j, k ), ab( 2, j ), 1,
253  $ colssq( 1 ), colssq( 2 ) )
254  CALL dcombssq( ssq, colssq )
255  120 CONTINUE
256  l = 1
257  END IF
258  ssq( 2 ) = 2*ssq( 2 )
259  ELSE
260  l = 1
261  END IF
262 *
263 * Sum diagonal
264 *
265  colssq( 1 ) = zero
266  colssq( 2 ) = one
267  CALL dlassq( n, ab( l, 1 ), ldab, colssq( 1 ), colssq( 2 ) )
268  CALL dcombssq( ssq, colssq )
269  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
270  END IF
271 *
272  dlansb = VALUE
273  RETURN
274 *
275 * End of DLANSB
276 *
277  END
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine dlassq(n, x, incx, scl, sumsq)
DLASSQ updates a sum of squares represented in scaled form.
Definition: dlassq.f90:126
subroutine dcombssq(V1, V2)
DCOMBSSQ adds two scaled sum of squares quantities.
Definition: dcombssq.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function dlansb(NORM, UPLO, N, K, AB, LDAB, WORK)
DLANSB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: dlansb.f:129