zqpt01()

double precision function zqpt01	(	integer	m,
		integer	n,
		integer	k,
		complex*16, dimension( lda, * )	a,
		complex*16, dimension( lda, * )	af,
		integer	lda,
		complex*16, dimension( * )	tau,
		integer, dimension( * )	jpvt,
		complex*16, dimension( lwork )	work,
		integer	lwork
	)

ZQPT01

Purpose:

 ZQPT01 tests the QR-factorization with pivoting of a matrix A.  The
 array AF contains the (possibly partial) QR-factorization of A, where
 the upper triangle of AF(1:k,1:k) is a partial triangular factor,
 the entries below the diagonal in the first k columns are the
 Householder vectors, and the rest of AF contains a partially updated
 matrix.

 This function returns ||A*P - Q*R|| / ( ||norm(A)||*eps*max(M,N) )

Parameters

[in]	M	M is INTEGER The number of rows of the matrices A and AF.
[in]	N	N is INTEGER The number of columns of the matrices A and AF.
[in]	K	K is INTEGER The number of columns of AF that have been reduced to upper triangular form.
[in]	A	A is COMPLEX*16 array, dimension (LDA, N) The original matrix A.
[in]	AF	AF is COMPLEX*16 array, dimension (LDA,N) The (possibly partial) output of ZGEQPF. The upper triangle of AF(1:k,1:k) is a partial triangular factor, the entries below the diagonal in the first k columns are the Householder vectors, and the rest of AF contains a partially updated matrix.
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A and AF.
[in]	TAU	TAU is COMPLEX*16 array, dimension (K) Details of the Householder transformations as returned by ZGEQPF.
[in]	JPVT	JPVT is INTEGER array, dimension (N) Pivot information as returned by ZGEQPF.
[out]	WORK	WORK is COMPLEX*16 array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= M*N+N.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 118 of file zqpt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            JPVT( * )
      COMPLEX*16         A( LDA, * ), AF( LDA, * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, J
      DOUBLE PRECISION   NORMA
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   RWORK( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANGE
      EXTERNAL           dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zaxpy, zcopy, zunmqr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max, min
*     ..
*     .. Executable Statements ..
*
      zqpt01 = zero
*
*     Test if there is enough workspace
*
      IF( lwork.LT.m*n+n ) THEN
         CALL xerbla( 'ZQPT01', 10 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      norma = zlange( 'One-norm', m, n, a, lda, rwork )
*
      DO j = 1, k
         DO i = 1, min( j, m )
            work( ( j-1 )*m+i ) = af( i, j )
         END DO
         DO i = j + 1, m
            work( ( j-1 )*m+i ) = zero
         END DO
      END DO
      DO j = k + 1, n
         CALL zcopy( m, af( 1, j ), 1, work( ( j-1 )*m+1 ), 1 )
      END DO
*
      CALL zunmqr( 'Left', 'No transpose', m, n, k, af, lda, tau, work,
     $             m, work( m*n+1 ), lwork-m*n, info )
*
      DO j = 1, n
*
*        Compare i-th column of QR and jpvt(i)-th column of A
*
         CALL zaxpy( m, dcmplx( -one ), a( 1, jpvt( j ) ), 1,
     $               work( ( j-1 )*m+1 ), 1 )
      END DO
*
      zqpt01 = zlange( 'One-norm', m, n, work, m, rwork ) /
     $         ( dble( max( m, n ) )*dlamch( 'Epsilon' ) )
      IF( norma.NE.zero )
     $   zqpt01 = zqpt01 / norma
*
      RETURN
*
*     End of ZQPT01
*

Here is the call graph for this function:

Here is the caller graph for this function: