LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
sgtcon.f
Go to the documentation of this file.
1*> \brief \b SGTCON
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgtcon.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgtcon.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgtcon.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE SGTCON( NORM, N, DL, D, DU, DU2, IPIV, ANORM, RCOND,
22* WORK, IWORK, INFO )
23*
24* .. Scalar Arguments ..
25* CHARACTER NORM
26* INTEGER INFO, N
27* REAL ANORM, RCOND
28* ..
29* .. Array Arguments ..
30* INTEGER IPIV( * ), IWORK( * )
31* REAL D( * ), DL( * ), DU( * ), DU2( * ), WORK( * )
32* ..
33*
34*
35*> \par Purpose:
36* =============
37*>
38*> \verbatim
39*>
40*> SGTCON estimates the reciprocal of the condition number of a real
41*> tridiagonal matrix A using the LU factorization as computed by
42*> SGTTRF.
43*>
44*> An estimate is obtained for norm(inv(A)), and the reciprocal of the
45*> condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
46*> \endverbatim
47*
48* Arguments:
49* ==========
50*
51*> \param[in] NORM
52*> \verbatim
53*> NORM is CHARACTER*1
54*> Specifies whether the 1-norm condition number or the
55*> infinity-norm condition number is required:
56*> = '1' or 'O': 1-norm;
57*> = 'I': Infinity-norm.
58*> \endverbatim
59*>
60*> \param[in] N
61*> \verbatim
62*> N is INTEGER
63*> The order of the matrix A. N >= 0.
64*> \endverbatim
65*>
66*> \param[in] DL
67*> \verbatim
68*> DL is REAL array, dimension (N-1)
69*> The (n-1) multipliers that define the matrix L from the
70*> LU factorization of A as computed by SGTTRF.
71*> \endverbatim
72*>
73*> \param[in] D
74*> \verbatim
75*> D is REAL array, dimension (N)
76*> The n diagonal elements of the upper triangular matrix U from
77*> the LU factorization of A.
78*> \endverbatim
79*>
80*> \param[in] DU
81*> \verbatim
82*> DU is REAL array, dimension (N-1)
83*> The (n-1) elements of the first superdiagonal of U.
84*> \endverbatim
85*>
86*> \param[in] DU2
87*> \verbatim
88*> DU2 is REAL array, dimension (N-2)
89*> The (n-2) elements of the second superdiagonal of U.
90*> \endverbatim
91*>
92*> \param[in] IPIV
93*> \verbatim
94*> IPIV is INTEGER array, dimension (N)
95*> The pivot indices; for 1 <= i <= n, row i of the matrix was
96*> interchanged with row IPIV(i). IPIV(i) will always be either
97*> i or i+1; IPIV(i) = i indicates a row interchange was not
98*> required.
99*> \endverbatim
100*>
101*> \param[in] ANORM
102*> \verbatim
103*> ANORM is REAL
104*> If NORM = '1' or 'O', the 1-norm of the original matrix A.
105*> If NORM = 'I', the infinity-norm of the original matrix A.
106*> \endverbatim
107*>
108*> \param[out] RCOND
109*> \verbatim
110*> RCOND is REAL
111*> The reciprocal of the condition number of the matrix A,
112*> computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
113*> estimate of the 1-norm of inv(A) computed in this routine.
114*> \endverbatim
115*>
116*> \param[out] WORK
117*> \verbatim
118*> WORK is REAL array, dimension (2*N)
119*> \endverbatim
120*>
121*> \param[out] IWORK
122*> \verbatim
123*> IWORK is INTEGER array, dimension (N)
124*> \endverbatim
125*>
126*> \param[out] INFO
127*> \verbatim
128*> INFO is INTEGER
129*> = 0: successful exit
130*> < 0: if INFO = -i, the i-th argument had an illegal value
131*> \endverbatim
132*
133* Authors:
134* ========
135*
136*> \author Univ. of Tennessee
137*> \author Univ. of California Berkeley
138*> \author Univ. of Colorado Denver
139*> \author NAG Ltd.
140*
141*> \ingroup gtcon
142*
143* =====================================================================
144 SUBROUTINE sgtcon( NORM, N, DL, D, DU, DU2, IPIV, ANORM, RCOND,
145 \$ WORK, IWORK, INFO )
146*
147* -- LAPACK computational routine --
148* -- LAPACK is a software package provided by Univ. of Tennessee, --
149* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
150*
151* .. Scalar Arguments ..
152 CHARACTER NORM
153 INTEGER INFO, N
154 REAL ANORM, RCOND
155* ..
156* .. Array Arguments ..
157 INTEGER IPIV( * ), IWORK( * )
158 REAL D( * ), DL( * ), DU( * ), DU2( * ), WORK( * )
159* ..
160*
161* =====================================================================
162*
163* .. Parameters ..
164 REAL ONE, ZERO
165 parameter( one = 1.0e+0, zero = 0.0e+0 )
166* ..
167* .. Local Scalars ..
168 LOGICAL ONENRM
169 INTEGER I, KASE, KASE1
170 REAL AINVNM
171* ..
172* .. Local Arrays ..
173 INTEGER ISAVE( 3 )
174* ..
175* .. External Functions ..
176 LOGICAL LSAME
177 EXTERNAL lsame
178* ..
179* .. External Subroutines ..
180 EXTERNAL sgttrs, slacn2, xerbla
181* ..
182* .. Executable Statements ..
183*
184* Test the input arguments.
185*
186 info = 0
187 onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
188 IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
189 info = -1
190 ELSE IF( n.LT.0 ) THEN
191 info = -2
192 ELSE IF( anorm.LT.zero ) THEN
193 info = -8
194 END IF
195 IF( info.NE.0 ) THEN
196 CALL xerbla( 'SGTCON', -info )
197 RETURN
198 END IF
199*
200* Quick return if possible
201*
202 rcond = zero
203 IF( n.EQ.0 ) THEN
204 rcond = one
205 RETURN
206 ELSE IF( anorm.EQ.zero ) THEN
207 RETURN
208 END IF
209*
210* Check that D(1:N) is non-zero.
211*
212 DO 10 i = 1, n
213 IF( d( i ).EQ.zero )
214 \$ RETURN
215 10 CONTINUE
216*
217 ainvnm = zero
218 IF( onenrm ) THEN
219 kase1 = 1
220 ELSE
221 kase1 = 2
222 END IF
223 kase = 0
224 20 CONTINUE
225 CALL slacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
226 IF( kase.NE.0 ) THEN
227 IF( kase.EQ.kase1 ) THEN
228*
229* Multiply by inv(U)*inv(L).
230*
231 CALL sgttrs( 'No transpose', n, 1, dl, d, du, du2, ipiv,
232 \$ work, n, info )
233 ELSE
234*
235* Multiply by inv(L**T)*inv(U**T).
236*
237 CALL sgttrs( 'Transpose', n, 1, dl, d, du, du2, ipiv, work,
238 \$ n, info )
239 END IF
240 GO TO 20
241 END IF
242*
243* Compute the estimate of the reciprocal condition number.
244*
245 IF( ainvnm.NE.zero )
246 \$ rcond = ( one / ainvnm ) / anorm
247*
248 RETURN
249*
250* End of SGTCON
251*
252 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine sgtcon(norm, n, dl, d, du, du2, ipiv, anorm, rcond, work, iwork, info)
SGTCON
Definition sgtcon.f:146
subroutine sgttrs(trans, n, nrhs, dl, d, du, du2, ipiv, b, ldb, info)
SGTTRS
Definition sgttrs.f:138
subroutine slacn2(n, v, x, isgn, est, kase, isave)
SLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition slacn2.f:136