sgglse.f

Go to the documentation of this file.

*> \brief <b> SGGLSE solves overdetermined or underdetermined systems for OTHER matrices</b>
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download SGGLSE + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgglse.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgglse.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgglse.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE SGGLSE( M, N, P, A, LDA, B, LDB, C, D, X, WORK, LWORK,
*                          INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDB, LWORK, M, N, P
*       ..
*       .. Array Arguments ..
*       REAL               A( LDA, * ), B( LDB, * ), C( * ), D( * ),
*      $                   WORK( * ), X( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SGGLSE solves the linear equality-constrained least squares (LSE)
*> problem:
*>
*>         minimize || c - A*x ||_2   subject to   B*x = d
*>
*> where A is an M-by-N matrix, B is a P-by-N matrix, c is a given
*> M-vector, and d is a given P-vector. It is assumed that
*> P <= N <= M+P, and
*>
*>          rank(B) = P and  rank( (A) ) = N.
*>                               ( (B) )
*>
*> These conditions ensure that the LSE problem has a unique solution,
*> which is obtained using a generalized RQ factorization of the
*> matrices (B, A) given by
*>
*>    B = (0 R)*Q,   A = Z*T*Q.
*>
*> Callers of this subroutine should note that the singularity/rank-deficiency checks
*> implemented in this subroutine are rudimentary. The STRTRS subroutine called by this
*> subroutine only signals a failure due to singularity if the problem is exactly singular.
*>
*> It is conceivable for one (or more) of the factors involved in the generalized RQ
*> factorization of the pair (B, A) to be subnormally close to singularity without this
*> subroutine signalling an error. The solutions computed for such almost-rank-deficient
*> problems may be less accurate due to a loss of numerical precision.
*> 
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrices A and B. N >= 0.
*> \endverbatim
*>
*> \param[in] P
*> \verbatim
*>          P is INTEGER
*>          The number of rows of the matrix B. 0 <= P <= N <= M+P.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is REAL array, dimension (LDA,N)
*>          On entry, the M-by-N matrix A.
*>          On exit, the elements on and above the diagonal of the array
*>          contain the min(M,N)-by-N upper trapezoidal matrix T.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A. LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is REAL array, dimension (LDB,N)
*>          On entry, the P-by-N matrix B.
*>          On exit, the upper triangle of the subarray B(1:P,N-P+1:N)
*>          contains the P-by-P upper triangular matrix R.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B. LDB >= max(1,P).
*> \endverbatim
*>
*> \param[in,out] C
*> \verbatim
*>          C is REAL array, dimension (M)
*>          On entry, C contains the right hand side vector for the
*>          least squares part of the LSE problem.
*>          On exit, the residual sum of squares for the solution
*>          is given by the sum of squares of elements N-P+1 to M of
*>          vector C.
*> \endverbatim
*>
*> \param[in,out] D
*> \verbatim
*>          D is REAL array, dimension (P)
*>          On entry, D contains the right hand side vector for the
*>          constrained equation.
*>          On exit, D is destroyed.
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is REAL array, dimension (N)
*>          On exit, X is the solution of the LSE problem.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK. LWORK >= max(1,M+N+P).
*>          For optimum performance LWORK >= P+min(M,N)+max(M,N)*NB,
*>          where NB is an upper bound for the optimal blocksizes for
*>          SGEQRF, SGERQF, SORMQR and SORMRQ.
*>
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the optimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*>          = 1:  the upper triangular factor R associated with B in the
*>                generalized RQ factorization of the pair (B, A) is exactly
*>                singular, so that rank(B) < P; the least squares
*>                solution could not be computed.
*>          = 2:  the (N-P) by (N-P) part of the upper trapezoidal factor
*>                T associated with A in the generalized RQ factorization
*>                of the pair (B, A) is exactly singular, so that
*>                rank( (A) ) < N; the least squares solution could not
*>                    ( (B) )
*>                be computed.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup gglse
*
*  =====================================================================
      SUBROUTINE sgglse( M, N, P, A, LDA, B, LDB, C, D, X, WORK,
     $                   LWORK,
     $                   INFO )
*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDB, LWORK, M, N, P
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), B( LDB, * ), C( * ), D( * ),
     $                   WORK( * ), X( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      PARAMETER          ( ONE = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            LOPT, LWKMIN, LWKOPT, MN, NB, NB1, NB2, NB3,
     $                   nb4, nr
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, scopy, sgemv, sggrqf, sormqr,
     $                   sormrq,
     $                   strmv, strtrs, xerbla
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      REAL               SROUNDUP_LWORK
      EXTERNAL           ilaenv, sroundup_lwork
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          int, max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters
*
      info = 0
      mn = min( m, n )
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( p.LT.0 .OR. p.GT.n .OR. p.LT.n-m ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, p ) ) THEN
         info = -7
      END IF
*
*     Calculate workspace
*
      IF( info.EQ.0) THEN
         IF( n.EQ.0 ) THEN
            lwkmin = 1
            lwkopt = 1
         ELSE
            nb1 = ilaenv( 1, 'SGEQRF', ' ', m, n, -1, -1 )
            nb2 = ilaenv( 1, 'SGERQF', ' ', m, n, -1, -1 )
            nb3 = ilaenv( 1, 'SORMQR', ' ', m, n, p, -1 )
            nb4 = ilaenv( 1, 'SORMRQ', ' ', m, n, p, -1 )
            nb = max( nb1, nb2, nb3, nb4 )
            lwkmin = m + n + p
            lwkopt = p + mn + max( m, n )*nb
         END IF
         work( 1 ) = sroundup_lwork(lwkopt)
*
         IF( lwork.LT.lwkmin .AND. .NOT.lquery ) THEN
            info = -12
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SGGLSE', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Compute the GRQ factorization of matrices B and A:
*
*            B*Q**T = (  0  T12 ) P   Z**T*A*Q**T = ( R11 R12 ) N-P
*                        N-P  P                     (  0  R22 ) M+P-N
*                                                      N-P  P
*
*     where T12 and R11 are upper triangular, and Q and Z are
*     orthogonal.
*
      CALL sggrqf( p, m, n, b, ldb, work, a, lda, work( p+1 ),
     $             work( p+mn+1 ), lwork-p-mn, info )
      lopt = int( work( p+mn+1 ) )
*
*     Update c = Z**T *c = ( c1 ) N-P
*                          ( c2 ) M+P-N
*
      CALL sormqr( 'Left', 'Transpose', m, 1, mn, a, lda,
     $             work( p+1 ),
     $             c, max( 1, m ), work( p+mn+1 ), lwork-p-mn, info )
      lopt = max( lopt, int( work( p+mn+1 ) ) )
*
*     Solve T12*x2 = d for x2
*
      IF( p.GT.0 ) THEN
         CALL strtrs( 'Upper', 'No transpose', 'Non-unit', p, 1,
     $                b( 1, n-p+1 ), ldb, d, p, info )
*
         IF( info.GT.0 ) THEN
            info = 1
            RETURN
         END IF
*
*        Put the solution in X
*
         CALL scopy( p, d, 1, x( n-p+1 ), 1 )
*
*        Update c1
*
         CALL sgemv( 'No transpose', n-p, p, -one, a( 1, n-p+1 ),
     $               lda,
     $               d, 1, one, c, 1 )
      END IF
*
*     Solve R11*x1 = c1 for x1
*
      IF( n.GT.p ) THEN
         CALL strtrs( 'Upper', 'No transpose', 'Non-unit', n-p, 1,
     $                a, lda, c, n-p, info )
*
         IF( info.GT.0 ) THEN
            info = 2
            RETURN
         END IF
*
*        Put the solutions in X
*
         CALL scopy( n-p, c, 1, x, 1 )
      END IF
*
*     Compute the residual vector:
*
      IF( m.LT.n ) THEN
         nr = m + p - n
         IF( nr.GT.0 )
     $      CALL sgemv( 'No transpose', nr, n-m, -one, a( n-p+1,
     $                  m+1 ),
     $                  lda, d( nr+1 ), 1, one, c( n-p+1 ), 1 )
      ELSE
         nr = p
      END IF
      IF( nr.GT.0 ) THEN
         CALL strmv( 'Upper', 'No transpose', 'Non unit', nr,
     $               a( n-p+1, n-p+1 ), lda, d, 1 )
         CALL saxpy( nr, -one, d, 1, c( n-p+1 ), 1 )
      END IF
*
*     Backward transformation x = Q**T*x
*
      CALL sormrq( 'Left', 'Transpose', n, 1, p, b, ldb, work( 1 ),
     $             x,
     $             n, work( p+mn+1 ), lwork-p-mn, info )
      work( 1 ) = real( p + mn + max( lopt, int( work( p+mn+1 ) ) ) )
*
      RETURN
*
*     End of SGGLSE
*
      END