LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
zgbmv.f
Go to the documentation of this file.
1*> \brief \b ZGBMV
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE ZGBMV(TRANS,M,N,KL,KU,ALPHA,A,LDA,X,INCX,BETA,Y,INCY)
12*
13* .. Scalar Arguments ..
14* COMPLEX*16 ALPHA,BETA
15* INTEGER INCX,INCY,KL,KU,LDA,M,N
16* CHARACTER TRANS
17* ..
18* .. Array Arguments ..
19* COMPLEX*16 A(LDA,*),X(*),Y(*)
20* ..
21*
22*
23*> \par Purpose:
24* =============
25*>
26*> \verbatim
27*>
28*> ZGBMV performs one of the matrix-vector operations
29*>
30*> y := alpha*A*x + beta*y, or y := alpha*A**T*x + beta*y, or
31*>
32*> y := alpha*A**H*x + beta*y,
33*>
34*> where alpha and beta are scalars, x and y are vectors and A is an
35*> m by n band matrix, with kl sub-diagonals and ku super-diagonals.
36*> \endverbatim
37*
38* Arguments:
39* ==========
40*
41*> \param[in] TRANS
42*> \verbatim
43*> TRANS is CHARACTER*1
44*> On entry, TRANS specifies the operation to be performed as
45*> follows:
46*>
47*> TRANS = 'N' or 'n' y := alpha*A*x + beta*y.
48*>
49*> TRANS = 'T' or 't' y := alpha*A**T*x + beta*y.
50*>
51*> TRANS = 'C' or 'c' y := alpha*A**H*x + beta*y.
52*> \endverbatim
53*>
54*> \param[in] M
55*> \verbatim
56*> M is INTEGER
57*> On entry, M specifies the number of rows of the matrix A.
58*> M must be at least zero.
59*> \endverbatim
60*>
61*> \param[in] N
62*> \verbatim
63*> N is INTEGER
64*> On entry, N specifies the number of columns of the matrix A.
65*> N must be at least zero.
66*> \endverbatim
67*>
68*> \param[in] KL
69*> \verbatim
70*> KL is INTEGER
71*> On entry, KL specifies the number of sub-diagonals of the
72*> matrix A. KL must satisfy 0 .le. KL.
73*> \endverbatim
74*>
75*> \param[in] KU
76*> \verbatim
77*> KU is INTEGER
78*> On entry, KU specifies the number of super-diagonals of the
79*> matrix A. KU must satisfy 0 .le. KU.
80*> \endverbatim
81*>
82*> \param[in] ALPHA
83*> \verbatim
84*> ALPHA is COMPLEX*16
85*> On entry, ALPHA specifies the scalar alpha.
86*> \endverbatim
87*>
88*> \param[in] A
89*> \verbatim
90*> A is COMPLEX*16 array, dimension ( LDA, N )
91*> Before entry, the leading ( kl + ku + 1 ) by n part of the
92*> array A must contain the matrix of coefficients, supplied
93*> column by column, with the leading diagonal of the matrix in
94*> row ( ku + 1 ) of the array, the first super-diagonal
95*> starting at position 2 in row ku, the first sub-diagonal
96*> starting at position 1 in row ( ku + 2 ), and so on.
97*> Elements in the array A that do not correspond to elements
98*> in the band matrix (such as the top left ku by ku triangle)
99*> are not referenced.
100*> The following program segment will transfer a band matrix
101*> from conventional full matrix storage to band storage:
102*>
103*> DO 20, J = 1, N
104*> K = KU + 1 - J
105*> DO 10, I = MAX( 1, J - KU ), MIN( M, J + KL )
106*> A( K + I, J ) = matrix( I, J )
107*> 10 CONTINUE
108*> 20 CONTINUE
109*> \endverbatim
110*>
111*> \param[in] LDA
112*> \verbatim
113*> LDA is INTEGER
114*> On entry, LDA specifies the first dimension of A as declared
115*> in the calling (sub) program. LDA must be at least
116*> ( kl + ku + 1 ).
117*> \endverbatim
118*>
119*> \param[in] X
120*> \verbatim
121*> X is COMPLEX*16 array, dimension at least
122*> ( 1 + ( n - 1 )*abs( INCX ) ) when TRANS = 'N' or 'n'
123*> and at least
124*> ( 1 + ( m - 1 )*abs( INCX ) ) otherwise.
125*> Before entry, the incremented array X must contain the
126*> vector x.
127*> \endverbatim
128*>
129*> \param[in] INCX
130*> \verbatim
131*> INCX is INTEGER
132*> On entry, INCX specifies the increment for the elements of
133*> X. INCX must not be zero.
134*> \endverbatim
135*>
136*> \param[in] BETA
137*> \verbatim
138*> BETA is COMPLEX*16
139*> On entry, BETA specifies the scalar beta. When BETA is
140*> supplied as zero then Y need not be set on input.
141*> \endverbatim
142*>
143*> \param[in,out] Y
144*> \verbatim
145*> Y is COMPLEX*16 array, dimension at least
146*> ( 1 + ( m - 1 )*abs( INCY ) ) when TRANS = 'N' or 'n'
147*> and at least
148*> ( 1 + ( n - 1 )*abs( INCY ) ) otherwise.
149*> Before entry, the incremented array Y must contain the
150*> vector y. On exit, Y is overwritten by the updated vector y.
151*> If either m or n is zero, then Y not referenced and the function
152*> performs a quick return.
153*> \endverbatim
154*>
155*> \param[in] INCY
156*> \verbatim
157*> INCY is INTEGER
158*> On entry, INCY specifies the increment for the elements of
159*> Y. INCY must not be zero.
160*> \endverbatim
161*
162* Authors:
163* ========
164*
165*> \author Univ. of Tennessee
166*> \author Univ. of California Berkeley
167*> \author Univ. of Colorado Denver
168*> \author NAG Ltd.
169*
170*> \ingroup gbmv
171*
172*> \par Further Details:
173* =====================
174*>
175*> \verbatim
176*>
177*> Level 2 Blas routine.
178*> The vector and matrix arguments are not referenced when N = 0, or M = 0
179*>
180*> -- Written on 22-October-1986.
181*> Jack Dongarra, Argonne National Lab.
182*> Jeremy Du Croz, Nag Central Office.
183*> Sven Hammarling, Nag Central Office.
184*> Richard Hanson, Sandia National Labs.
185*> \endverbatim
186*>
187* =====================================================================
188 SUBROUTINE zgbmv(TRANS,M,N,KL,KU,ALPHA,A,LDA,X,INCX,
189 + BETA,Y,INCY)
190*
191* -- Reference BLAS level2 routine --
192* -- Reference BLAS is a software package provided by Univ. of Tennessee, --
193* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
194*
195* .. Scalar Arguments ..
196 COMPLEX*16 ALPHA,BETA
197 INTEGER INCX,INCY,KL,KU,LDA,M,N
198 CHARACTER TRANS
199* ..
200* .. Array Arguments ..
201 COMPLEX*16 A(LDA,*),X(*),Y(*)
202* ..
203*
204* =====================================================================
205*
206* .. Parameters ..
207 COMPLEX*16 ONE
208 parameter(one= (1.0d+0,0.0d+0))
209 COMPLEX*16 ZERO
210 parameter(zero= (0.0d+0,0.0d+0))
211* ..
212* .. Local Scalars ..
213 COMPLEX*16 TEMP
214 INTEGER I,INFO,IX,IY,J,JX,JY,K,KUP1,KX,KY,LENX,LENY
215 LOGICAL NOCONJ
216* ..
217* .. External Functions ..
218 LOGICAL LSAME
219 EXTERNAL lsame
220* ..
221* .. External Subroutines ..
222 EXTERNAL xerbla
223* ..
224* .. Intrinsic Functions ..
225 INTRINSIC dconjg,max,min
226* ..
227*
228* Test the input parameters.
229*
230 info = 0
231 IF (.NOT.lsame(trans,'N') .AND. .NOT.lsame(trans,'T') .AND.
232 + .NOT.lsame(trans,'C')) THEN
233 info = 1
234 ELSE IF (m.LT.0) THEN
235 info = 2
236 ELSE IF (n.LT.0) THEN
237 info = 3
238 ELSE IF (kl.LT.0) THEN
239 info = 4
240 ELSE IF (ku.LT.0) THEN
241 info = 5
242 ELSE IF (lda.LT. (kl+ku+1)) THEN
243 info = 8
244 ELSE IF (incx.EQ.0) THEN
245 info = 10
246 ELSE IF (incy.EQ.0) THEN
247 info = 13
248 END IF
249 IF (info.NE.0) THEN
250 CALL xerbla('ZGBMV ',info)
251 RETURN
252 END IF
253*
254* Quick return if possible.
255*
256 IF ((m.EQ.0) .OR. (n.EQ.0) .OR.
257 + ((alpha.EQ.zero).AND. (beta.EQ.one))) RETURN
258*
259 noconj = lsame(trans,'T')
260*
261* Set LENX and LENY, the lengths of the vectors x and y, and set
262* up the start points in X and Y.
263*
264 IF (lsame(trans,'N')) THEN
265 lenx = n
266 leny = m
267 ELSE
268 lenx = m
269 leny = n
270 END IF
271 IF (incx.GT.0) THEN
272 kx = 1
273 ELSE
274 kx = 1 - (lenx-1)*incx
275 END IF
276 IF (incy.GT.0) THEN
277 ky = 1
278 ELSE
279 ky = 1 - (leny-1)*incy
280 END IF
281*
282* Start the operations. In this version the elements of A are
283* accessed sequentially with one pass through the band part of A.
284*
285* First form y := beta*y.
286*
287 IF (beta.NE.one) THEN
288 IF (incy.EQ.1) THEN
289 IF (beta.EQ.zero) THEN
290 DO 10 i = 1,leny
291 y(i) = zero
292 10 CONTINUE
293 ELSE
294 DO 20 i = 1,leny
295 y(i) = beta*y(i)
296 20 CONTINUE
297 END IF
298 ELSE
299 iy = ky
300 IF (beta.EQ.zero) THEN
301 DO 30 i = 1,leny
302 y(iy) = zero
303 iy = iy + incy
304 30 CONTINUE
305 ELSE
306 DO 40 i = 1,leny
307 y(iy) = beta*y(iy)
308 iy = iy + incy
309 40 CONTINUE
310 END IF
311 END IF
312 END IF
313 IF (alpha.EQ.zero) RETURN
314 kup1 = ku + 1
315 IF (lsame(trans,'N')) THEN
316*
317* Form y := alpha*A*x + y.
318*
319 jx = kx
320 IF (incy.EQ.1) THEN
321 DO 60 j = 1,n
322 temp = alpha*x(jx)
323 k = kup1 - j
324 DO 50 i = max(1,j-ku),min(m,j+kl)
325 y(i) = y(i) + temp*a(k+i,j)
326 50 CONTINUE
327 jx = jx + incx
328 60 CONTINUE
329 ELSE
330 DO 80 j = 1,n
331 temp = alpha*x(jx)
332 iy = ky
333 k = kup1 - j
334 DO 70 i = max(1,j-ku),min(m,j+kl)
335 y(iy) = y(iy) + temp*a(k+i,j)
336 iy = iy + incy
337 70 CONTINUE
338 jx = jx + incx
339 IF (j.GT.ku) ky = ky + incy
340 80 CONTINUE
341 END IF
342 ELSE
343*
344* Form y := alpha*A**T*x + y or y := alpha*A**H*x + y.
345*
346 jy = ky
347 IF (incx.EQ.1) THEN
348 DO 110 j = 1,n
349 temp = zero
350 k = kup1 - j
351 IF (noconj) THEN
352 DO 90 i = max(1,j-ku),min(m,j+kl)
353 temp = temp + a(k+i,j)*x(i)
354 90 CONTINUE
355 ELSE
356 DO 100 i = max(1,j-ku),min(m,j+kl)
357 temp = temp + dconjg(a(k+i,j))*x(i)
358 100 CONTINUE
359 END IF
360 y(jy) = y(jy) + alpha*temp
361 jy = jy + incy
362 110 CONTINUE
363 ELSE
364 DO 140 j = 1,n
365 temp = zero
366 ix = kx
367 k = kup1 - j
368 IF (noconj) THEN
369 DO 120 i = max(1,j-ku),min(m,j+kl)
370 temp = temp + a(k+i,j)*x(ix)
371 ix = ix + incx
372 120 CONTINUE
373 ELSE
374 DO 130 i = max(1,j-ku),min(m,j+kl)
375 temp = temp + dconjg(a(k+i,j))*x(ix)
376 ix = ix + incx
377 130 CONTINUE
378 END IF
379 y(jy) = y(jy) + alpha*temp
380 jy = jy + incy
381 IF (j.GT.ku) kx = kx + incx
382 140 CONTINUE
383 END IF
384 END IF
385*
386 RETURN
387*
388* End of ZGBMV
389*
390 END
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
zgbmv
subroutine zgbmv(trans, m, n, kl, ku, alpha, a, lda, x, incx, beta, y, incy)
ZGBMV
Definition zgbmv.f:190