dchkbd()

subroutine dchkbd	(	integer	nsizes,
		integer, dimension( * )	mval,
		integer, dimension( * )	nval,
		integer	ntypes,
		logical, dimension( * )	dotype,
		integer	nrhs,
		integer, dimension( 4 )	iseed,
		double precision	thresh,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	bd,
		double precision, dimension( * )	be,
		double precision, dimension( * )	s1,
		double precision, dimension( * )	s2,
		double precision, dimension( ldx, * )	x,
		integer	ldx,
		double precision, dimension( ldx, * )	y,
		double precision, dimension( ldx, * )	z,
		double precision, dimension( ldq, * )	q,
		integer	ldq,
		double precision, dimension( ldpt, * )	pt,
		integer	ldpt,
		double precision, dimension( ldpt, * )	u,
		double precision, dimension( ldpt, * )	vt,
		double precision, dimension( * )	work,
		integer	lwork,
		integer, dimension( * )	iwork,
		integer	nout,
		integer	info )

DCHKBD

Purpose:

!>
!> DCHKBD checks the singular value decomposition (SVD) routines.
!>
!> DGEBRD reduces a real general m by n matrix A to upper or lower
!> bidiagonal form B by an orthogonal transformation:  Q' * A * P = B
!> (or A = Q * B * P').  The matrix B is upper bidiagonal if m >= n
!> and lower bidiagonal if m < n.
!>
!> DORGBR generates the orthogonal matrices Q and P' from DGEBRD.
!> Note that Q and P are not necessarily square.
!>
!> DBDSQR computes the singular value decomposition of the bidiagonal
!> matrix B as B = U S V'.  It is called three times to compute
!>    1)  B = U S1 V', where S1 is the diagonal matrix of singular
!>        values and the columns of the matrices U and V are the left
!>        and right singular vectors, respectively, of B.
!>    2)  Same as 1), but the singular values are stored in S2 and the
!>        singular vectors are not computed.
!>    3)  A = (UQ) S (P'V'), the SVD of the original matrix A.
!> In addition, DBDSQR has an option to apply the left orthogonal matrix
!> U to a matrix X, useful in least squares applications.
!>
!> DBDSDC computes the singular value decomposition of the bidiagonal
!> matrix B as B = U S V' using divide-and-conquer. It is called twice
!> to compute
!>    1) B = U S1 V', where S1 is the diagonal matrix of singular
!>        values and the columns of the matrices U and V are the left
!>        and right singular vectors, respectively, of B.
!>    2) Same as 1), but the singular values are stored in S2 and the
!>        singular vectors are not computed.
!>
!>  DBDSVDX computes the singular value decomposition of the bidiagonal
!>  matrix B as B = U S V' using bisection and inverse iteration. It is
!>  called six times to compute
!>     1) B = U S1 V', RANGE='A', where S1 is the diagonal matrix of singular
!>         values and the columns of the matrices U and V are the left
!>         and right singular vectors, respectively, of B.
!>     2) Same as 1), but the singular values are stored in S2 and the
!>         singular vectors are not computed.
!>     3) B = U S1 V', RANGE='I', with where S1 is the diagonal matrix of singular
!>         values and the columns of the matrices U and V are the left
!>         and right singular vectors, respectively, of B
!>     4) Same as 3), but the singular values are stored in S2 and the
!>         singular vectors are not computed.
!>     5) B = U S1 V', RANGE='V', with where S1 is the diagonal matrix of singular
!>         values and the columns of the matrices U and V are the left
!>         and right singular vectors, respectively, of B
!>     6) Same as 5), but the singular values are stored in S2 and the
!>         singular vectors are not computed.
!>
!> For each pair of matrix dimensions (M,N) and each selected matrix
!> type, an M by N matrix A and an M by NRHS matrix X are generated.
!> The problem dimensions are as follows
!>    A:          M x N
!>    Q:          M x min(M,N) (but M x M if NRHS > 0)
!>    P:          min(M,N) x N
!>    B:          min(M,N) x min(M,N)
!>    U, V:       min(M,N) x min(M,N)
!>    S1, S2      diagonal, order min(M,N)
!>    X:          M x NRHS
!>
!> For each generated matrix, 14 tests are performed:
!>
!> Test DGEBRD and DORGBR
!>
!> (1)   | A - Q B PT | / ( |A| max(M,N) ulp ), PT = P'
!>
!> (2)   | I - Q' Q | / ( M ulp )
!>
!> (3)   | I - PT PT' | / ( N ulp )
!>
!> Test DBDSQR on bidiagonal matrix B
!>
!> (4)   | B - U S1 VT | / ( |B| min(M,N) ulp ), VT = V'
!>
!> (5)   | Y - U Z | / ( |Y| max(min(M,N),k) ulp ), where Y = Q' X
!>                                                  and   Z = U' Y.
!> (6)   | I - U' U | / ( min(M,N) ulp )
!>
!> (7)   | I - VT VT' | / ( min(M,N) ulp )
!>
!> (8)   S1 contains min(M,N) nonnegative values in decreasing order.
!>       (Return 0 if true, 1/ULP if false.)
!>
!> (9)   | S1 - S2 | / ( |S1| ulp ), where S2 is computed without
!>                                   computing U and V.
!>
!> (10)  0 if the true singular values of B are within THRESH of
!>       those in S1.  2*THRESH if they are not.  (Tested using
!>       DSVDCH)
!>
!> Test DBDSQR on matrix A
!>
!> (11)  | A - (QU) S (VT PT) | / ( |A| max(M,N) ulp )
!>
!> (12)  | X - (QU) Z | / ( |X| max(M,k) ulp )
!>
!> (13)  | I - (QU)'(QU) | / ( M ulp )
!>
!> (14)  | I - (VT PT) (PT'VT') | / ( N ulp )
!>
!> Test DBDSDC on bidiagonal matrix B
!>
!> (15)  | B - U S1 VT | / ( |B| min(M,N) ulp ), VT = V'
!>
!> (16)  | I - U' U | / ( min(M,N) ulp )
!>
!> (17)  | I - VT VT' | / ( min(M,N) ulp )
!>
!> (18)  S1 contains min(M,N) nonnegative values in decreasing order.
!>       (Return 0 if true, 1/ULP if false.)
!>
!> (19)  | S1 - S2 | / ( |S1| ulp ), where S2 is computed without
!>                                   computing U and V.
!>  Test DBDSVDX on bidiagonal matrix B
!>
!>  (20)  | B - U S1 VT | / ( |B| min(M,N) ulp ), VT = V'
!>
!>  (21)  | I - U' U | / ( min(M,N) ulp )
!>
!>  (22)  | I - VT VT' | / ( min(M,N) ulp )
!>
!>  (23)  S1 contains min(M,N) nonnegative values in decreasing order.
!>        (Return 0 if true, 1/ULP if false.)
!>
!>  (24)  | S1 - S2 | / ( |S1| ulp ), where S2 is computed without
!>                                    computing U and V.
!>
!>  (25)  | S1 - U' B VT' | / ( |S| n ulp )    DBDSVDX('V', 'I')
!>
!>  (26)  | I - U' U | / ( min(M,N) ulp )
!>
!>  (27)  | I - VT VT' | / ( min(M,N) ulp )
!>
!>  (28)  S1 contains min(M,N) nonnegative values in decreasing order.
!>        (Return 0 if true, 1/ULP if false.)
!>
!>  (29)  | S1 - S2 | / ( |S1| ulp ), where S2 is computed without
!>                                    computing U and V.
!>
!>  (30)  | S1 - U' B VT' | / ( |S1| n ulp )   DBDSVDX('V', 'V')
!>
!>  (31)  | I - U' U | / ( min(M,N) ulp )
!>
!>  (32)  | I - VT VT' | / ( min(M,N) ulp )
!>
!>  (33)  S1 contains min(M,N) nonnegative values in decreasing order.
!>        (Return 0 if true, 1/ULP if false.)
!>
!>  (34)  | S1 - S2 | / ( |S1| ulp ), where S2 is computed without
!>                                    computing U and V.
!>
!> The possible matrix types are
!>
!> (1)  The zero matrix.
!> (2)  The identity matrix.
!>
!> (3)  A diagonal matrix with evenly spaced entries
!>      1, ..., ULP  and random signs.
!>      (ULP = (first number larger than 1) - 1 )
!> (4)  A diagonal matrix with geometrically spaced entries
!>      1, ..., ULP  and random signs.
!> (5)  A diagonal matrix with  entries 1, ULP, ..., ULP
!>      and random signs.
!>
!> (6)  Same as (3), but multiplied by SQRT( overflow threshold )
!> (7)  Same as (3), but multiplied by SQRT( underflow threshold )
!>
!> (8)  A matrix of the form  U D V, where U and V are orthogonal and
!>      D has evenly spaced entries 1, ..., ULP with random signs
!>      on the diagonal.
!>
!> (9)  A matrix of the form  U D V, where U and V are orthogonal and
!>      D has geometrically spaced entries 1, ..., ULP with random
!>      signs on the diagonal.
!>
!> (10) A matrix of the form  U D V, where U and V are orthogonal and
!>      D has  entries 1, ULP,..., ULP with random
!>      signs on the diagonal.
!>
!> (11) Same as (8), but multiplied by SQRT( overflow threshold )
!> (12) Same as (8), but multiplied by SQRT( underflow threshold )
!>
!> (13) Rectangular matrix with random entries chosen from (-1,1).
!> (14) Same as (13), but multiplied by SQRT( overflow threshold )
!> (15) Same as (13), but multiplied by SQRT( underflow threshold )
!>
!> Special case:
!> (16) A bidiagonal matrix with random entries chosen from a
!>      logarithmic distribution on [ulp^2,ulp^(-2)]  (I.e., each
!>      entry is  e^x, where x is chosen uniformly on
!>      [ 2 log(ulp), -2 log(ulp) ] .)  For *this* type:
!>      (a) DGEBRD is not called to reduce it to bidiagonal form.
!>      (b) the bidiagonal is  min(M,N) x min(M,N); if M<N, the
!>          matrix will be lower bidiagonal, otherwise upper.
!>      (c) only tests 5--8 and 14 are performed.
!>
!> A subset of the full set of matrix types may be selected through
!> the logical array DOTYPE.
!> 

Parameters

[in]	NSIZES	!> NSIZES is INTEGER !> The number of values of M and N contained in the vectors !> MVAL and NVAL. The matrix sizes are used in pairs (M,N). !>
[in]	MVAL	!> MVAL is INTEGER array, dimension (NM) !> The values of the matrix row dimension M. !>
[in]	NVAL	!> NVAL is INTEGER array, dimension (NM) !> The values of the matrix column dimension N. !>
[in]	NTYPES	!> NTYPES is INTEGER !> The number of elements in DOTYPE. If it is zero, DCHKBD !> does nothing. It must be at least zero. If it is MAXTYP+1 !> and NSIZES is 1, then an additional type, MAXTYP+1 is !> defined, which is to use whatever matrices are in A and B. !> This is only useful if DOTYPE(1:MAXTYP) is .FALSE. and !> DOTYPE(MAXTYP+1) is .TRUE. . !>
[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> If DOTYPE(j) is .TRUE., then for each size (m,n), a matrix !> of type j will be generated. If NTYPES is smaller than the !> maximum number of types defined (PARAMETER MAXTYP), then !> types NTYPES+1 through MAXTYP will not be generated. If !> NTYPES is larger than MAXTYP, DOTYPE(MAXTYP+1) through !> DOTYPE(NTYPES) will be ignored. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns in the matrices X, Y, !> and Z, used in testing DBDSQR. If NRHS = 0, then the !> operations on the right-hand side will not be tested. !> NRHS must be at least 0. !>
[in,out]	ISEED	!> ISEED is INTEGER array, dimension (4) !> On entry ISEED specifies the seed of the random number !> generator. The array elements should be between 0 and 4095; !> if not they will be reduced mod 4096. Also, ISEED(4) must !> be odd. The values of ISEED are changed on exit, and can be !> used in the next call to DCHKBD to continue the same random !> number sequence. !>
[in]	THRESH	!> THRESH is DOUBLE PRECISION !> The threshold value for the test ratios. A result is !> included in the output file if RESULT >= THRESH. To have !> every test ratio printed, use THRESH = 0. Note that the !> expected value of the test ratios is O(1), so THRESH should !> be a reasonably small multiple of 1, e.g., 10 or 100. !>
[out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,NMAX) !> where NMAX is the maximum value of N in NVAL. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,MMAX), !> where MMAX is the maximum value of M in MVAL. !>
[out]	BD	!> BD is DOUBLE PRECISION array, dimension !> (max(min(MVAL(j),NVAL(j)))) !>
[out]	BE	!> BE is DOUBLE PRECISION array, dimension !> (max(min(MVAL(j),NVAL(j)))) !>
[out]	S1	!> S1 is DOUBLE PRECISION array, dimension !> (max(min(MVAL(j),NVAL(j)))) !>
[out]	S2	!> S2 is DOUBLE PRECISION array, dimension !> (max(min(MVAL(j),NVAL(j)))) !>
[out]	X	!> X is DOUBLE PRECISION array, dimension (LDX,NRHS) !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the arrays X, Y, and Z. !> LDX >= max(1,MMAX) !>
[out]	Y	!> Y is DOUBLE PRECISION array, dimension (LDX,NRHS) !>
[out]	Z	!> Z is DOUBLE PRECISION array, dimension (LDX,NRHS) !>
[out]	Q	!> Q is DOUBLE PRECISION array, dimension (LDQ,MMAX) !>
[in]	LDQ	!> LDQ is INTEGER !> The leading dimension of the array Q. LDQ >= max(1,MMAX). !>
[out]	PT	!> PT is DOUBLE PRECISION array, dimension (LDPT,NMAX) !>
[in]	LDPT	!> LDPT is INTEGER !> The leading dimension of the arrays PT, U, and V. !> LDPT >= max(1, max(min(MVAL(j),NVAL(j)))). !>
[out]	U	!> U is DOUBLE PRECISION array, dimension !> (LDPT,max(min(MVAL(j),NVAL(j)))) !>
[out]	VT	!> VT is DOUBLE PRECISION array, dimension !> (LDPT,max(min(MVAL(j),NVAL(j)))) !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The number of entries in WORK. This must be at least !> 3(M+N) and M(M + max(M,N,k) + 1) + N*min(M,N) for all !> pairs (M,N)=(MM(j),NN(j)) !>
[out]	IWORK	!> IWORK is INTEGER array, dimension at least 8*min(M,N) !>
[in]	NOUT	!> NOUT is INTEGER !> The FORTRAN unit number for printing out error messages !> (e.g., if a routine returns IINFO not equal to 0.) !>
[out]	INFO	!> INFO is INTEGER !> If 0, then everything ran OK. !> -1: NSIZES < 0 !> -2: Some MM(j) < 0 !> -3: Some NN(j) < 0 !> -4: NTYPES < 0 !> -6: NRHS < 0 !> -8: THRESH < 0 !> -11: LDA < 1 or LDA < MMAX, where MMAX is max( MM(j) ). !> -17: LDB < 1 or LDB < MMAX. !> -21: LDQ < 1 or LDQ < MMAX. !> -23: LDPT< 1 or LDPT< MNMAX. !> -27: LWORK too small. !> If DLATMR, SLATMS, DGEBRD, DORGBR, or DBDSQR, !> returns an error code, the !> absolute value of it is returned. !> !>----------------------------------------------------------------------- !> !> Some Local Variables and Parameters: !> ---- ----- --------- --- ---------- !> !> ZERO, ONE Real 0 and 1. !> MAXTYP The number of types defined. !> NTEST The number of tests performed, or which can !> be performed so far, for the current matrix. !> MMAX Largest value in NN. !> NMAX Largest value in NN. !> MNMIN min(MM(j), NN(j)) (the dimension of the bidiagonal !> matrix.) !> MNMAX The maximum value of MNMIN for j=1,...,NSIZES. !> NFAIL The number of tests which have exceeded THRESH !> COND, IMODE Values to be passed to the matrix generators. !> ANORM Norm of A; passed to matrix generators. !> !> OVFL, UNFL Overflow and underflow thresholds. !> RTOVFL, RTUNFL Square roots of the previous 2 values. !> ULP, ULPINV Finest relative precision and its inverse. !> !> The following four arrays decode JTYPE: !> KTYPE(j) The general type (1-10) for type . !> KMODE(j) The MODE value to be passed to the matrix !> generator for type . !> KMAGN(j) The order of magnitude ( O(1), !> O(overflow^(1/2) ), O(underflow^(1/2) ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 489 of file dchkbd.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDPT, LDQ, LDX, LWORK, NOUT, NRHS,
     $                   NSIZES, NTYPES
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            ISEED( 4 ), IWORK( * ), MVAL( * ), NVAL( * )
      DOUBLE PRECISION   A( LDA, * ), BD( * ), BE( * ), PT( LDPT, * ),
     $                   Q( LDQ, * ), S1( * ), S2( * ), U( LDPT, * ),
     $                   VT( LDPT, * ), WORK( * ), X( LDX, * ),
     $                   Y( LDX, * ), Z( LDX, * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE, TWO, HALF
      parameter( zero = 0.0d0, one = 1.0d0, two = 2.0d0,
     $                   half = 0.5d0 )
      INTEGER            MAXTYP
      parameter( maxtyp = 16 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADMM, BADNN, BIDIAG
      CHARACTER          UPLO
      CHARACTER*3        PATH
      INTEGER            I, IINFO, IL, IMODE, ITEMP, ITYPE, IU, IWBD,
     $                   IWBE, IWBS, IWBZ, IWWORK, J, JCOL, JSIZE,
     $                   JTYPE, LOG2UI, M, MINWRK, MMAX, MNMAX, MNMIN,
     $                   MNMIN2, MQ, MTYPES, N, NFAIL, NMAX,
     $                   NS1, NS2, NTEST
      DOUBLE PRECISION   ABSTOL, AMNINV, ANORM, COND, OVFL, RTOVFL,
     $                   RTUNFL, TEMP1, TEMP2, ULP, ULPINV, UNFL,
     $                   VL, VU
*     ..
*     .. Local Arrays ..
      INTEGER            IDUM( 1 ), IOLDSD( 4 ), ISEED2( 4 ),
     $                   KMAGN( MAXTYP ), KMODE( MAXTYP ),
     $                   KTYPE( MAXTYP )
      DOUBLE PRECISION   DUM( 1 ), DUMMA( 1 ), RESULT( 40 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLARND, DSXT1
      EXTERNAL           dlamch, dlarnd, dsxt1
*     ..
*     .. External Subroutines ..
      EXTERNAL           alasum, dbdsdc, dbdsqr, dbdsvdx, dbdt01,
     $                   dbdt02, dbdt03, dbdt04, dcopy, dgebrd,
     $                   dgemm, dlacpy, dlahd2, dlaset, dlatmr,
     $                   dlatms, dorgbr, dort01, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, exp, int, log, max, min, sqrt
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA            ktype / 1, 2, 5*4, 5*6, 3*9, 10 /
      DATA            kmagn / 2*1, 3*1, 2, 3, 3*1, 2, 3, 1, 2, 3, 0 /
      DATA            kmode / 2*0, 4, 3, 1, 4, 4, 4, 3, 1, 4, 4, 0,
     $                0, 0, 0 /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      info = 0
*
      badmm = .false.
      badnn = .false.
      mmax = 1
      nmax = 1
      mnmax = 1
      minwrk = 1
      DO 10 j = 1, nsizes
         mmax = max( mmax, mval( j ) )
         IF( mval( j ).LT.0 )
     $      badmm = .true.
         nmax = max( nmax, nval( j ) )
         IF( nval( j ).LT.0 )
     $      badnn = .true.
         mnmax = max( mnmax, min( mval( j ), nval( j ) ) )
         minwrk = max( minwrk, 3*( mval( j )+nval( j ) ),
     $            mval( j )*( mval( j )+max( mval( j ), nval( j ),
     $            nrhs )+1 )+nval( j )*min( nval( j ), mval( j ) ) )
   10 CONTINUE
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badmm ) THEN
         info = -2
      ELSE IF( badnn ) THEN
         info = -3
      ELSE IF( ntypes.LT.0 ) THEN
         info = -4
      ELSE IF( nrhs.LT.0 ) THEN
         info = -6
      ELSE IF( lda.LT.mmax ) THEN
         info = -11
      ELSE IF( ldx.LT.mmax ) THEN
         info = -17
      ELSE IF( ldq.LT.mmax ) THEN
         info = -21
      ELSE IF( ldpt.LT.mnmax ) THEN
         info = -23
      ELSE IF( minwrk.GT.lwork ) THEN
         info = -27
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DCHKBD', -info )
         RETURN
      END IF
*
*     Initialize constants
*
      path( 1: 1 ) = 'Double precision'
      path( 2: 3 ) = 'BD'
      nfail = 0
      ntest = 0
      unfl = dlamch( 'Safe minimum' )
      ovfl = dlamch( 'Overflow' )
      ulp = dlamch( 'Precision' )
      ulpinv = one / ulp
      log2ui = int( log( ulpinv ) / log( two ) )
      rtunfl = sqrt( unfl )
      rtovfl = sqrt( ovfl )
      infot = 0
      abstol = 2*unfl
*
*     Loop over sizes, types
*
      DO 300 jsize = 1, nsizes
         m = mval( jsize )
         n = nval( jsize )
         mnmin = min( m, n )
         amninv = one / max( m, n, 1 )
*
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
         DO 290 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         GO TO 290
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       CONTINUE
*
            DO 30 j = 1, 34
               result( j ) = -one
   30       CONTINUE
*
            uplo = ' '
*
*           Compute "A"
*
*           Control parameters:
*
*           KMAGN  KMODE        KTYPE
*       =1  O(1)   clustered 1  zero
*       =2  large  clustered 2  identity
*       =3  small  exponential  (none)
*       =4         arithmetic   diagonal, (w/ eigenvalues)
*       =5         random       symmetric, w/ eigenvalues
*       =6                      nonsymmetric, w/ singular values
*       =7                      random diagonal
*       =8                      random symmetric
*       =9                      random nonsymmetric
*       =10                     random bidiagonal (log. distrib.)
*
            IF( mtypes.GT.maxtyp )
     $         GO TO 100
*
            itype = ktype( jtype )
            imode = kmode( jtype )
*
*           Compute norm
*
            GO TO ( 40, 50, 60 )kmagn( jtype )
*
   40       CONTINUE
            anorm = one
            GO TO 70
*
   50       CONTINUE
            anorm = ( rtovfl*ulp )*amninv
            GO TO 70
*
   60       CONTINUE
            anorm = rtunfl*max( m, n )*ulpinv
            GO TO 70
*
   70       CONTINUE
*
            CALL dlaset( 'Full', lda, n, zero, zero, a, lda )
            iinfo = 0
            cond = ulpinv
*
            bidiag = .false.
            IF( itype.EQ.1 ) THEN
*
*              Zero matrix
*
               iinfo = 0
*
            ELSE IF( itype.EQ.2 ) THEN
*
*              Identity
*
               DO 80 jcol = 1, mnmin
                  a( jcol, jcol ) = anorm
   80          CONTINUE
*
            ELSE IF( itype.EQ.4 ) THEN
*
*              Diagonal Matrix, [Eigen]values Specified
*
               CALL dlatms( mnmin, mnmin, 'S', iseed, 'N', work, imode,
     $                      cond, anorm, 0, 0, 'N', a, lda,
     $                      work( mnmin+1 ), iinfo )
*
            ELSE IF( itype.EQ.5 ) THEN
*
*              Symmetric, eigenvalues specified
*
               CALL dlatms( mnmin, mnmin, 'S', iseed, 'S', work, imode,
     $                      cond, anorm, m, n, 'N', a, lda,
     $                      work( mnmin+1 ), iinfo )
*
            ELSE IF( itype.EQ.6 ) THEN
*
*              Nonsymmetric, singular values specified
*
               CALL dlatms( m, n, 'S', iseed, 'N', work, imode, cond,
     $                      anorm, m, n, 'N', a, lda, work( mnmin+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.7 ) THEN
*
*              Diagonal, random entries
*
               CALL dlatmr( mnmin, mnmin, 'S', iseed, 'N', work, 6, one,
     $                      one, 'T', 'N', work( mnmin+1 ), 1, one,
     $                      work( 2*mnmin+1 ), 1, one, 'N', iwork, 0, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.8 ) THEN
*
*              Symmetric, random entries
*
               CALL dlatmr( mnmin, mnmin, 'S', iseed, 'S', work, 6, one,
     $                      one, 'T', 'N', work( mnmin+1 ), 1, one,
     $                      work( m+mnmin+1 ), 1, one, 'N', iwork, m, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.9 ) THEN
*
*              Nonsymmetric, random entries
*
               CALL dlatmr( m, n, 'S', iseed, 'N', work, 6, one, one,
     $                      'T', 'N', work( mnmin+1 ), 1, one,
     $                      work( m+mnmin+1 ), 1, one, 'N', iwork, m, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.10 ) THEN
*
*              Bidiagonal, random entries
*
               temp1 = -two*log( ulp )
               DO 90 j = 1, mnmin
                  bd( j ) = exp( temp1*dlarnd( 2, iseed ) )
                  IF( j.LT.mnmin )
     $               be( j ) = exp( temp1*dlarnd( 2, iseed ) )
   90          CONTINUE
*
               iinfo = 0
               bidiag = .true.
               IF( m.GE.n ) THEN
                  uplo = 'U'
               ELSE
                  uplo = 'L'
               END IF
            ELSE
               iinfo = 1
            END IF
*
            IF( iinfo.EQ.0 ) THEN
*
*              Generate Right-Hand Side
*
               IF( bidiag ) THEN
                  CALL dlatmr( mnmin, nrhs, 'S', iseed, 'N', work, 6,
     $                         one, one, 'T', 'N', work( mnmin+1 ), 1,
     $                         one, work( 2*mnmin+1 ), 1, one, 'N',
     $                         iwork, mnmin, nrhs, zero, one, 'NO', y,
     $                         ldx, iwork, iinfo )
               ELSE
                  CALL dlatmr( m, nrhs, 'S', iseed, 'N', work, 6, one,
     $                         one, 'T', 'N', work( m+1 ), 1, one,
     $                         work( 2*m+1 ), 1, one, 'N', iwork, m,
     $                         nrhs, zero, one, 'NO', x, ldx, iwork,
     $                         iinfo )
               END IF
            END IF
*
*           Error Exit
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'Generator', iinfo, m, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               RETURN
            END IF
*
  100       CONTINUE
*
*           Call DGEBRD and DORGBR to compute B, Q, and P, do tests.
*
            IF( .NOT.bidiag ) THEN
*
*              Compute transformations to reduce A to bidiagonal form:
*              B := Q' * A * P.
*
               CALL dlacpy( ' ', m, n, a, lda, q, ldq )
               CALL dgebrd( m, n, q, ldq, bd, be, work, work( mnmin+1 ),
     $                      work( 2*mnmin+1 ), lwork-2*mnmin, iinfo )
*
*              Check error code from DGEBRD.
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nout, fmt = 9998 )'DGEBRD', iinfo, m, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  RETURN
               END IF
*
               CALL dlacpy( ' ', m, n, q, ldq, pt, ldpt )
               IF( m.GE.n ) THEN
                  uplo = 'U'
               ELSE
                  uplo = 'L'
               END IF
*
*              Generate Q
*
               mq = m
               IF( nrhs.LE.0 )
     $            mq = mnmin
               CALL dorgbr( 'Q', m, mq, n, q, ldq, work,
     $                      work( 2*mnmin+1 ), lwork-2*mnmin, iinfo )
*
*              Check error code from DORGBR.
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nout, fmt = 9998 )'DORGBR(Q)', iinfo, m, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  RETURN
               END IF
*
*              Generate P'
*
               CALL dorgbr( 'P', mnmin, n, m, pt, ldpt, work( mnmin+1 ),
     $                      work( 2*mnmin+1 ), lwork-2*mnmin, iinfo )
*
*              Check error code from DORGBR.
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nout, fmt = 9998 )'DORGBR(P)', iinfo, m, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  RETURN
               END IF
*
*              Apply Q' to an M by NRHS matrix X:  Y := Q' * X.
*
               CALL dgemm( 'Transpose', 'No transpose', m, nrhs, m, one,
     $                     q, ldq, x, ldx, zero, y, ldx )
*
*              Test 1:  Check the decomposition A := Q * B * PT
*                   2:  Check the orthogonality of Q
*                   3:  Check the orthogonality of PT
*
               CALL dbdt01( m, n, 1, a, lda, q, ldq, bd, be, pt, ldpt,
     $                      work, result( 1 ) )
               CALL dort01( 'Columns', m, mq, q, ldq, work, lwork,
     $                      result( 2 ) )
               CALL dort01( 'Rows', mnmin, n, pt, ldpt, work, lwork,
     $                      result( 3 ) )
            END IF
*
*           Use DBDSQR to form the SVD of the bidiagonal matrix B:
*           B := U * S1 * VT, and compute Z = U' * Y.
*
            CALL dcopy( mnmin, bd, 1, s1, 1 )
            IF( mnmin.GT.0 )
     $         CALL dcopy( mnmin-1, be, 1, work, 1 )
            CALL dlacpy( ' ', m, nrhs, y, ldx, z, ldx )
            CALL dlaset( 'Full', mnmin, mnmin, zero, one, u, ldpt )
            CALL dlaset( 'Full', mnmin, mnmin, zero, one, vt, ldpt )
*
            CALL dbdsqr( uplo, mnmin, mnmin, mnmin, nrhs, s1, work, vt,
     $                   ldpt, u, ldpt, z, ldx, work( mnmin+1 ), iinfo )
*
*           Check error code from DBDSQR.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'DBDSQR(vects)', iinfo, m, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 4 ) = ulpinv
                  GO TO 270
               END IF
            END IF
*
*           Use DBDSQR to compute only the singular values of the
*           bidiagonal matrix B;  U, VT, and Z should not be modified.
*
            CALL dcopy( mnmin, bd, 1, s2, 1 )
            IF( mnmin.GT.0 )
     $         CALL dcopy( mnmin-1, be, 1, work, 1 )
*
            CALL dbdsqr( uplo, mnmin, 0, 0, 0, s2, work, vt, ldpt, u,
     $                   ldpt, z, ldx, work( mnmin+1 ), iinfo )
*
*           Check error code from DBDSQR.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'DBDSQR(values)', iinfo, m, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 9 ) = ulpinv
                  GO TO 270
               END IF
            END IF
*
*           Test 4:  Check the decomposition B := U * S1 * VT
*                5:  Check the computation Z := U' * Y
*                6:  Check the orthogonality of U
*                7:  Check the orthogonality of VT
*
            CALL dbdt03( uplo, mnmin, 1, bd, be, u, ldpt, s1, vt, ldpt,
     $                   work, result( 4 ) )
            CALL dbdt02( mnmin, nrhs, y, ldx, z, ldx, u, ldpt, work,
     $                   result( 5 ) )
            CALL dort01( 'Columns', mnmin, mnmin, u, ldpt, work, lwork,
     $                   result( 6 ) )
            CALL dort01( 'Rows', mnmin, mnmin, vt, ldpt, work, lwork,
     $                   result( 7 ) )
*
*           Test 8:  Check that the singular values are sorted in
*                    non-increasing order and are non-negative
*
            result( 8 ) = zero
            DO 110 i = 1, mnmin - 1
               IF( s1( i ).LT.s1( i+1 ) )
     $            result( 8 ) = ulpinv
               IF( s1( i ).LT.zero )
     $            result( 8 ) = ulpinv
  110       CONTINUE
            IF( mnmin.GE.1 ) THEN
               IF( s1( mnmin ).LT.zero )
     $            result( 8 ) = ulpinv
            END IF
*
*           Test 9:  Compare DBDSQR with and without singular vectors
*
            temp2 = zero
*
            DO 120 j = 1, mnmin
               temp1 = abs( s1( j )-s2( j ) ) /
     $                 max( sqrt( unfl )*max( s1( 1 ), one ),
     $                 ulp*max( abs( s1( j ) ), abs( s2( j ) ) ) )
               temp2 = max( temp1, temp2 )
  120       CONTINUE
*
            result( 9 ) = temp2
*
*           Test 10:  Sturm sequence test of singular values
*                     Go up by factors of two until it succeeds
*
            temp1 = thresh*( half-ulp )
*
            DO 130 j = 0, log2ui
*               CALL DSVDCH( MNMIN, BD, BE, S1, TEMP1, IINFO )
               IF( iinfo.EQ.0 )
     $            GO TO 140
               temp1 = temp1*two
  130       CONTINUE
*
  140       CONTINUE
            result( 10 ) = temp1
*
*           Use DBDSQR to form the decomposition A := (QU) S (VT PT)
*           from the bidiagonal form A := Q B PT.
*
            IF( .NOT.bidiag ) THEN
               CALL dcopy( mnmin, bd, 1, s2, 1 )
               IF( mnmin.GT.0 )
     $            CALL dcopy( mnmin-1, be, 1, work, 1 )
*
               CALL dbdsqr( uplo, mnmin, n, m, nrhs, s2, work, pt, ldpt,
     $                      q, ldq, y, ldx, work( mnmin+1 ), iinfo )
*
*              Test 11:  Check the decomposition A := Q*U * S2 * VT*PT
*                   12:  Check the computation Z := U' * Q' * X
*                   13:  Check the orthogonality of Q*U
*                   14:  Check the orthogonality of VT*PT
*
               CALL dbdt01( m, n, 0, a, lda, q, ldq, s2, dumma, pt,
     $                      ldpt, work, result( 11 ) )
               CALL dbdt02( m, nrhs, x, ldx, y, ldx, q, ldq, work,
     $                      result( 12 ) )
               CALL dort01( 'Columns', m, mq, q, ldq, work, lwork,
     $                      result( 13 ) )
               CALL dort01( 'Rows', mnmin, n, pt, ldpt, work, lwork,
     $                      result( 14 ) )
            END IF
*
*           Use DBDSDC to form the SVD of the bidiagonal matrix B:
*           B := U * S1 * VT
*
            CALL dcopy( mnmin, bd, 1, s1, 1 )
            IF( mnmin.GT.0 )
     $         CALL dcopy( mnmin-1, be, 1, work, 1 )
            CALL dlaset( 'Full', mnmin, mnmin, zero, one, u, ldpt )
            CALL dlaset( 'Full', mnmin, mnmin, zero, one, vt, ldpt )
*
            CALL dbdsdc( uplo, 'I', mnmin, s1, work, u, ldpt, vt, ldpt,
     $                   dum, idum, work( mnmin+1 ), iwork, iinfo )
*
*           Check error code from DBDSDC.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'DBDSDC(vects)', iinfo, m, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 15 ) = ulpinv
                  GO TO 270
               END IF
            END IF
*
*           Use DBDSDC to compute only the singular values of the
*           bidiagonal matrix B;  U and VT should not be modified.
*
            CALL dcopy( mnmin, bd, 1, s2, 1 )
            IF( mnmin.GT.0 )
     $         CALL dcopy( mnmin-1, be, 1, work, 1 )
*
            CALL dbdsdc( uplo, 'N', mnmin, s2, work, dum, 1, dum, 1,
     $                   dum, idum, work( mnmin+1 ), iwork, iinfo )
*
*           Check error code from DBDSDC.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'DBDSDC(values)', iinfo, m, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 18 ) = ulpinv
                  GO TO 270
               END IF
            END IF
*
*           Test 15:  Check the decomposition B := U * S1 * VT
*                16:  Check the orthogonality of U
*                17:  Check the orthogonality of VT
*
            CALL dbdt03( uplo, mnmin, 1, bd, be, u, ldpt, s1, vt, ldpt,
     $                   work, result( 15 ) )
            CALL dort01( 'Columns', mnmin, mnmin, u, ldpt, work, lwork,
     $                   result( 16 ) )
            CALL dort01( 'Rows', mnmin, mnmin, vt, ldpt, work, lwork,
     $                   result( 17 ) )
*
*           Test 18:  Check that the singular values are sorted in
*                     non-increasing order and are non-negative
*
            result( 18 ) = zero
            DO 150 i = 1, mnmin - 1
               IF( s1( i ).LT.s1( i+1 ) )
     $            result( 18 ) = ulpinv
               IF( s1( i ).LT.zero )
     $            result( 18 ) = ulpinv
  150       CONTINUE
            IF( mnmin.GE.1 ) THEN
               IF( s1( mnmin ).LT.zero )
     $            result( 18 ) = ulpinv
            END IF
*
*           Test 19:  Compare DBDSQR with and without singular vectors
*
            temp2 = zero
*
            DO 160 j = 1, mnmin
               temp1 = abs( s1( j )-s2( j ) ) /
     $                 max( sqrt( unfl )*max( s1( 1 ), one ),
     $                 ulp*max( abs( s1( 1 ) ), abs( s2( 1 ) ) ) )
               temp2 = max( temp1, temp2 )
  160       CONTINUE
*
            result( 19 ) = temp2
*
*
*           Use DBDSVDX to compute the SVD of the bidiagonal matrix B:
*           B := U * S1 * VT
*
            IF( jtype.EQ.10 .OR. jtype.EQ.16 ) THEN
*              =================================
*              Matrix types temporarily disabled
*              =================================
               result( 20:34 ) = zero
               GO TO 270
            END IF
*
            iwbs = 1
            iwbd = iwbs + mnmin
            iwbe = iwbd + mnmin
            iwbz = iwbe + mnmin
            iwwork = iwbz + 2*mnmin*(mnmin+1)
            mnmin2 = max( 1,mnmin*2 )
*
            CALL dcopy( mnmin, bd, 1, work( iwbd ), 1 )
            IF( mnmin.GT.0 )
     $         CALL dcopy( mnmin-1, be, 1, work( iwbe ), 1 )
*
            CALL dbdsvdx( uplo, 'V', 'A', mnmin, work( iwbd ),
     $                    work( iwbe ), zero, zero, 0, 0, ns1, s1,
     $                    work( iwbz ), mnmin2, work( iwwork ),
     $                    iwork, iinfo)
*
*           Check error code from DBDSVDX.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'DBDSVDX(vects,A)', iinfo, m, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 20 ) = ulpinv
                  GO TO 270
               END IF
            END IF
*
            j = iwbz
            DO 170 i = 1, ns1
               CALL dcopy( mnmin, work( j ), 1, u( 1,i ), 1 )
               j = j + mnmin
               CALL dcopy( mnmin, work( j ), 1, vt( i,1 ), ldpt )
               j = j + mnmin
  170       CONTINUE
*
*           Use DBDSVDX to compute only the singular values of the
*           bidiagonal matrix B;  U and VT should not be modified.
*
            IF( jtype.EQ.9 ) THEN
*              =================================
*              Matrix types temporarily disabled
*              =================================
               result( 24 ) = zero
               GO TO 270
            END IF
*
            CALL dcopy( mnmin, bd, 1, work( iwbd ), 1 )
            IF( mnmin.GT.0 )
     $         CALL dcopy( mnmin-1, be, 1, work( iwbe ), 1 )
*
            CALL dbdsvdx( uplo, 'N', 'A', mnmin, work( iwbd ),
     $                    work( iwbe ), zero, zero, 0, 0, ns2, s2,
     $                    work( iwbz ), mnmin2, work( iwwork ),
     $                    iwork, iinfo )
*
*           Check error code from DBDSVDX.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'DBDSVDX(values,A)', iinfo,
     $            m, n, jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 24 ) = ulpinv
                  GO TO 270
               END IF
            END IF
*
*           Save S1 for tests 30-34.
*
            CALL dcopy( mnmin, s1, 1, work( iwbs ), 1 )
*
*           Test 20:  Check the decomposition B := U * S1 * VT
*                21:  Check the orthogonality of U
*                22:  Check the orthogonality of VT
*                23:  Check that the singular values are sorted in
*                     non-increasing order and are non-negative
*                24:  Compare DBDSVDX with and without singular vectors
*
            CALL dbdt03( uplo, mnmin, 1, bd, be, u, ldpt, s1, vt,
     $                   ldpt, work( iwbs+mnmin ), result( 20 ) )
            CALL dort01( 'Columns', mnmin, mnmin, u, ldpt,
     $                   work( iwbs+mnmin ), lwork-mnmin,
     $                   result( 21 ) )
            CALL dort01( 'Rows', mnmin, mnmin, vt, ldpt,
     $                   work( iwbs+mnmin ), lwork-mnmin,
     $                   result( 22) )
*
            result( 23 ) = zero
            DO 180 i = 1, mnmin - 1
               IF( s1( i ).LT.s1( i+1 ) )
     $            result( 23 ) = ulpinv
               IF( s1( i ).LT.zero )
     $            result( 23 ) = ulpinv
  180       CONTINUE
            IF( mnmin.GE.1 ) THEN
               IF( s1( mnmin ).LT.zero )
     $            result( 23 ) = ulpinv
            END IF
*
            temp2 = zero
            DO 190 j = 1, mnmin
               temp1 = abs( s1( j )-s2( j ) ) /
     $                 max( sqrt( unfl )*max( s1( 1 ), one ),
     $                 ulp*max( abs( s1( 1 ) ), abs( s2( 1 ) ) ) )
               temp2 = max( temp1, temp2 )
  190       CONTINUE
            result( 24 ) = temp2
            anorm = s1( 1 )
*
*           Use DBDSVDX with RANGE='I': choose random values for IL and
*           IU, and ask for the IL-th through IU-th singular values
*           and corresponding vectors.
*
            DO 200 i = 1, 4
               iseed2( i ) = iseed( i )
  200       CONTINUE
            IF( mnmin.LE.1 ) THEN
               il = 1
               iu = mnmin
            ELSE
               il = 1 + int( ( mnmin-1 )*dlarnd( 1, iseed2 ) )
               iu = 1 + int( ( mnmin-1 )*dlarnd( 1, iseed2 ) )
               IF( iu.LT.il ) THEN
                  itemp = iu
                  iu = il
                  il = itemp
               END IF
            END IF
*
            CALL dcopy( mnmin, bd, 1, work( iwbd ), 1 )
            IF( mnmin.GT.0 )
     $         CALL dcopy( mnmin-1, be, 1, work( iwbe ), 1 )
*
            CALL dbdsvdx( uplo, 'V', 'I', mnmin, work( iwbd ),
     $                    work( iwbe ), zero, zero, il, iu, ns1, s1,
     $                    work( iwbz ), mnmin2, work( iwwork ),
     $                    iwork, iinfo)
*
*           Check error code from DBDSVDX.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'DBDSVDX(vects,I)', iinfo,
     $            m, n, jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 25 ) = ulpinv
                  GO TO 270
               END IF
            END IF
*
            j = iwbz
            DO 210 i = 1, ns1
               CALL dcopy( mnmin, work( j ), 1, u( 1,i ), 1 )
               j = j + mnmin
               CALL dcopy( mnmin, work( j ), 1, vt( i,1 ), ldpt )
               j = j + mnmin
  210       CONTINUE
*
*           Use DBDSVDX to compute only the singular values of the
*           bidiagonal matrix B;  U and VT should not be modified.
*
            CALL dcopy( mnmin, bd, 1, work( iwbd ), 1 )
            IF( mnmin.GT.0 )
     $         CALL dcopy( mnmin-1, be, 1, work( iwbe ), 1 )
*
            CALL dbdsvdx( uplo, 'N', 'I', mnmin, work( iwbd ),
     $                    work( iwbe ), zero, zero, il, iu, ns2, s2,
     $                    work( iwbz ), mnmin2, work( iwwork ),
     $                    iwork, iinfo )
*
*           Check error code from DBDSVDX.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'DBDSVDX(values,I)', iinfo,
     $            m, n, jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 29 ) = ulpinv
                  GO TO 270
               END IF
            END IF
*
*           Test 25:  Check S1 - U' * B * VT'
*                26:  Check the orthogonality of U
*                27:  Check the orthogonality of VT
*                28:  Check that the singular values are sorted in
*                     non-increasing order and are non-negative
*                29:  Compare DBDSVDX with and without singular vectors
*
            CALL dbdt04( uplo, mnmin, bd, be, s1, ns1, u,
     $                   ldpt, vt, ldpt, work( iwbs+mnmin ),
     $                   result( 25 ) )
            CALL dort01( 'Columns', mnmin, ns1, u, ldpt,
     $                   work( iwbs+mnmin ), lwork-mnmin,
     $                   result( 26 ) )
            CALL dort01( 'Rows', ns1, mnmin, vt, ldpt,
     $                   work( iwbs+mnmin ), lwork-mnmin,
     $                   result( 27 ) )
*
            result( 28 ) = zero
            DO 220 i = 1, ns1 - 1
               IF( s1( i ).LT.s1( i+1 ) )
     $            result( 28 ) = ulpinv
               IF( s1( i ).LT.zero )
     $            result( 28 ) = ulpinv
  220       CONTINUE
            IF( ns1.GE.1 ) THEN
               IF( s1( ns1 ).LT.zero )
     $            result( 28 ) = ulpinv
            END IF
*
            temp2 = zero
            DO 230 j = 1, ns1
               temp1 = abs( s1( j )-s2( j ) ) /
     $                 max( sqrt( unfl )*max( s1( 1 ), one ),
     $                 ulp*max( abs( s1( 1 ) ), abs( s2( 1 ) ) ) )
               temp2 = max( temp1, temp2 )
  230       CONTINUE
            result( 29 ) = temp2
*
*           Use DBDSVDX with RANGE='V': determine the values VL and VU
*           of the IL-th and IU-th singular values and ask for all
*           singular values in this range.
*
            CALL dcopy( mnmin, work( iwbs ), 1, s1, 1 )
*
            IF( mnmin.GT.0 ) THEN
               IF( il.NE.1 ) THEN
                  vu = s1( il ) + max( half*abs( s1( il )-s1( il-1 ) ),
     $                 ulp*anorm, two*rtunfl )
               ELSE
                  vu = s1( 1 ) + max( half*abs( s1( mnmin )-s1( 1 ) ),
     $                 ulp*anorm, two*rtunfl )
               END IF
               IF( iu.NE.ns1 ) THEN
                  vl = s1( iu ) - max( ulp*anorm, two*rtunfl,
     $                 half*abs( s1( iu+1 )-s1( iu ) ) )
               ELSE
                  vl = s1( ns1 ) - max( ulp*anorm, two*rtunfl,
     $                 half*abs( s1( mnmin )-s1( 1 ) ) )
               END IF
               vl = max( vl,zero )
               vu = max( vu,zero )
               IF( vl.GE.vu ) vu = max( vu*2, vu+vl+half )
            ELSE
               vl = zero
               vu = one
            END IF
*
            CALL dcopy( mnmin, bd, 1, work( iwbd ), 1 )
            IF( mnmin.GT.0 )
     $         CALL dcopy( mnmin-1, be, 1, work( iwbe ), 1 )
*
            CALL dbdsvdx( uplo, 'V', 'V', mnmin, work( iwbd ),
     $                    work( iwbe ), vl, vu, 0, 0, ns1, s1,
     $                    work( iwbz ), mnmin2, work( iwwork ),
     $                    iwork, iinfo )
*
*           Check error code from DBDSVDX.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'DBDSVDX(vects,V)', iinfo,
     $            m, n, jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 30 ) = ulpinv
                  GO TO 270
               END IF
            END IF
*
            j = iwbz
            DO 240 i = 1, ns1
               CALL dcopy( mnmin, work( j ), 1, u( 1,i ), 1 )
               j = j + mnmin
               CALL dcopy( mnmin, work( j ), 1, vt( i,1 ), ldpt )
               j = j + mnmin
  240       CONTINUE
*
*           Use DBDSVDX to compute only the singular values of the
*           bidiagonal matrix B;  U and VT should not be modified.
*
            CALL dcopy( mnmin, bd, 1, work( iwbd ), 1 )
            IF( mnmin.GT.0 )
     $         CALL dcopy( mnmin-1, be, 1, work( iwbe ), 1 )
*
            CALL dbdsvdx( uplo, 'N', 'V', mnmin, work( iwbd ),
     $                    work( iwbe ), vl, vu, 0, 0, ns2, s2,
     $                    work( iwbz ), mnmin2, work( iwwork ),
     $                    iwork, iinfo )
*
*           Check error code from DBDSVDX.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'DBDSVDX(values,V)', iinfo,
     $            m, n, jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 34 ) = ulpinv
                  GO TO 270
               END IF
            END IF
*
*           Test 30:  Check S1 - U' * B * VT'
*                31:  Check the orthogonality of U
*                32:  Check the orthogonality of VT
*                33:  Check that the singular values are sorted in
*                     non-increasing order and are non-negative
*                34:  Compare DBDSVDX with and without singular vectors
*
            CALL dbdt04( uplo, mnmin, bd, be, s1, ns1, u,
     $                   ldpt, vt, ldpt, work( iwbs+mnmin ),
     $                   result( 30 ) )
            CALL dort01( 'Columns', mnmin, ns1, u, ldpt,
     $                   work( iwbs+mnmin ), lwork-mnmin,
     $                   result( 31 ) )
            CALL dort01( 'Rows', ns1, mnmin, vt, ldpt,
     $                   work( iwbs+mnmin ), lwork-mnmin,
     $                   result( 32 ) )
*
            result( 33 ) = zero
            DO 250 i = 1, ns1 - 1
               IF( s1( i ).LT.s1( i+1 ) )
     $            result( 28 ) = ulpinv
               IF( s1( i ).LT.zero )
     $            result( 28 ) = ulpinv
  250       CONTINUE
            IF( ns1.GE.1 ) THEN
               IF( s1( ns1 ).LT.zero )
     $            result( 28 ) = ulpinv
            END IF
*
            temp2 = zero
            DO 260 j = 1, ns1
               temp1 = abs( s1( j )-s2( j ) ) /
     $                 max( sqrt( unfl )*max( s1( 1 ), one ),
     $                 ulp*max( abs( s1( 1 ) ), abs( s2( 1 ) ) ) )
               temp2 = max( temp1, temp2 )
  260       CONTINUE
            result( 34 ) = temp2
*
*           End of Loop -- Check for RESULT(j) > THRESH
*
  270       CONTINUE
*
            DO 280 j = 1, 34
               IF( result( j ).GE.thresh ) THEN
                  IF( nfail.EQ.0 )
     $               CALL dlahd2( nout, path )
                  WRITE( nout, fmt = 9999 )m, n, jtype, ioldsd, j,
     $               result( j )
                  nfail = nfail + 1
               END IF
  280       CONTINUE
            IF( .NOT.bidiag ) THEN
               ntest = ntest + 34
            ELSE
               ntest = ntest + 30
            END IF
*
  290    CONTINUE
  300 CONTINUE
*
*     Summary
*
      CALL alasum( path, nout, nfail, ntest, 0 )
*
      RETURN
*
*     End of DCHKBD
*
 9999 FORMAT( ' M=', i5, ', N=', i5, ', type ', i2, ', seed=',
     $      4( i4, ',' ), ' test(', i2, ')=', g11.4 )
 9998 FORMAT( ' DCHKBD: ', a, ' returned INFO=', i6, '.', / 9x, 'M=',
     $      i6, ', N=', i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ),
     $      i5, ')' )
*

Here is the call graph for this function:

Here is the caller graph for this function: