chetri_3x()

subroutine chetri_3x	(	character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( * )	e,
		integer, dimension( * )	ipiv,
		complex, dimension( n+nb+1, * )	work,
		integer	nb,
		integer	info )

CHETRI_3X

Download CHETRI_3X + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!> CHETRI_3X computes the inverse of a complex Hermitian indefinite
!> matrix A using the factorization computed by CHETRF_RK or CHETRF_BK:
!>
!>     A = P*U*D*(U**H)*(P**T) or A = P*L*D*(L**H)*(P**T),
!>
!> where U (or L) is unit upper (or lower) triangular matrix,
!> U**H (or L**H) is the conjugate of U (or L), P is a permutation
!> matrix, P**T is the transpose of P, and D is Hermitian and block
!> diagonal with 1-by-1 and 2-by-2 diagonal blocks.
!>
!> This is the blocked version of the algorithm, calling Level 3 BLAS.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the details of the factorization are !> stored as an upper or lower triangular matrix. !> = 'U': Upper triangle of A is stored; !> = 'L': Lower triangle of A is stored. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, diagonal of the block diagonal matrix D and !> factors U or L as computed by CHETRF_RK and CHETRF_BK: !> a) ONLY diagonal elements of the Hermitian block diagonal !> matrix D on the diagonal of A, i.e. D(k,k) = A(k,k); !> (superdiagonal (or subdiagonal) elements of D !> should be provided on entry in array E), and !> b) If UPLO = 'U': factor U in the superdiagonal part of A. !> If UPLO = 'L': factor L in the subdiagonal part of A. !> !> On exit, if INFO = 0, the Hermitian inverse of the original !> matrix. !> If UPLO = 'U': the upper triangular part of the inverse !> is formed and the part of A below the diagonal is not !> referenced; !> If UPLO = 'L': the lower triangular part of the inverse !> is formed and the part of A above the diagonal is not !> referenced. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	E	!> E is COMPLEX array, dimension (N) !> On entry, contains the superdiagonal (or subdiagonal) !> elements of the Hermitian block diagonal matrix D !> with 1-by-1 or 2-by-2 diagonal blocks, where !> If UPLO = 'U': E(i) = D(i-1,i), i=2:N, E(1) not referenced; !> If UPLO = 'L': E(i) = D(i+1,i), i=1:N-1, E(N) not referenced. !> !> NOTE: For 1-by-1 diagonal block D(k), where !> 1 <= k <= N, the element E(k) is not referenced in both !> UPLO = 'U' or UPLO = 'L' cases. !>
[in]	IPIV	!> IPIV is INTEGER array, dimension (N) !> Details of the interchanges and the block structure of D !> as determined by CHETRF_RK or CHETRF_BK. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (N+NB+1,NB+3). !>
[in]	NB	!> NB is INTEGER !> Block size. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: if INFO = i, D(i,i) = 0; the matrix is singular and its !> inverse could not be computed. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

!>
!>  June 2017,  Igor Kozachenko,
!>                  Computer Science Division,
!>                  University of California, Berkeley
!>
!> 

Definition at line 156 of file chetri_3x.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N, NB
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX            A( LDA, * ), E( * ), WORK( N+NB+1, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e+0 )
      COMPLEX            CONE, CZERO
      parameter( cone = ( 1.0e+0, 0.0e+0 ),
     $                     czero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            CUT, I, ICOUNT, INVD, IP, K, NNB, J, U11
      REAL               AK, AKP1, T
      COMPLEX            AKKP1, D, U01_I_J, U01_IP1_J, U11_I_J,
     $                   U11_IP1_J
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cheswapr, ctrtri, ctrmm,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, conjg, max, real
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
*
*     Quick return if possible
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHETRI_3X', -info )
         RETURN
      END IF
      IF( n.EQ.0 )
     $   RETURN
*
*     Workspace got Non-diag elements of D
*
      DO k = 1, n
         work( k, 1 ) = e( k )
      END DO
*
*     Check that the diagonal matrix D is nonsingular.
*
      IF( upper ) THEN
*
*        Upper triangular storage: examine D from bottom to top
*
         DO info = n, 1, -1
            IF( ipiv( info ).GT.0 .AND. a( info, info ).EQ.czero )
     $         RETURN
         END DO
      ELSE
*
*        Lower triangular storage: examine D from top to bottom.
*
         DO info = 1, n
            IF( ipiv( info ).GT.0 .AND. a( info, info ).EQ.czero )
     $         RETURN
         END DO
      END IF
*
      info = 0
*
*     Splitting Workspace
*     U01 is a block ( N, NB+1 )
*     The first element of U01 is in WORK( 1, 1 )
*     U11 is a block ( NB+1, NB+1 )
*     The first element of U11 is in WORK( N+1, 1 )
*
      u11 = n
*
*     INVD is a block ( N, 2 )
*     The first element of INVD is in WORK( 1, INVD )
*
      invd = nb + 2
 
      IF( upper ) THEN
*
*        Begin Upper
*
*        invA = P * inv(U**H) * inv(D) * inv(U) * P**T.
*
         CALL ctrtri( uplo, 'U', n, a, lda, info )
*
*        inv(D) and inv(D) * inv(U)
*
         k = 1
         DO WHILE( k.LE.n )
            IF( ipiv( k ).GT.0 ) THEN
*              1 x 1 diagonal NNB
               work( k, invd ) = one / real( a( k, k ) )
               work( k, invd+1 ) = czero
            ELSE
*              2 x 2 diagonal NNB
               t = abs( work( k+1, 1 ) )
               ak = real( a( k, k ) ) / t
               akp1 = real( a( k+1, k+1 ) ) / t
               akkp1 = work( k+1, 1 )  / t
               d = t*( ak*akp1-cone )
               work( k, invd ) = akp1 / d
               work( k+1, invd+1 ) = ak / d
               work( k, invd+1 ) = -akkp1 / d
               work( k+1, invd ) = conjg( work( k, invd+1 ) )
               k = k + 1
            END IF
            k = k + 1
         END DO
*
*        inv(U**H) = (inv(U))**H
*
*        inv(U**H) * inv(D) * inv(U)
*
         cut = n
         DO WHILE( cut.GT.0 )
            nnb = nb
            IF( cut.LE.nnb ) THEN
               nnb = cut
            ELSE
               icount = 0
*              count negative elements,
               DO i = cut+1-nnb, cut
                  IF( ipiv( i ).LT.0 ) icount = icount + 1
               END DO
*              need a even number for a clear cut
               IF( mod( icount, 2 ).EQ.1 ) nnb = nnb + 1
            END IF
 
            cut = cut - nnb
*
*           U01 Block
*
            DO i = 1, cut
               DO j = 1, nnb
                  work( i, j ) = a( i, cut+j )
               END DO
            END DO
*
*           U11 Block
*
            DO i = 1, nnb
               work( u11+i, i ) = cone
               DO j = 1, i-1
                  work( u11+i, j ) = czero
                END DO
                DO j = i+1, nnb
                   work( u11+i, j ) = a( cut+i, cut+j )
                END DO
            END DO
*
*           invD * U01
*
            i = 1
            DO WHILE( i.LE.cut )
               IF( ipiv( i ).GT.0 ) THEN
                  DO j = 1, nnb
                     work( i, j ) = work( i, invd ) * work( i, j )
                  END DO
               ELSE
                  DO j = 1, nnb
                     u01_i_j = work( i, j )
                     u01_ip1_j = work( i+1, j )
                     work( i, j ) = work( i, invd ) * u01_i_j
     $                            + work( i, invd+1 ) * u01_ip1_j
                     work( i+1, j ) = work( i+1, invd ) * u01_i_j
     $                              + work( i+1, invd+1 ) * u01_ip1_j
                  END DO
                  i = i + 1
               END IF
               i = i + 1
            END DO
*
*           invD1 * U11
*
            i = 1
            DO WHILE ( i.LE.nnb )
               IF( ipiv( cut+i ).GT.0 ) THEN
                  DO j = i, nnb
                     work( u11+i, j ) = work(cut+i,invd) * work(u11+i,j)
                  END DO
               ELSE
                  DO j = i, nnb
                     u11_i_j = work(u11+i,j)
                     u11_ip1_j = work(u11+i+1,j)
                     work( u11+i, j ) = work(cut+i,invd) * work(u11+i,j)
     $                            + work(cut+i,invd+1) * work(u11+i+1,j)
                     work( u11+i+1, j ) = work(cut+i+1,invd) * u11_i_j
     $                               + work(cut+i+1,invd+1) * u11_ip1_j
                  END DO
                  i = i + 1
               END IF
               i = i + 1
            END DO
*
*           U11**H * invD1 * U11 -> U11
*
            CALL ctrmm( 'L', 'U', 'C', 'U', nnb, nnb,
     $                 cone, a( cut+1, cut+1 ), lda, work( u11+1, 1 ),
     $                 n+nb+1 )
*
            DO i = 1, nnb
               DO j = i, nnb
                  a( cut+i, cut+j ) = work( u11+i, j )
               END DO
            END DO
*
*           U01**H * invD * U01 -> A( CUT+I, CUT+J )
*
            CALL cgemm( 'C', 'N', nnb, nnb, cut, cone, a( 1, cut+1 ),
     $                  lda, work, n+nb+1, czero, work(u11+1,1),
     $                  n+nb+1 )
 
*
*           U11 =  U11**H * invD1 * U11 + U01**H * invD * U01
*
            DO i = 1, nnb
               DO j = i, nnb
                  a( cut+i, cut+j ) = a( cut+i, cut+j ) + work(u11+i,j)
               END DO
            END DO
*
*           U01 =  U00**H * invD0 * U01
*
            CALL ctrmm( 'L', uplo, 'C', 'U', cut, nnb,
     $                  cone, a, lda, work, n+nb+1 )
 
*
*           Update U01
*
            DO i = 1, cut
               DO j = 1, nnb
                  a( i, cut+j ) = work( i, j )
               END DO
            END DO
*
*           Next Block
*
         END DO
*
*        Apply PERMUTATIONS P and P**T:
*        P * inv(U**H) * inv(D) * inv(U) * P**T.
*        Interchange rows and columns I and IPIV(I) in reverse order
*        from the formation order of IPIV vector for Upper case.
*
*        ( We can use a loop over IPIV with increment 1,
*        since the ABS value of IPIV(I) represents the row (column)
*        index of the interchange with row (column) i in both 1x1
*        and 2x2 pivot cases, i.e. we don't need separate code branches
*        for 1x1 and 2x2 pivot cases )
*
         DO i = 1, n
             ip = abs( ipiv( i ) )
             IF( ip.NE.i ) THEN
                IF (i .LT. ip) CALL cheswapr( uplo, n, a, lda, i ,
     $               ip )
                IF (i .GT. ip) CALL cheswapr( uplo, n, a, lda, ip ,
     $               i )
             END IF
         END DO
*
      ELSE
*
*        Begin Lower
*
*        inv A = P * inv(L**H) * inv(D) * inv(L) * P**T.
*
         CALL ctrtri( uplo, 'U', n, a, lda, info )
*
*        inv(D) and inv(D) * inv(L)
*
         k = n
         DO WHILE ( k .GE. 1 )
            IF( ipiv( k ).GT.0 ) THEN
*              1 x 1 diagonal NNB
               work( k, invd ) = one / real( a( k, k ) )
               work( k, invd+1 ) = czero
            ELSE
*              2 x 2 diagonal NNB
               t = abs( work( k-1, 1 ) )
               ak = real( a( k-1, k-1 ) ) / t
               akp1 = real( a( k, k ) ) / t
               akkp1 = work( k-1, 1 ) / t
               d = t*( ak*akp1-cone )
               work( k-1, invd ) = akp1 / d
               work( k, invd ) = ak / d
               work( k, invd+1 ) = -akkp1 / d
               work( k-1, invd+1 ) = conjg( work( k, invd+1 ) )
               k = k - 1
            END IF
            k = k - 1
         END DO
*
*        inv(L**H) = (inv(L))**H
*
*        inv(L**H) * inv(D) * inv(L)
*
         cut = 0
         DO WHILE( cut.LT.n )
            nnb = nb
            IF( (cut + nnb).GT.n ) THEN
               nnb = n - cut
            ELSE
               icount = 0
*              count negative elements,
               DO i = cut + 1, cut+nnb
                  IF ( ipiv( i ).LT.0 ) icount = icount + 1
               END DO
*              need a even number for a clear cut
               IF( mod( icount, 2 ).EQ.1 ) nnb = nnb + 1
            END IF
*
*           L21 Block
*
            DO i = 1, n-cut-nnb
               DO j = 1, nnb
                 work( i, j ) = a( cut+nnb+i, cut+j )
               END DO
            END DO
*
*           L11 Block
*
            DO i = 1, nnb
               work( u11+i, i) = cone
               DO j = i+1, nnb
                  work( u11+i, j ) = czero
               END DO
               DO j = 1, i-1
                  work( u11+i, j ) = a( cut+i, cut+j )
               END DO
            END DO
*
*           invD*L21
*
            i = n-cut-nnb
            DO WHILE( i.GE.1 )
               IF( ipiv( cut+nnb+i ).GT.0 ) THEN
                  DO j = 1, nnb
                     work( i, j ) = work( cut+nnb+i, invd) * work( i, j)
                  END DO
               ELSE
                  DO j = 1, nnb
                     u01_i_j = work(i,j)
                     u01_ip1_j = work(i-1,j)
                     work(i,j)=work(cut+nnb+i,invd)*u01_i_j+
     $                        work(cut+nnb+i,invd+1)*u01_ip1_j
                     work(i-1,j)=work(cut+nnb+i-1,invd+1)*u01_i_j+
     $                        work(cut+nnb+i-1,invd)*u01_ip1_j
                  END DO
                  i = i - 1
               END IF
               i = i - 1
            END DO
*
*           invD1*L11
*
            i = nnb
            DO WHILE( i.GE.1 )
               IF( ipiv( cut+i ).GT.0 ) THEN
                  DO j = 1, nnb
                     work( u11+i, j ) = work( cut+i, invd)*work(u11+i,j)
                  END DO
 
               ELSE
                  DO j = 1, nnb
                     u11_i_j = work( u11+i, j )
                     u11_ip1_j = work( u11+i-1, j )
                     work( u11+i, j ) = work(cut+i,invd) * work(u11+i,j)
     $                                + work(cut+i,invd+1) * u11_ip1_j
                     work( u11+i-1, j ) = work(cut+i-1,invd+1) * u11_i_j
     $                                  + work(cut+i-1,invd) * u11_ip1_j
                  END DO
                  i = i - 1
               END IF
               i = i - 1
            END DO
*
*           L11**H * invD1 * L11 -> L11
*
            CALL ctrmm( 'L', uplo, 'C', 'U', nnb, nnb, cone,
     $                   a( cut+1, cut+1 ), lda, work( u11+1, 1 ),
     $                   n+nb+1 )
 
*
            DO i = 1, nnb
               DO j = 1, i
                  a( cut+i, cut+j ) = work( u11+i, j )
               END DO
            END DO
*
            IF( (cut+nnb).LT.n ) THEN
*
*              L21**H * invD2*L21 -> A( CUT+I, CUT+J )
*
               CALL cgemm( 'C', 'N', nnb, nnb, n-nnb-cut, cone,
     $                     a( cut+nnb+1, cut+1 ), lda, work, n+nb+1,
     $                     czero, work( u11+1, 1 ), n+nb+1 )
 
*
*              L11 =  L11**H * invD1 * L11 + U01**H * invD * U01
*
               DO i = 1, nnb
                  DO j = 1, i
                     a( cut+i, cut+j ) = a( cut+i, cut+j )+work(u11+i,j)
                  END DO
               END DO
*
*              L01 =  L22**H * invD2 * L21
*
               CALL ctrmm( 'L', uplo, 'C', 'U', n-nnb-cut, nnb, cone,
     $                     a( cut+nnb+1, cut+nnb+1 ), lda, work,
     $                     n+nb+1 )
*
*              Update L21
*
               DO i = 1, n-cut-nnb
                  DO j = 1, nnb
                     a( cut+nnb+i, cut+j ) = work( i, j )
                  END DO
               END DO
*
            ELSE
*
*              L11 =  L11**H * invD1 * L11
*
               DO i = 1, nnb
                  DO j = 1, i
                     a( cut+i, cut+j ) = work( u11+i, j )
                  END DO
               END DO
            END IF
*
*           Next Block
*
            cut = cut + nnb
*
         END DO
*
*        Apply PERMUTATIONS P and P**T:
*        P * inv(L**H) * inv(D) * inv(L) * P**T.
*        Interchange rows and columns I and IPIV(I) in reverse order
*        from the formation order of IPIV vector for Lower case.
*
*        ( We can use a loop over IPIV with increment -1,
*        since the ABS value of IPIV(I) represents the row (column)
*        index of the interchange with row (column) i in both 1x1
*        and 2x2 pivot cases, i.e. we don't need separate code branches
*        for 1x1 and 2x2 pivot cases )
*
         DO i = n, 1, -1
             ip = abs( ipiv( i ) )
             IF( ip.NE.i ) THEN
                IF (i .LT. ip) CALL cheswapr( uplo, n, a, lda, i ,
     $               ip )
                IF (i .GT. ip) CALL cheswapr( uplo, n, a, lda, ip ,
     $               i )
             END IF
         END DO
*
      END IF
*
      RETURN
*
*     End of CHETRI_3X
*

Here is the call graph for this function:

Here is the caller graph for this function: