srzt01()

real function srzt01	(	integer	m,
		integer	n,
		real, dimension( lda, * )	a,
		real, dimension( lda, * )	af,
		integer	lda,
		real, dimension( * )	tau,
		real, dimension( lwork )	work,
		integer	lwork
	)

SRZT01

Purpose:

 SRZT01 returns
      || A - R*Q || / ( M * eps * ||A|| )
 for an upper trapezoidal A that was factored with STZRZF.

Parameters

[in]	M	M is INTEGER The number of rows of the matrices A and AF.
[in]	N	N is INTEGER The number of columns of the matrices A and AF.
[in]	A	A is REAL array, dimension (LDA,N) The original upper trapezoidal M by N matrix A.
[in]	AF	AF is REAL array, dimension (LDA,N) The output of STZRZF for input matrix A. The lower triangle is not referenced.
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A and AF.
[in]	TAU	TAU is REAL array, dimension (M) Details of the Householder transformations as returned by STZRZF.
[out]	WORK	WORK is REAL array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= m*n + m*nb.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 96 of file srzt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), AF( LDA, * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, J
      REAL               NORMA
*     ..
*     .. Local Arrays ..
      REAL               RWORK( 1 )
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLANGE
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, slaset, sormrz, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real
*     ..
*     .. Executable Statements ..
*
      srzt01 = zero
*
      IF( lwork.LT.m*n+m ) THEN
         CALL xerbla( 'SRZT01', 8 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      norma = slange( 'One-norm', m, n, a, lda, rwork )
*
*     Copy upper triangle R
*
      CALL slaset( 'Full', m, n, zero, zero, work, m )
      DO 20 j = 1, m
         DO 10 i = 1, j
            work( ( j-1 )*m+i ) = af( i, j )
   10    CONTINUE
   20 CONTINUE
*
*     R = R * P(1) * ... *P(m)
*
      CALL sormrz( 'Right', 'No transpose', m, n, m, n-m, af, lda, tau,
     $             work, m, work( m*n+1 ), lwork-m*n, info )
*
*     R = R - A
*
      DO 30 i = 1, n
         CALL saxpy( m, -one, a( 1, i ), 1, work( ( i-1 )*m+1 ), 1 )
   30 CONTINUE
*
      srzt01 = slange( 'One-norm', m, n, work, m, rwork )
*
      srzt01 = srzt01 / ( slamch( 'Epsilon' )*real( max( m, n ) ) )
      IF( norma.NE.zero )
     $   srzt01 = srzt01 / norma
*
      RETURN
*
*     End of SRZT01
*

Here is the call graph for this function:

Here is the caller graph for this function: