LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
zhetrf.f
Go to the documentation of this file.
1 *> \brief \b ZHETRF
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZHETRF + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zhetrf.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zhetrf.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zhetrf.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZHETRF( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER UPLO
25 * INTEGER INFO, LDA, LWORK, N
26 * ..
27 * .. Array Arguments ..
28 * INTEGER IPIV( * )
29 * COMPLEX*16 A( LDA, * ), WORK( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> ZHETRF computes the factorization of a complex Hermitian matrix A
39 *> using the Bunch-Kaufman diagonal pivoting method. The form of the
40 *> factorization is
41 *>
42 *> A = U*D*U**H or A = L*D*L**H
43 *>
44 *> where U (or L) is a product of permutation and unit upper (lower)
45 *> triangular matrices, and D is Hermitian and block diagonal with
46 *> 1-by-1 and 2-by-2 diagonal blocks.
47 *>
48 *> This is the blocked version of the algorithm, calling Level 3 BLAS.
49 *> \endverbatim
50 *
51 * Arguments:
52 * ==========
53 *
54 *> \param[in] UPLO
55 *> \verbatim
56 *> UPLO is CHARACTER*1
57 *> = 'U': Upper triangle of A is stored;
58 *> = 'L': Lower triangle of A is stored.
59 *> \endverbatim
60 *>
61 *> \param[in] N
62 *> \verbatim
63 *> N is INTEGER
64 *> The order of the matrix A. N >= 0.
65 *> \endverbatim
66 *>
67 *> \param[in,out] A
68 *> \verbatim
69 *> A is COMPLEX*16 array, dimension (LDA,N)
70 *> On entry, the Hermitian matrix A. If UPLO = 'U', the leading
71 *> N-by-N upper triangular part of A contains the upper
72 *> triangular part of the matrix A, and the strictly lower
73 *> triangular part of A is not referenced. If UPLO = 'L', the
74 *> leading N-by-N lower triangular part of A contains the lower
75 *> triangular part of the matrix A, and the strictly upper
76 *> triangular part of A is not referenced.
77 *>
78 *> On exit, the block diagonal matrix D and the multipliers used
79 *> to obtain the factor U or L (see below for further details).
80 *> \endverbatim
81 *>
82 *> \param[in] LDA
83 *> \verbatim
84 *> LDA is INTEGER
85 *> The leading dimension of the array A. LDA >= max(1,N).
86 *> \endverbatim
87 *>
88 *> \param[out] IPIV
89 *> \verbatim
90 *> IPIV is INTEGER array, dimension (N)
91 *> Details of the interchanges and the block structure of D.
92 *> If IPIV(k) > 0, then rows and columns k and IPIV(k) were
93 *> interchanged and D(k,k) is a 1-by-1 diagonal block.
94 *> If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and
95 *> columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k)
96 *> is a 2-by-2 diagonal block. If UPLO = 'L' and IPIV(k) =
97 *> IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were
98 *> interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
99 *> \endverbatim
100 *>
101 *> \param[out] WORK
102 *> \verbatim
103 *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
104 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
105 *> \endverbatim
106 *>
107 *> \param[in] LWORK
108 *> \verbatim
109 *> LWORK is INTEGER
110 *> The length of WORK. LWORK >=1. For best performance
111 *> LWORK >= N*NB, where NB is the block size returned by ILAENV.
112 *> \endverbatim
113 *>
114 *> \param[out] INFO
115 *> \verbatim
116 *> INFO is INTEGER
117 *> = 0: successful exit
118 *> < 0: if INFO = -i, the i-th argument had an illegal value
119 *> > 0: if INFO = i, D(i,i) is exactly zero. The factorization
120 *> has been completed, but the block diagonal matrix D is
121 *> exactly singular, and division by zero will occur if it
122 *> is used to solve a system of equations.
123 *> \endverbatim
124 *
125 * Authors:
126 * ========
127 *
128 *> \author Univ. of Tennessee
129 *> \author Univ. of California Berkeley
130 *> \author Univ. of Colorado Denver
131 *> \author NAG Ltd.
132 *
133 *> \ingroup complex16HEcomputational
134 *
135 *> \par Further Details:
136 * =====================
137 *>
138 *> \verbatim
139 *>
140 *> If UPLO = 'U', then A = U*D*U**H, where
141 *> U = P(n)*U(n)* ... *P(k)U(k)* ...,
142 *> i.e., U is a product of terms P(k)*U(k), where k decreases from n to
143 *> 1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
144 *> and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
145 *> defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
146 *> that if the diagonal block D(k) is of order s (s = 1 or 2), then
147 *>
148 *> ( I v 0 ) k-s
149 *> U(k) = ( 0 I 0 ) s
150 *> ( 0 0 I ) n-k
151 *> k-s s n-k
152 *>
153 *> If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
154 *> If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
155 *> and A(k,k), and v overwrites A(1:k-2,k-1:k).
156 *>
157 *> If UPLO = 'L', then A = L*D*L**H, where
158 *> L = P(1)*L(1)* ... *P(k)*L(k)* ...,
159 *> i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
160 *> n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
161 *> and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
162 *> defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
163 *> that if the diagonal block D(k) is of order s (s = 1 or 2), then
164 *>
165 *> ( I 0 0 ) k-1
166 *> L(k) = ( 0 I 0 ) s
167 *> ( 0 v I ) n-k-s+1
168 *> k-1 s n-k-s+1
169 *>
170 *> If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
171 *> If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
172 *> and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).
173 *> \endverbatim
174 *>
175 * =====================================================================
176  SUBROUTINE zhetrf( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
177 *
178 * -- LAPACK computational routine --
179 * -- LAPACK is a software package provided by Univ. of Tennessee, --
180 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
181 *
182 * .. Scalar Arguments ..
183  CHARACTER UPLO
184  INTEGER INFO, LDA, LWORK, N
185 * ..
186 * .. Array Arguments ..
187  INTEGER IPIV( * )
188  COMPLEX*16 A( LDA, * ), WORK( * )
189 * ..
190 *
191 * =====================================================================
192 *
193 * .. Local Scalars ..
194  LOGICAL LQUERY, UPPER
195  INTEGER IINFO, IWS, J, K, KB, LDWORK, LWKOPT, NB, NBMIN
196 * ..
197 * .. External Functions ..
198  LOGICAL LSAME
199  INTEGER ILAENV
200  EXTERNAL lsame, ilaenv
201 * ..
202 * .. External Subroutines ..
203  EXTERNAL xerbla, zhetf2, zlahef
204 * ..
205 * .. Intrinsic Functions ..
206  INTRINSIC max
207 * ..
208 * .. Executable Statements ..
209 *
210 * Test the input parameters.
211 *
212  info = 0
213  upper = lsame( uplo, 'U' )
214  lquery = ( lwork.EQ.-1 )
215  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
216  info = -1
217  ELSE IF( n.LT.0 ) THEN
218  info = -2
219  ELSE IF( lda.LT.max( 1, n ) ) THEN
220  info = -4
221  ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
222  info = -7
223  END IF
224 *
225  IF( info.EQ.0 ) THEN
226 *
227 * Determine the block size
228 *
229  nb = ilaenv( 1, 'ZHETRF', uplo, n, -1, -1, -1 )
230  lwkopt = n*nb
231  work( 1 ) = lwkopt
232  END IF
233 *
234  IF( info.NE.0 ) THEN
235  CALL xerbla( 'ZHETRF', -info )
236  RETURN
237  ELSE IF( lquery ) THEN
238  RETURN
239  END IF
240 *
241  nbmin = 2
242  ldwork = n
243  IF( nb.GT.1 .AND. nb.LT.n ) THEN
244  iws = ldwork*nb
245  IF( lwork.LT.iws ) THEN
246  nb = max( lwork / ldwork, 1 )
247  nbmin = max( 2, ilaenv( 2, 'ZHETRF', uplo, n, -1, -1, -1 ) )
248  END IF
249  ELSE
250  iws = 1
251  END IF
252  IF( nb.LT.nbmin )
253  $ nb = n
254 *
255  IF( upper ) THEN
256 *
257 * Factorize A as U*D*U**H using the upper triangle of A
258 *
259 * K is the main loop index, decreasing from N to 1 in steps of
260 * KB, where KB is the number of columns factorized by ZLAHEF;
261 * KB is either NB or NB-1, or K for the last block
262 *
263  k = n
264  10 CONTINUE
265 *
266 * If K < 1, exit from loop
267 *
268  IF( k.LT.1 )
269  $ GO TO 40
270 *
271  IF( k.GT.nb ) THEN
272 *
273 * Factorize columns k-kb+1:k of A and use blocked code to
274 * update columns 1:k-kb
275 *
276  CALL zlahef( uplo, k, nb, kb, a, lda, ipiv, work, n, iinfo )
277  ELSE
278 *
279 * Use unblocked code to factorize columns 1:k of A
280 *
281  CALL zhetf2( uplo, k, a, lda, ipiv, iinfo )
282  kb = k
283  END IF
284 *
285 * Set INFO on the first occurrence of a zero pivot
286 *
287  IF( info.EQ.0 .AND. iinfo.GT.0 )
288  $ info = iinfo
289 *
290 * Decrease K and return to the start of the main loop
291 *
292  k = k - kb
293  GO TO 10
294 *
295  ELSE
296 *
297 * Factorize A as L*D*L**H using the lower triangle of A
298 *
299 * K is the main loop index, increasing from 1 to N in steps of
300 * KB, where KB is the number of columns factorized by ZLAHEF;
301 * KB is either NB or NB-1, or N-K+1 for the last block
302 *
303  k = 1
304  20 CONTINUE
305 *
306 * If K > N, exit from loop
307 *
308  IF( k.GT.n )
309  $ GO TO 40
310 *
311  IF( k.LE.n-nb ) THEN
312 *
313 * Factorize columns k:k+kb-1 of A and use blocked code to
314 * update columns k+kb:n
315 *
316  CALL zlahef( uplo, n-k+1, nb, kb, a( k, k ), lda, ipiv( k ),
317  $ work, n, iinfo )
318  ELSE
319 *
320 * Use unblocked code to factorize columns k:n of A
321 *
322  CALL zhetf2( uplo, n-k+1, a( k, k ), lda, ipiv( k ), iinfo )
323  kb = n - k + 1
324  END IF
325 *
326 * Set INFO on the first occurrence of a zero pivot
327 *
328  IF( info.EQ.0 .AND. iinfo.GT.0 )
329  $ info = iinfo + k - 1
330 *
331 * Adjust IPIV
332 *
333  DO 30 j = k, k + kb - 1
334  IF( ipiv( j ).GT.0 ) THEN
335  ipiv( j ) = ipiv( j ) + k - 1
336  ELSE
337  ipiv( j ) = ipiv( j ) - k + 1
338  END IF
339  30 CONTINUE
340 *
341 * Increase K and return to the start of the main loop
342 *
343  k = k + kb
344  GO TO 20
345 *
346  END IF
347 *
348  40 CONTINUE
349  work( 1 ) = lwkopt
350  RETURN
351 *
352 * End of ZHETRF
353 *
354  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine zhetf2(UPLO, N, A, LDA, IPIV, INFO)
ZHETF2 computes the factorization of a complex Hermitian matrix, using the diagonal pivoting method (...
Definition: zhetf2.f:191
subroutine zlahef(UPLO, N, NB, KB, A, LDA, IPIV, W, LDW, INFO)
ZLAHEF computes a partial factorization of a complex Hermitian indefinite matrix using the Bunch-Kauf...
Definition: zlahef.f:177
subroutine zhetrf(UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO)
ZHETRF
Definition: zhetrf.f:177