sgelss()

subroutine sgelss	(	integer	m,
		integer	n,
		integer	nrhs,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( * )	s,
		real	rcond,
		integer	rank,
		real, dimension( * )	work,
		integer	lwork,
		integer	info )

SGELSS solves overdetermined or underdetermined systems for GE matrices

Download SGELSS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SGELSS computes the minimum norm solution to a real linear least
!> squares problem:
!>
!> Minimize 2-norm(| b - A*x |).
!>
!> using the singular value decomposition (SVD) of A. A is an M-by-N
!> matrix which may be rank-deficient.
!>
!> Several right hand side vectors b and solution vectors x can be
!> handled in a single call; they are stored as the columns of the
!> M-by-NRHS right hand side matrix B and the N-by-NRHS solution matrix
!> X.
!>
!> The effective rank of A is determined by treating as zero those
!> singular values which are less than RCOND times the largest singular
!> value.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrices B and X. NRHS >= 0. !>
[in,out]	A	!> A is REAL array, dimension (LDA,N) !> On entry, the M-by-N matrix A. !> On exit, the first min(m,n) rows of A are overwritten with !> its right singular vectors, stored rowwise. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[in,out]	B	!> B is REAL array, dimension (LDB,NRHS) !> On entry, the M-by-NRHS right hand side matrix B. !> On exit, B is overwritten by the N-by-NRHS solution !> matrix X. If m >= n and RANK = n, the residual !> sum-of-squares for the solution in the i-th column is given !> by the sum of squares of elements n+1:m in that column. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,max(M,N)). !>
[out]	S	!> S is REAL array, dimension (min(M,N)) !> The singular values of A in decreasing order. !> The condition number of A in the 2-norm = S(1)/S(min(m,n)). !>
[in]	RCOND	!> RCOND is REAL !> RCOND is used to determine the effective rank of A. !> Singular values S(i) <= RCOND*S(1) are treated as zero. !> If RCOND < 0, machine precision is used instead. !>
[out]	RANK	!> RANK is INTEGER !> The effective rank of A, i.e., the number of singular values !> which are greater than RCOND*S(1). !>
[out]	WORK	!> WORK is REAL array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= 1, and also: !> LWORK >= 3*min(M,N) + max( 2*min(M,N), max(M,N), NRHS ) !> For good performance, LWORK should generally be larger. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: the algorithm for computing the SVD failed to converge; !> if INFO = i, i off-diagonal elements of an intermediate !> bidiagonal form did not converge to zero. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 168 of file sgelss.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS, RANK
      REAL               RCOND
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), B( LDB, * ), S( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            BDSPAC, BL, CHUNK, I, IASCL, IBSCL, IE, IL,
     $                   ITAU, ITAUP, ITAUQ, IWORK, LDWORK, MAXMN,
     $                   MAXWRK, MINMN, MINWRK, MM, MNTHR
      INTEGER            LWORK_SGEQRF, LWORK_SORMQR, LWORK_SGEBRD,
     $                   LWORK_SORMBR, LWORK_SORGBR, LWORK_SORMLQ
      REAL               ANRM, BIGNUM, BNRM, EPS, SFMIN, SMLNUM, THR
*     ..
*     .. Local Arrays ..
      REAL               DUM( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           sbdsqr, scopy, sgebrd, sgelqf, sgemm,
     $                   sgemv,
     $                   sgeqrf, slacpy, slascl, slaset, sorgbr,
     $                   sormbr, sormlq, sormqr, srscl, xerbla
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      REAL               SLAMCH, SLANGE, SROUNDUP_LWORK
      EXTERNAL           ilaenv, slamch, slange,
     $                   sroundup_lwork
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      minmn = min( m, n )
      maxmn = max( m, n )
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, maxmn ) ) THEN
         info = -7
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       NB refers to the optimal block size for the immediately
*       following subroutine, as returned by ILAENV.)
*
      IF( info.EQ.0 ) THEN
         minwrk = 1
         maxwrk = 1
         IF( minmn.GT.0 ) THEN
            mm = m
            mnthr = ilaenv( 6, 'SGELSS', ' ', m, n, nrhs, -1 )
            IF( m.GE.n .AND. m.GE.mnthr ) THEN
*
*              Path 1a - overdetermined, with many more rows than
*                        columns
*
*              Compute space needed for SGEQRF
               CALL sgeqrf( m, n, a, lda, dum(1), dum(1), -1, info )
               lwork_sgeqrf = int( dum(1) )
*              Compute space needed for SORMQR
               CALL sormqr( 'L', 'T', m, nrhs, n, a, lda, dum(1), b,
     $                   ldb, dum(1), -1, info )
               lwork_sormqr = int( dum(1) )
               mm = n
               maxwrk = max( maxwrk, n + lwork_sgeqrf )
               maxwrk = max( maxwrk, n + lwork_sormqr )
            END IF
            IF( m.GE.n ) THEN
*
*              Path 1 - overdetermined or exactly determined
*
*              Compute workspace needed for SBDSQR
*
               bdspac = max( 1, 5*n )
*              Compute space needed for SGEBRD
               CALL sgebrd( mm, n, a, lda, s, dum(1), dum(1),
     $                      dum(1), dum(1), -1, info )
               lwork_sgebrd = int( dum(1) )
*              Compute space needed for SORMBR
               CALL sormbr( 'Q', 'L', 'T', mm, nrhs, n, a, lda,
     $                      dum(1),
     $                b, ldb, dum(1), -1, info )
               lwork_sormbr = int( dum(1) )
*              Compute space needed for SORGBR
               CALL sorgbr( 'P', n, n, n, a, lda, dum(1),
     $                   dum(1), -1, info )
               lwork_sorgbr = int( dum(1) )
*              Compute total workspace needed
               maxwrk = max( maxwrk, 3*n + lwork_sgebrd )
               maxwrk = max( maxwrk, 3*n + lwork_sormbr )
               maxwrk = max( maxwrk, 3*n + lwork_sorgbr )
               maxwrk = max( maxwrk, bdspac )
               maxwrk = max( maxwrk, n*nrhs )
               minwrk = max( 3*n + mm, 3*n + nrhs, bdspac )
               maxwrk = max( minwrk, maxwrk )
            END IF
            IF( n.GT.m ) THEN
*
*              Compute workspace needed for SBDSQR
*
               bdspac = max( 1, 5*m )
               minwrk = max( 3*m+nrhs, 3*m+n, bdspac )
               IF( n.GE.mnthr ) THEN
*
*                 Path 2a - underdetermined, with many more columns
*                 than rows
*
*                 Compute space needed for SGEBRD
                  CALL sgebrd( m, m, a, lda, s, dum(1), dum(1),
     $                      dum(1), dum(1), -1, info )
                  lwork_sgebrd = int( dum(1) )
*                 Compute space needed for SORMBR
                  CALL sormbr( 'Q', 'L', 'T', m, nrhs, n, a, lda,
     $                dum(1), b, ldb, dum(1), -1, info )
                  lwork_sormbr = int( dum(1) )
*                 Compute space needed for SORGBR
                  CALL sorgbr( 'P', m, m, m, a, lda, dum(1),
     $                   dum(1), -1, info )
                  lwork_sorgbr = int( dum(1) )
*                 Compute space needed for SORMLQ
                  CALL sormlq( 'L', 'T', n, nrhs, m, a, lda, dum(1),
     $                 b, ldb, dum(1), -1, info )
                  lwork_sormlq = int( dum(1) )
*                 Compute total workspace needed
                  maxwrk = m + m*ilaenv( 1, 'SGELQF', ' ', m, n, -1,
     $                                  -1 )
                  maxwrk = max( maxwrk, m*m + 4*m + lwork_sgebrd )
                  maxwrk = max( maxwrk, m*m + 4*m + lwork_sormbr )
                  maxwrk = max( maxwrk, m*m + 4*m + lwork_sorgbr )
                  maxwrk = max( maxwrk, m*m + m + bdspac )
                  IF( nrhs.GT.1 ) THEN
                     maxwrk = max( maxwrk, m*m + m + m*nrhs )
                  ELSE
                     maxwrk = max( maxwrk, m*m + 2*m )
                  END IF
                  maxwrk = max( maxwrk, m + lwork_sormlq )
               ELSE
*
*                 Path 2 - underdetermined
*
*                 Compute space needed for SGEBRD
                  CALL sgebrd( m, n, a, lda, s, dum(1), dum(1),
     $                      dum(1), dum(1), -1, info )
                  lwork_sgebrd = int( dum(1) )
*                 Compute space needed for SORMBR
                  CALL sormbr( 'Q', 'L', 'T', m, nrhs, m, a, lda,
     $                dum(1), b, ldb, dum(1), -1, info )
                  lwork_sormbr = int( dum(1) )
*                 Compute space needed for SORGBR
                  CALL sorgbr( 'P', m, n, m, a, lda, dum(1),
     $                   dum(1), -1, info )
                  lwork_sorgbr = int( dum(1) )
                  maxwrk = 3*m + lwork_sgebrd
                  maxwrk = max( maxwrk, 3*m + lwork_sormbr )
                  maxwrk = max( maxwrk, 3*m + lwork_sorgbr )
                  maxwrk = max( maxwrk, bdspac )
                  maxwrk = max( maxwrk, n*nrhs )
               END IF
            END IF
            maxwrk = max( minwrk, maxwrk )
         END IF
         work( 1 ) = sroundup_lwork(maxwrk)
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery )
     $      info = -12
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SGELSS', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 ) THEN
         rank = 0
         RETURN
      END IF
*
*     Get machine parameters
*
      eps = slamch( 'P' )
      sfmin = slamch( 'S' )
      smlnum = sfmin / eps
      bignum = one / smlnum
*
*     Scale A if max element outside range [SMLNUM,BIGNUM]
*
      anrm = slange( 'M', m, n, a, lda, work )
      iascl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL slascl( 'G', 0, 0, anrm, smlnum, m, n, a, lda, info )
         iascl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL slascl( 'G', 0, 0, anrm, bignum, m, n, a, lda, info )
         iascl = 2
      ELSE IF( anrm.EQ.zero ) THEN
*
*        Matrix all zero. Return zero solution.
*
         CALL slaset( 'F', max( m, n ), nrhs, zero, zero, b, ldb )
         CALL slaset( 'F', minmn, 1, zero, zero, s, minmn )
         rank = 0
         GO TO 70
      END IF
*
*     Scale B if max element outside range [SMLNUM,BIGNUM]
*
      bnrm = slange( 'M', m, nrhs, b, ldb, work )
      ibscl = 0
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL slascl( 'G', 0, 0, bnrm, smlnum, m, nrhs, b, ldb,
     $                info )
         ibscl = 1
      ELSE IF( bnrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL slascl( 'G', 0, 0, bnrm, bignum, m, nrhs, b, ldb,
     $                info )
         ibscl = 2
      END IF
*
*     Overdetermined case
*
      IF( m.GE.n ) THEN
*
*        Path 1 - overdetermined or exactly determined
*
         mm = m
         IF( m.GE.mnthr ) THEN
*
*           Path 1a - overdetermined, with many more rows than columns
*
            mm = n
            itau = 1
            iwork = itau + n
*
*           Compute A=Q*R
*           (Workspace: need 2*N, prefer N+N*NB)
*
            CALL sgeqrf( m, n, a, lda, work( itau ), work( iwork ),
     $                   lwork-iwork+1, info )
*
*           Multiply B by transpose(Q)
*           (Workspace: need N+NRHS, prefer N+NRHS*NB)
*
            CALL sormqr( 'L', 'T', m, nrhs, n, a, lda, work( itau ),
     $                   b,
     $                   ldb, work( iwork ), lwork-iwork+1, info )
*
*           Zero out below R
*
            IF( n.GT.1 )
     $         CALL slaset( 'L', n-1, n-1, zero, zero, a( 2, 1 ),
     $                      lda )
         END IF
*
         ie = 1
         itauq = ie + n
         itaup = itauq + n
         iwork = itaup + n
*
*        Bidiagonalize R in A
*        (Workspace: need 3*N+MM, prefer 3*N+(MM+N)*NB)
*
         CALL sgebrd( mm, n, a, lda, s, work( ie ), work( itauq ),
     $                work( itaup ), work( iwork ), lwork-iwork+1,
     $                info )
*
*        Multiply B by transpose of left bidiagonalizing vectors of R
*        (Workspace: need 3*N+NRHS, prefer 3*N+NRHS*NB)
*
         CALL sormbr( 'Q', 'L', 'T', mm, nrhs, n, a, lda,
     $                work( itauq ),
     $                b, ldb, work( iwork ), lwork-iwork+1, info )
*
*        Generate right bidiagonalizing vectors of R in A
*        (Workspace: need 4*N-1, prefer 3*N+(N-1)*NB)
*
         CALL sorgbr( 'P', n, n, n, a, lda, work( itaup ),
     $                work( iwork ), lwork-iwork+1, info )
         iwork = ie + n
*
*        Perform bidiagonal QR iteration
*          multiply B by transpose of left singular vectors
*          compute right singular vectors in A
*        (Workspace: need BDSPAC)
*
         CALL sbdsqr( 'U', n, n, 0, nrhs, s, work( ie ), a, lda, dum,
     $                1, b, ldb, work( iwork ), info )
         IF( info.NE.0 )
     $      GO TO 70
*
*        Multiply B by reciprocals of singular values
*
         thr = max( rcond*s( 1 ), sfmin )
         IF( rcond.LT.zero )
     $      thr = max( eps*s( 1 ), sfmin )
         rank = 0
         DO 10 i = 1, n
            IF( s( i ).GT.thr ) THEN
               CALL srscl( nrhs, s( i ), b( i, 1 ), ldb )
               rank = rank + 1
            ELSE
               CALL slaset( 'F', 1, nrhs, zero, zero, b( i, 1 ),
     $                      ldb )
            END IF
   10    CONTINUE
*
*        Multiply B by right singular vectors
*        (Workspace: need N, prefer N*NRHS)
*
         IF( lwork.GE.ldb*nrhs .AND. nrhs.GT.1 ) THEN
            CALL sgemm( 'T', 'N', n, nrhs, n, one, a, lda, b, ldb,
     $                  zero,
     $                  work, ldb )
            CALL slacpy( 'G', n, nrhs, work, ldb, b, ldb )
         ELSE IF( nrhs.GT.1 ) THEN
            chunk = lwork / n
            DO 20 i = 1, nrhs, chunk
               bl = min( nrhs-i+1, chunk )
               CALL sgemm( 'T', 'N', n, bl, n, one, a, lda, b( 1,
     $                     i ),
     $                     ldb, zero, work, n )
               CALL slacpy( 'G', n, bl, work, n, b( 1, i ), ldb )
   20       CONTINUE
         ELSE IF( nrhs.EQ.1 ) THEN
            CALL sgemv( 'T', n, n, one, a, lda, b, 1, zero, work, 1 )
            CALL scopy( n, work, 1, b, 1 )
         END IF
*
      ELSE IF( n.GE.mnthr .AND. lwork.GE.4*m+m*m+
     $         max( m, 2*m-4, nrhs, n-3*m ) ) THEN
*
*        Path 2a - underdetermined, with many more columns than rows
*        and sufficient workspace for an efficient algorithm
*
         ldwork = m
         IF( lwork.GE.max( 4*m+m*lda+max( m, 2*m-4, nrhs, n-3*m ),
     $       m*lda+m+m*nrhs ) )ldwork = lda
         itau = 1
         iwork = m + 1
*
*        Compute A=L*Q
*        (Workspace: need 2*M, prefer M+M*NB)
*
         CALL sgelqf( m, n, a, lda, work( itau ), work( iwork ),
     $                lwork-iwork+1, info )
         il = iwork
*
*        Copy L to WORK(IL), zeroing out above it
*
         CALL slacpy( 'L', m, m, a, lda, work( il ), ldwork )
         CALL slaset( 'U', m-1, m-1, zero, zero, work( il+ldwork ),
     $                ldwork )
         ie = il + ldwork*m
         itauq = ie + m
         itaup = itauq + m
         iwork = itaup + m
*
*        Bidiagonalize L in WORK(IL)
*        (Workspace: need M*M+5*M, prefer M*M+4*M+2*M*NB)
*
         CALL sgebrd( m, m, work( il ), ldwork, s, work( ie ),
     $                work( itauq ), work( itaup ), work( iwork ),
     $                lwork-iwork+1, info )
*
*        Multiply B by transpose of left bidiagonalizing vectors of L
*        (Workspace: need M*M+4*M+NRHS, prefer M*M+4*M+NRHS*NB)
*
         CALL sormbr( 'Q', 'L', 'T', m, nrhs, m, work( il ), ldwork,
     $                work( itauq ), b, ldb, work( iwork ),
     $                lwork-iwork+1, info )
*
*        Generate right bidiagonalizing vectors of R in WORK(IL)
*        (Workspace: need M*M+5*M-1, prefer M*M+4*M+(M-1)*NB)
*
         CALL sorgbr( 'P', m, m, m, work( il ), ldwork,
     $                work( itaup ),
     $                work( iwork ), lwork-iwork+1, info )
         iwork = ie + m
*
*        Perform bidiagonal QR iteration,
*           computing right singular vectors of L in WORK(IL) and
*           multiplying B by transpose of left singular vectors
*        (Workspace: need M*M+M+BDSPAC)
*
         CALL sbdsqr( 'U', m, m, 0, nrhs, s, work( ie ), work( il ),
     $                ldwork, a, lda, b, ldb, work( iwork ), info )
         IF( info.NE.0 )
     $      GO TO 70
*
*        Multiply B by reciprocals of singular values
*
         thr = max( rcond*s( 1 ), sfmin )
         IF( rcond.LT.zero )
     $      thr = max( eps*s( 1 ), sfmin )
         rank = 0
         DO 30 i = 1, m
            IF( s( i ).GT.thr ) THEN
               CALL srscl( nrhs, s( i ), b( i, 1 ), ldb )
               rank = rank + 1
            ELSE
               CALL slaset( 'F', 1, nrhs, zero, zero, b( i, 1 ),
     $                      ldb )
            END IF
   30    CONTINUE
         iwork = ie
*
*        Multiply B by right singular vectors of L in WORK(IL)
*        (Workspace: need M*M+2*M, prefer M*M+M+M*NRHS)
*
         IF( lwork.GE.ldb*nrhs+iwork-1 .AND. nrhs.GT.1 ) THEN
            CALL sgemm( 'T', 'N', m, nrhs, m, one, work( il ),
     $                  ldwork,
     $                  b, ldb, zero, work( iwork ), ldb )
            CALL slacpy( 'G', m, nrhs, work( iwork ), ldb, b, ldb )
         ELSE IF( nrhs.GT.1 ) THEN
            chunk = ( lwork-iwork+1 ) / m
            DO 40 i = 1, nrhs, chunk
               bl = min( nrhs-i+1, chunk )
               CALL sgemm( 'T', 'N', m, bl, m, one, work( il ),
     $                     ldwork,
     $                     b( 1, i ), ldb, zero, work( iwork ), m )
               CALL slacpy( 'G', m, bl, work( iwork ), m, b( 1, i ),
     $                      ldb )
   40       CONTINUE
         ELSE IF( nrhs.EQ.1 ) THEN
            CALL sgemv( 'T', m, m, one, work( il ), ldwork, b( 1,
     $                  1 ), 1, zero, work( iwork ), 1 )
            CALL scopy( m, work( iwork ), 1, b( 1, 1 ), 1 )
         END IF
*
*        Zero out below first M rows of B
*
         CALL slaset( 'F', n-m, nrhs, zero, zero, b( m+1, 1 ), ldb )
         iwork = itau + m
*
*        Multiply transpose(Q) by B
*        (Workspace: need M+NRHS, prefer M+NRHS*NB)
*
         CALL sormlq( 'L', 'T', n, nrhs, m, a, lda, work( itau ), b,
     $                ldb, work( iwork ), lwork-iwork+1, info )
*
      ELSE
*
*        Path 2 - remaining underdetermined cases
*
         ie = 1
         itauq = ie + m
         itaup = itauq + m
         iwork = itaup + m
*
*        Bidiagonalize A
*        (Workspace: need 3*M+N, prefer 3*M+(M+N)*NB)
*
         CALL sgebrd( m, n, a, lda, s, work( ie ), work( itauq ),
     $                work( itaup ), work( iwork ), lwork-iwork+1,
     $                info )
*
*        Multiply B by transpose of left bidiagonalizing vectors
*        (Workspace: need 3*M+NRHS, prefer 3*M+NRHS*NB)
*
         CALL sormbr( 'Q', 'L', 'T', m, nrhs, n, a, lda,
     $                work( itauq ),
     $                b, ldb, work( iwork ), lwork-iwork+1, info )
*
*        Generate right bidiagonalizing vectors in A
*        (Workspace: need 4*M, prefer 3*M+M*NB)
*
         CALL sorgbr( 'P', m, n, m, a, lda, work( itaup ),
     $                work( iwork ), lwork-iwork+1, info )
         iwork = ie + m
*
*        Perform bidiagonal QR iteration,
*           computing right singular vectors of A in A and
*           multiplying B by transpose of left singular vectors
*        (Workspace: need BDSPAC)
*
         CALL sbdsqr( 'L', m, n, 0, nrhs, s, work( ie ), a, lda, dum,
     $                1, b, ldb, work( iwork ), info )
         IF( info.NE.0 )
     $      GO TO 70
*
*        Multiply B by reciprocals of singular values
*
         thr = max( rcond*s( 1 ), sfmin )
         IF( rcond.LT.zero )
     $      thr = max( eps*s( 1 ), sfmin )
         rank = 0
         DO 50 i = 1, m
            IF( s( i ).GT.thr ) THEN
               CALL srscl( nrhs, s( i ), b( i, 1 ), ldb )
               rank = rank + 1
            ELSE
               CALL slaset( 'F', 1, nrhs, zero, zero, b( i, 1 ),
     $                      ldb )
            END IF
   50    CONTINUE
*
*        Multiply B by right singular vectors of A
*        (Workspace: need N, prefer N*NRHS)
*
         IF( lwork.GE.ldb*nrhs .AND. nrhs.GT.1 ) THEN
            CALL sgemm( 'T', 'N', n, nrhs, m, one, a, lda, b, ldb,
     $                  zero,
     $                  work, ldb )
            CALL slacpy( 'F', n, nrhs, work, ldb, b, ldb )
         ELSE IF( nrhs.GT.1 ) THEN
            chunk = lwork / n
            DO 60 i = 1, nrhs, chunk
               bl = min( nrhs-i+1, chunk )
               CALL sgemm( 'T', 'N', n, bl, m, one, a, lda, b( 1,
     $                     i ),
     $                     ldb, zero, work, n )
               CALL slacpy( 'F', n, bl, work, n, b( 1, i ), ldb )
   60       CONTINUE
         ELSE IF( nrhs.EQ.1 ) THEN
            CALL sgemv( 'T', m, n, one, a, lda, b, 1, zero, work, 1 )
            CALL scopy( n, work, 1, b, 1 )
         END IF
      END IF
*
*     Undo scaling
*
      IF( iascl.EQ.1 ) THEN
         CALL slascl( 'G', 0, 0, anrm, smlnum, n, nrhs, b, ldb,
     $                info )
         CALL slascl( 'G', 0, 0, smlnum, anrm, minmn, 1, s, minmn,
     $                info )
      ELSE IF( iascl.EQ.2 ) THEN
         CALL slascl( 'G', 0, 0, anrm, bignum, n, nrhs, b, ldb,
     $                info )
         CALL slascl( 'G', 0, 0, bignum, anrm, minmn, 1, s, minmn,
     $                info )
      END IF
      IF( ibscl.EQ.1 ) THEN
         CALL slascl( 'G', 0, 0, smlnum, bnrm, n, nrhs, b, ldb,
     $                info )
      ELSE IF( ibscl.EQ.2 ) THEN
         CALL slascl( 'G', 0, 0, bignum, bnrm, n, nrhs, b, ldb,
     $                info )
      END IF
*
   70 CONTINUE
      work( 1 ) = sroundup_lwork(maxwrk)
      RETURN
*
*     End of SGELSS
*

Here is the call graph for this function:

Here is the caller graph for this function: