LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
cgelqt3.f
Go to the documentation of this file.
1*> \brief \b CGELQT3
2*
3* Definition:
4* ===========
5*
6* RECURSIVE SUBROUTINE CGELQT3( M, N, A, LDA, T, LDT, INFO )
7*
8* .. Scalar Arguments ..
9* INTEGER INFO, LDA, M, N, LDT
10* ..
11* .. Array Arguments ..
12* COMPLEX A( LDA, * ), T( LDT, * )
13* ..
14*
15*
16*> \par Purpose:
17* =============
18*>
19*> \verbatim
20*>
21*> CGELQT3 recursively computes a LQ factorization of a complex M-by-N
22*> matrix A, using the compact WY representation of Q.
23*>
24*> Based on the algorithm of Elmroth and Gustavson,
25*> IBM J. Res. Develop. Vol 44 No. 4 July 2000.
26*> \endverbatim
27*
28* Arguments:
29* ==========
30*
31*> \param[in] M
32*> \verbatim
33*> M is INTEGER
34*> The number of rows of the matrix A. M =< N.
35*> \endverbatim
36*>
37*> \param[in] N
38*> \verbatim
39*> N is INTEGER
40*> The number of columns of the matrix A. N >= 0.
41*> \endverbatim
42*>
43*> \param[in,out] A
44*> \verbatim
45*> A is COMPLEX array, dimension (LDA,N)
46*> On entry, the complex M-by-N matrix A. On exit, the elements on and
47*> below the diagonal contain the N-by-N lower triangular matrix L; the
48*> elements above the diagonal are the rows of V. See below for
49*> further details.
50*> \endverbatim
51*>
52*> \param[in] LDA
53*> \verbatim
54*> LDA is INTEGER
55*> The leading dimension of the array A. LDA >= max(1,M).
56*> \endverbatim
57*>
58*> \param[out] T
59*> \verbatim
60*> T is COMPLEX array, dimension (LDT,N)
61*> The N-by-N upper triangular factor of the block reflector.
62*> The elements on and above the diagonal contain the block
63*> reflector T; the elements below the diagonal are not used.
64*> See below for further details.
65*> \endverbatim
66*>
67*> \param[in] LDT
68*> \verbatim
69*> LDT is INTEGER
70*> The leading dimension of the array T. LDT >= max(1,N).
71*> \endverbatim
72*>
73*> \param[out] INFO
74*> \verbatim
75*> INFO is INTEGER
76*> = 0: successful exit
77*> < 0: if INFO = -i, the i-th argument had an illegal value
78*> \endverbatim
79*
80* Authors:
81* ========
82*
83*> \author Univ. of Tennessee
84*> \author Univ. of California Berkeley
85*> \author Univ. of Colorado Denver
86*> \author NAG Ltd.
87*
88*> \ingroup gelqt3
89*
90*> \par Further Details:
91* =====================
92*>
93*> \verbatim
94*>
95*> The matrix V stores the elementary reflectors H(i) in the i-th row
96*> above the diagonal. For example, if M=5 and N=3, the matrix V is
97*>
98*> V = ( 1 v1 v1 v1 v1 )
99*> ( 1 v2 v2 v2 )
100*> ( 1 v3 v3 v3 )
101*>
102*>
103*> where the vi's represent the vectors which define H(i), which are returned
104*> in the matrix A. The 1's along the diagonal of V are not stored in A. The
105*> block reflector H is then given by
106*>
107*> H = I - V * T * V**T
108*>
109*> where V**T is the transpose of V.
110*>
111*> For details of the algorithm, see Elmroth and Gustavson (cited above).
112*> \endverbatim
113*>
114* =====================================================================
115 RECURSIVE SUBROUTINE cgelqt3( M, N, A, LDA, T, LDT, INFO )
116*
117* -- LAPACK computational routine --
118* -- LAPACK is a software package provided by Univ. of Tennessee, --
119* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
120*
121* .. Scalar Arguments ..
122 INTEGER info, lda, m, n, ldt
123* ..
124* .. Array Arguments ..
125 COMPLEX a( lda, * ), t( ldt, * )
126* ..
127*
128* =====================================================================
129*
130* .. Parameters ..
131 COMPLEX one, zero
132 parameter( one = (1.0e+00,0.0e+00) )
133 parameter( zero = (0.0e+00,0.0e+00))
134* ..
135* .. Local Scalars ..
136 INTEGER i, i1, j, j1, m1, m2, iinfo
137* ..
138* .. External Subroutines ..
139 EXTERNAL clarfg, ctrmm, cgemm, xerbla
140* ..
141* .. Executable Statements ..
142*
143 info = 0
144 IF( m .LT. 0 ) THEN
145 info = -1
146 ELSE IF( n .LT. m ) THEN
147 info = -2
148 ELSE IF( lda .LT. max( 1, m ) ) THEN
149 info = -4
150 ELSE IF( ldt .LT. max( 1, m ) ) THEN
151 info = -6
152 END IF
153 IF( info.NE.0 ) THEN
154 CALL xerbla( 'CGELQT3', -info )
155 RETURN
156 END IF
157*
158 IF( m.EQ.1 ) THEN
159*
160* Compute Householder transform when M=1
161*
162 CALL clarfg( n, a( 1, 1 ), a( 1, min( 2, n ) ), lda,
163 & t( 1, 1 ) )
164 t(1,1)=conjg(t(1,1))
165*
166 ELSE
167*
168* Otherwise, split A into blocks...
169*
170 m1 = m/2
171 m2 = m-m1
172 i1 = min( m1+1, m )
173 j1 = min( m+1, n )
174*
175* Compute A(1:M1,1:N) <- (Y1,R1,T1), where Q1 = I - Y1 T1 Y1^H
176*
177 CALL cgelqt3( m1, n, a, lda, t, ldt, iinfo )
178*
179* Compute A(J1:M,1:N) = A(J1:M,1:N) Q1^H [workspace: T(1:N1,J1:N)]
180*
181 DO i=1,m2
182 DO j=1,m1
183 t( i+m1, j ) = a( i+m1, j )
184 END DO
185 END DO
186 CALL ctrmm( 'R', 'U', 'C', 'U', m2, m1, one,
187 & a, lda, t( i1, 1 ), ldt )
188*
189 CALL cgemm( 'N', 'C', m2, m1, n-m1, one, a( i1, i1 ), lda,
190 & a( 1, i1 ), lda, one, t( i1, 1 ), ldt)
191*
192 CALL ctrmm( 'R', 'U', 'N', 'N', m2, m1, one,
193 & t, ldt, t( i1, 1 ), ldt )
194*
195 CALL cgemm( 'N', 'N', m2, n-m1, m1, -one, t( i1, 1 ), ldt,
196 & a( 1, i1 ), lda, one, a( i1, i1 ), lda )
197*
198 CALL ctrmm( 'R', 'U', 'N', 'U', m2, m1 , one,
199 & a, lda, t( i1, 1 ), ldt )
200*
201 DO i=1,m2
202 DO j=1,m1
203 a( i+m1, j ) = a( i+m1, j ) - t( i+m1, j )
204 t( i+m1, j )= zero
205 END DO
206 END DO
207*
208* Compute A(J1:M,J1:N) <- (Y2,R2,T2) where Q2 = I - Y2 T2 Y2^H
209*
210 CALL cgelqt3( m2, n-m1, a( i1, i1 ), lda,
211 & t( i1, i1 ), ldt, iinfo )
212*
213* Compute T3 = T(J1:N1,1:N) = -T1 Y1^H Y2 T2
214*
215 DO i=1,m2
216 DO j=1,m1
217 t( j, i+m1 ) = (a( j, i+m1 ))
218 END DO
219 END DO
220*
221 CALL ctrmm( 'R', 'U', 'C', 'U', m1, m2, one,
222 & a( i1, i1 ), lda, t( 1, i1 ), ldt )
223*
224 CALL cgemm( 'N', 'C', m1, m2, n-m, one, a( 1, j1 ), lda,
225 & a( i1, j1 ), lda, one, t( 1, i1 ), ldt )
226*
227 CALL ctrmm( 'L', 'U', 'N', 'N', m1, m2, -one, t, ldt,
228 & t( 1, i1 ), ldt )
229*
230 CALL ctrmm( 'R', 'U', 'N', 'N', m1, m2, one,
231 & t( i1, i1 ), ldt, t( 1, i1 ), ldt )
232*
233*
234*
235* Y = (Y1,Y2); L = [ L1 0 ]; T = [T1 T3]
236* [ A(1:N1,J1:N) L2 ] [ 0 T2]
237*
238 END IF
239*
240 RETURN
241*
242* End of CGELQT3
243*
244 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
recursive subroutine cgelqt3(m, n, a, lda, t, ldt, info)
CGELQT3
Definition cgelqt3.f:116
subroutine cgemm(transa, transb, m, n, k, alpha, a, lda, b, ldb, beta, c, ldc)
CGEMM
Definition cgemm.f:188
subroutine clarfg(n, alpha, x, incx, tau)
CLARFG generates an elementary reflector (Householder matrix).
Definition clarfg.f:106
subroutine ctrmm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
CTRMM
Definition ctrmm.f:177