LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
chet01.f
Go to the documentation of this file.
1 *> \brief \b CHET01
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 * Definition:
9 * ===========
10 *
11 * SUBROUTINE CHET01( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C, LDC,
12 * RWORK, RESID )
13 *
14 * .. Scalar Arguments ..
15 * CHARACTER UPLO
16 * INTEGER LDA, LDAFAC, LDC, N
17 * REAL RESID
18 * ..
19 * .. Array Arguments ..
20 * INTEGER IPIV( * )
21 * REAL RWORK( * )
22 * COMPLEX A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * )
23 * ..
24 *
25 *
26 *> \par Purpose:
27 * =============
28 *>
29 *> \verbatim
30 *>
31 *> CHET01 reconstructs a Hermitian indefinite matrix A from its
32 *> block L*D*L' or U*D*U' factorization and computes the residual
33 *> norm( C - A ) / ( N * norm(A) * EPS ),
34 *> where C is the reconstructed matrix, EPS is the machine epsilon,
35 *> L' is the conjugate transpose of L, and U' is the conjugate transpose
36 *> of U.
37 *> \endverbatim
38 *
39 * Arguments:
40 * ==========
41 *
42 *> \param[in] UPLO
43 *> \verbatim
44 *> UPLO is CHARACTER*1
45 *> Specifies whether the upper or lower triangular part of the
46 *> Hermitian matrix A is stored:
47 *> = 'U': Upper triangular
48 *> = 'L': Lower triangular
49 *> \endverbatim
50 *>
51 *> \param[in] N
52 *> \verbatim
53 *> N is INTEGER
54 *> The number of rows and columns of the matrix A. N >= 0.
55 *> \endverbatim
56 *>
57 *> \param[in] A
58 *> \verbatim
59 *> A is COMPLEX array, dimension (LDA,N)
60 *> The original Hermitian matrix A.
61 *> \endverbatim
62 *>
63 *> \param[in] LDA
64 *> \verbatim
65 *> LDA is INTEGER
66 *> The leading dimension of the array A. LDA >= max(1,N)
67 *> \endverbatim
68 *>
69 *> \param[in] AFAC
70 *> \verbatim
71 *> AFAC is COMPLEX array, dimension (LDAFAC,N)
72 *> The factored form of the matrix A. AFAC contains the block
73 *> diagonal matrix D and the multipliers used to obtain the
74 *> factor L or U from the block L*D*L' or U*D*U' factorization
75 *> as computed by CHETRF.
76 *> \endverbatim
77 *>
78 *> \param[in] LDAFAC
79 *> \verbatim
80 *> LDAFAC is INTEGER
81 *> The leading dimension of the array AFAC. LDAFAC >= max(1,N).
82 *> \endverbatim
83 *>
84 *> \param[in] IPIV
85 *> \verbatim
86 *> IPIV is INTEGER array, dimension (N)
87 *> The pivot indices from CHETRF.
88 *> \endverbatim
89 *>
90 *> \param[out] C
91 *> \verbatim
92 *> C is COMPLEX array, dimension (LDC,N)
93 *> \endverbatim
94 *>
95 *> \param[in] LDC
96 *> \verbatim
97 *> LDC is INTEGER
98 *> The leading dimension of the array C. LDC >= max(1,N).
99 *> \endverbatim
100 *>
101 *> \param[out] RWORK
102 *> \verbatim
103 *> RWORK is REAL array, dimension (N)
104 *> \endverbatim
105 *>
106 *> \param[out] RESID
107 *> \verbatim
108 *> RESID is REAL
109 *> If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
110 *> If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
111 *> \endverbatim
112 *
113 * Authors:
114 * ========
115 *
116 *> \author Univ. of Tennessee
117 *> \author Univ. of California Berkeley
118 *> \author Univ. of Colorado Denver
119 *> \author NAG Ltd.
120 *
121 *> \ingroup complex_lin
122 *
123 * =====================================================================
124  SUBROUTINE chet01( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C, LDC,
125  $ RWORK, RESID )
126 *
127 * -- LAPACK test routine --
128 * -- LAPACK is a software package provided by Univ. of Tennessee, --
129 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130 *
131 * .. Scalar Arguments ..
132  CHARACTER UPLO
133  INTEGER LDA, LDAFAC, LDC, N
134  REAL RESID
135 * ..
136 * .. Array Arguments ..
137  INTEGER IPIV( * )
138  REAL RWORK( * )
139  COMPLEX A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * )
140 * ..
141 *
142 * =====================================================================
143 *
144 * .. Parameters ..
145  REAL ZERO, ONE
146  parameter( zero = 0.0e+0, one = 1.0e+0 )
147  COMPLEX CZERO, CONE
148  parameter( czero = ( 0.0e+0, 0.0e+0 ),
149  $ cone = ( 1.0e+0, 0.0e+0 ) )
150 * ..
151 * .. Local Scalars ..
152  INTEGER I, INFO, J
153  REAL ANORM, EPS
154 * ..
155 * .. External Functions ..
156  LOGICAL LSAME
157  REAL CLANHE, SLAMCH
158  EXTERNAL lsame, clanhe, slamch
159 * ..
160 * .. External Subroutines ..
161  EXTERNAL clavhe, claset
162 * ..
163 * .. Intrinsic Functions ..
164  INTRINSIC aimag, real
165 * ..
166 * .. Executable Statements ..
167 *
168 * Quick exit if N = 0.
169 *
170  IF( n.LE.0 ) THEN
171  resid = zero
172  RETURN
173  END IF
174 *
175 * Determine EPS and the norm of A.
176 *
177  eps = slamch( 'Epsilon' )
178  anorm = clanhe( '1', uplo, n, a, lda, rwork )
179 *
180 * Check the imaginary parts of the diagonal elements and return with
181 * an error code if any are nonzero.
182 *
183  DO 10 j = 1, n
184  IF( aimag( afac( j, j ) ).NE.zero ) THEN
185  resid = one / eps
186  RETURN
187  END IF
188  10 CONTINUE
189 *
190 * Initialize C to the identity matrix.
191 *
192  CALL claset( 'Full', n, n, czero, cone, c, ldc )
193 *
194 * Call CLAVHE to form the product D * U' (or D * L' ).
195 *
196  CALL clavhe( uplo, 'Conjugate', 'Non-unit', n, n, afac, ldafac,
197  $ ipiv, c, ldc, info )
198 *
199 * Call CLAVHE again to multiply by U (or L ).
200 *
201  CALL clavhe( uplo, 'No transpose', 'Unit', n, n, afac, ldafac,
202  $ ipiv, c, ldc, info )
203 *
204 * Compute the difference C - A .
205 *
206  IF( lsame( uplo, 'U' ) ) THEN
207  DO 30 j = 1, n
208  DO 20 i = 1, j - 1
209  c( i, j ) = c( i, j ) - a( i, j )
210  20 CONTINUE
211  c( j, j ) = c( j, j ) - real( a( j, j ) )
212  30 CONTINUE
213  ELSE
214  DO 50 j = 1, n
215  c( j, j ) = c( j, j ) - real( a( j, j ) )
216  DO 40 i = j + 1, n
217  c( i, j ) = c( i, j ) - a( i, j )
218  40 CONTINUE
219  50 CONTINUE
220  END IF
221 *
222 * Compute norm( C - A ) / ( N * norm(A) * EPS )
223 *
224  resid = clanhe( '1', uplo, n, c, ldc, rwork )
225 *
226  IF( anorm.LE.zero ) THEN
227  IF( resid.NE.zero )
228  $ resid = one / eps
229  ELSE
230  resid = ( ( resid / real( n ) ) / anorm ) / eps
231  END IF
232 *
233  RETURN
234 *
235 * End of CHET01
236 *
237  END
subroutine clavhe(UPLO, TRANS, DIAG, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
CLAVHE
Definition: clavhe.f:153
subroutine chet01(UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C, LDC, RWORK, RESID)
CHET01
Definition: chet01.f:126
subroutine claset(UPLO, M, N, ALPHA, BETA, A, LDA)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: claset.f:106