LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
zhpev.f
Go to the documentation of this file.
1*> \brief <b> ZHPEV computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices</b>
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zhpev.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zhpev.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zhpev.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE ZHPEV( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, RWORK,
22* INFO )
23*
24* .. Scalar Arguments ..
25* CHARACTER JOBZ, UPLO
26* INTEGER INFO, LDZ, N
27* ..
28* .. Array Arguments ..
29* DOUBLE PRECISION RWORK( * ), W( * )
30* COMPLEX*16 AP( * ), WORK( * ), Z( LDZ, * )
31* ..
32*
33*
34*> \par Purpose:
35* =============
36*>
37*> \verbatim
38*>
39*> ZHPEV computes all the eigenvalues and, optionally, eigenvectors of a
40*> complex Hermitian matrix in packed storage.
41*> \endverbatim
42*
43* Arguments:
44* ==========
45*
46*> \param[in] JOBZ
47*> \verbatim
48*> JOBZ is CHARACTER*1
49*> = 'N': Compute eigenvalues only;
50*> = 'V': Compute eigenvalues and eigenvectors.
51*> \endverbatim
52*>
53*> \param[in] UPLO
54*> \verbatim
55*> UPLO is CHARACTER*1
56*> = 'U': Upper triangle of A is stored;
57*> = 'L': Lower triangle of A is stored.
58*> \endverbatim
59*>
60*> \param[in] N
61*> \verbatim
62*> N is INTEGER
63*> The order of the matrix A. N >= 0.
64*> \endverbatim
65*>
66*> \param[in,out] AP
67*> \verbatim
68*> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
69*> On entry, the upper or lower triangle of the Hermitian matrix
70*> A, packed columnwise in a linear array. The j-th column of A
71*> is stored in the array AP as follows:
72*> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
73*> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
74*>
75*> On exit, AP is overwritten by values generated during the
76*> reduction to tridiagonal form. If UPLO = 'U', the diagonal
77*> and first superdiagonal of the tridiagonal matrix T overwrite
78*> the corresponding elements of A, and if UPLO = 'L', the
79*> diagonal and first subdiagonal of T overwrite the
80*> corresponding elements of A.
81*> \endverbatim
82*>
83*> \param[out] W
84*> \verbatim
85*> W is DOUBLE PRECISION array, dimension (N)
86*> If INFO = 0, the eigenvalues in ascending order.
87*> \endverbatim
88*>
89*> \param[out] Z
90*> \verbatim
91*> Z is COMPLEX*16 array, dimension (LDZ, N)
92*> If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal
93*> eigenvectors of the matrix A, with the i-th column of Z
94*> holding the eigenvector associated with W(i).
95*> If JOBZ = 'N', then Z is not referenced.
96*> \endverbatim
97*>
98*> \param[in] LDZ
99*> \verbatim
100*> LDZ is INTEGER
101*> The leading dimension of the array Z. LDZ >= 1, and if
102*> JOBZ = 'V', LDZ >= max(1,N).
103*> \endverbatim
104*>
105*> \param[out] WORK
106*> \verbatim
107*> WORK is COMPLEX*16 array, dimension (max(1, 2*N-1))
108*> \endverbatim
109*>
110*> \param[out] RWORK
111*> \verbatim
112*> RWORK is DOUBLE PRECISION array, dimension (max(1, 3*N-2))
113*> \endverbatim
114*>
115*> \param[out] INFO
116*> \verbatim
117*> INFO is INTEGER
118*> = 0: successful exit.
119*> < 0: if INFO = -i, the i-th argument had an illegal value.
120*> > 0: if INFO = i, the algorithm failed to converge; i
121*> off-diagonal elements of an intermediate tridiagonal
122*> form did not converge to zero.
123*> \endverbatim
124*
125* Authors:
126* ========
127*
128*> \author Univ. of Tennessee
129*> \author Univ. of California Berkeley
130*> \author Univ. of Colorado Denver
131*> \author NAG Ltd.
132*
133*> \ingroup hpev
134*
135* =====================================================================
136 SUBROUTINE zhpev( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, RWORK,
137 \$ INFO )
138*
139* -- LAPACK driver routine --
140* -- LAPACK is a software package provided by Univ. of Tennessee, --
141* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
142*
143* .. Scalar Arguments ..
144 CHARACTER JOBZ, UPLO
145 INTEGER INFO, LDZ, N
146* ..
147* .. Array Arguments ..
148 DOUBLE PRECISION RWORK( * ), W( * )
149 COMPLEX*16 AP( * ), WORK( * ), Z( LDZ, * )
150* ..
151*
152* =====================================================================
153*
154* .. Parameters ..
155 DOUBLE PRECISION ZERO, ONE
156 parameter( zero = 0.0d0, one = 1.0d0 )
157* ..
158* .. Local Scalars ..
159 LOGICAL WANTZ
160 INTEGER IINFO, IMAX, INDE, INDRWK, INDTAU, INDWRK,
161 \$ iscale
162 DOUBLE PRECISION ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
163 \$ smlnum
164* ..
165* .. External Functions ..
166 LOGICAL LSAME
167 DOUBLE PRECISION DLAMCH, ZLANHP
168 EXTERNAL lsame, dlamch, zlanhp
169* ..
170* .. External Subroutines ..
171 EXTERNAL dscal, dsterf, xerbla, zdscal, zhptrd, zsteqr,
172 \$ zupgtr
173* ..
174* .. Intrinsic Functions ..
175 INTRINSIC sqrt
176* ..
177* .. Executable Statements ..
178*
179* Test the input parameters.
180*
181 wantz = lsame( jobz, 'V' )
182*
183 info = 0
184 IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
185 info = -1
186 ELSE IF( .NOT.( lsame( uplo, 'L' ) .OR. lsame( uplo, 'U' ) ) )
187 \$ THEN
188 info = -2
189 ELSE IF( n.LT.0 ) THEN
190 info = -3
191 ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
192 info = -7
193 END IF
194*
195 IF( info.NE.0 ) THEN
196 CALL xerbla( 'ZHPEV ', -info )
197 RETURN
198 END IF
199*
200* Quick return if possible
201*
202 IF( n.EQ.0 )
203 \$ RETURN
204*
205 IF( n.EQ.1 ) THEN
206 w( 1 ) = dble( ap( 1 ) )
207 rwork( 1 ) = 1
208 IF( wantz )
209 \$ z( 1, 1 ) = one
210 RETURN
211 END IF
212*
213* Get machine constants.
214*
215 safmin = dlamch( 'Safe minimum' )
216 eps = dlamch( 'Precision' )
217 smlnum = safmin / eps
218 bignum = one / smlnum
219 rmin = sqrt( smlnum )
220 rmax = sqrt( bignum )
221*
222* Scale matrix to allowable range, if necessary.
223*
224 anrm = zlanhp( 'M', uplo, n, ap, rwork )
225 iscale = 0
226 IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
227 iscale = 1
228 sigma = rmin / anrm
229 ELSE IF( anrm.GT.rmax ) THEN
230 iscale = 1
231 sigma = rmax / anrm
232 END IF
233 IF( iscale.EQ.1 ) THEN
234 CALL zdscal( ( n*( n+1 ) ) / 2, sigma, ap, 1 )
235 END IF
236*
237* Call ZHPTRD to reduce Hermitian packed matrix to tridiagonal form.
238*
239 inde = 1
240 indtau = 1
241 CALL zhptrd( uplo, n, ap, w, rwork( inde ), work( indtau ),
242 \$ iinfo )
243*
244* For eigenvalues only, call DSTERF. For eigenvectors, first call
245* ZUPGTR to generate the orthogonal matrix, then call ZSTEQR.
246*
247 IF( .NOT.wantz ) THEN
248 CALL dsterf( n, w, rwork( inde ), info )
249 ELSE
250 indwrk = indtau + n
251 CALL zupgtr( uplo, n, ap, work( indtau ), z, ldz,
252 \$ work( indwrk ), iinfo )
253 indrwk = inde + n
254 CALL zsteqr( jobz, n, w, rwork( inde ), z, ldz,
255 \$ rwork( indrwk ), info )
256 END IF
257*
258* If matrix was scaled, then rescale eigenvalues appropriately.
259*
260 IF( iscale.EQ.1 ) THEN
261 IF( info.EQ.0 ) THEN
262 imax = n
263 ELSE
264 imax = info - 1
265 END IF
266 CALL dscal( imax, one / sigma, w, 1 )
267 END IF
268*
269 RETURN
270*
271* End of ZHPEV
272*
273 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine zhpev(jobz, uplo, n, ap, w, z, ldz, work, rwork, info)
ZHPEV computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices
Definition zhpev.f:138
subroutine zhptrd(uplo, n, ap, d, e, tau, info)
ZHPTRD
Definition zhptrd.f:151
subroutine dscal(n, da, dx, incx)
DSCAL
Definition dscal.f:79
subroutine zdscal(n, da, zx, incx)
ZDSCAL
Definition zdscal.f:78
subroutine zsteqr(compz, n, d, e, z, ldz, work, info)
ZSTEQR
Definition zsteqr.f:132
subroutine dsterf(n, d, e, info)
DSTERF
Definition dsterf.f:86
subroutine zupgtr(uplo, n, ap, tau, q, ldq, work, info)
ZUPGTR
Definition zupgtr.f:114