zdrvsy_rook()

subroutine zdrvsy_rook	(	logical, dimension( * )	dotype,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nrhs,
		double precision	thresh,
		logical	tsterr,
		integer	nmax,
		complex*16, dimension( * )	a,
		complex*16, dimension( * )	afac,
		complex*16, dimension( * )	ainv,
		complex*16, dimension( * )	b,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	xact,
		complex*16, dimension( * )	work,
		double precision, dimension( * )	rwork,
		integer, dimension( * )	iwork,
		integer	nout )

ZDRVSY_ROOK

Purpose:

!>
!> ZDRVSY_ROOK tests the driver routines ZSYSV_ROOK.
!> 

Parameters

[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> The matrix types to be used for testing. Matrices of type j !> (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = !> .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used. !>
[in]	NN	!> NN is INTEGER !> The number of values of N contained in the vector NVAL. !>
[in]	NVAL	!> NVAL is INTEGER array, dimension (NN) !> The values of the matrix dimension N. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand side vectors to be generated for !> each linear system. !>
[in]	THRESH	!> THRESH is DOUBLE PRECISION !> The threshold value for the test ratios. A result is !> included in the output file if RESULT >= THRESH. To have !> every test ratio printed, use THRESH = 0. !>
[in]	TSTERR	!> TSTERR is LOGICAL !> Flag that indicates whether error exits are to be tested. !>
[in]	NMAX	!> NMAX is INTEGER !> The maximum value permitted for N, used in dimensioning the !> work arrays. !>
[out]	A	!> A is COMPLEX*16 array, dimension (NMAX*NMAX) !>
[out]	AFAC	!> AFAC is COMPLEX*16 array, dimension (NMAX*NMAX) !>
[out]	AINV	!> AINV is COMPLEX*16 array, dimension (NMAX*NMAX) !>
[out]	B	!> B is COMPLEX*16 array, dimension (NMAX*NRHS) !>
[out]	X	!> X is COMPLEX*16 array, dimension (NMAX*NRHS) !>
[out]	XACT	!> XACT is COMPLEX*16 array, dimension (NMAX*NRHS) !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (NMAX*max(2,NRHS)) !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (NMAX+2*NRHS) !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (NMAX) !>
[in]	NOUT	!> NOUT is INTEGER !> The unit number for output. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 150 of file zdrvsy_rook.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NOUT, NRHS
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NVAL( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( * ), AFAC( * ), AINV( * ), B( * ),
     $                   WORK( * ), X( * ), XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
      INTEGER            NTYPES, NTESTS
      parameter( ntypes = 11, ntests = 3 )
      INTEGER            NFACT
      parameter( nfact = 2 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ZEROT
      CHARACTER          DIST, FACT, TYPE, UPLO, XTYPE
      CHARACTER*3        MATPATH, PATH
      INTEGER            I, I1, I2, IFACT, IMAT, IN, INFO, IOFF, IUPLO,
     $                   IZERO, J, K, KL, KU, LDA, LWORK, MODE, N,
     $                   NB, NBMIN, NERRS, NFAIL, NIMAT, NRUN, NT
      DOUBLE PRECISION   AINVNM, ANORM, CNDNUM, RCONDC
*     ..
*     .. Local Arrays ..
      CHARACTER          FACTS( NFACT ), UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
 
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   ZLANSY
      EXTERNAL           zlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           aladhd, alaerh, alasvm, xlaenv, zerrvx, zget04,
     $                   zlacpy, zlarhs, zlaset, zlatb4, zlatms, zlatsy,
     $                   zpot05, zsysv_rook, zsyt01_rook, zsyt02,
     $                   zsytrf_rook, zsytri_rook
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' / , facts / 'F', 'N' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
*     Test path
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'SR'
*
*     Path to generate matrices
*
      matpath( 1: 1 ) = 'Zomplex precision'
      matpath( 2: 3 ) = 'SY'
*
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
      lwork = max( 2*nmax, nmax*nrhs )
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL zerrvx( path, nout )
      infot = 0
*
*     Set the block size and minimum block size for which the block
*     routine should be used, which will be later returned by ILAENV.
*
      nb = 1
      nbmin = 2
      CALL xlaenv( 1, nb )
      CALL xlaenv( 2, nbmin )
*
*     Do for each value of N in NVAL
*
      DO 180 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 170 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 170
*
*           Skip types 3, 4, 5, or 6 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.6
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 170
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 160 iuplo = 1, 2
               uplo = uplos( iuplo )
*
               IF( imat.NE.ntypes ) THEN
*
*              Begin generate the test matrix A.
*
*              Set up parameters with ZLATB4 for the matrix generator
*              based on the type of matrix to be generated.
*
                  CALL zlatb4( matpath, imat, n, n, TYPE, KL, KU, ANORM,
     $                         MODE, CNDNUM, DIST )
*
*              Generate a matrix with ZLATMS.
*
                  srnamt = 'ZLATMS'
                  CALL zlatms( n, n, dist, iseed, TYPE, RWORK, MODE,
     $                         CNDNUM, ANORM, KL, KU, UPLO, A, LDA,
     $                         WORK, INFO )
*
*              Check error code from DLATMS and handle error.
*
                  IF( info.NE.0 ) THEN
                     CALL alaerh( path, 'ZLATMS', info, 0, uplo, n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
                     GO TO 160
                  END IF
*
*                 For types 3-6, zero one or more rows and columns of
*                 the matrix to test that INFO is returned correctly.
*
                  IF( zerot ) THEN
                     IF( imat.EQ.3 ) THEN
                        izero = 1
                     ELSE IF( imat.EQ.4 ) THEN
                        izero = n
                     ELSE
                        izero = n / 2 + 1
                     END IF
*
                     IF( imat.LT.6 ) THEN
*
*                       Set row and column IZERO to zero.
*
                        IF( iuplo.EQ.1 ) THEN
                           ioff = ( izero-1 )*lda
                           DO 20 i = 1, izero - 1
                              a( ioff+i ) = zero
   20                      CONTINUE
                           ioff = ioff + izero
                           DO 30 i = izero, n
                              a( ioff ) = zero
                              ioff = ioff + lda
   30                      CONTINUE
                        ELSE
                           ioff = izero
                           DO 40 i = 1, izero - 1
                              a( ioff ) = zero
                              ioff = ioff + lda
   40                      CONTINUE
                           ioff = ioff - izero
                           DO 50 i = izero, n
                              a( ioff+i ) = zero
   50                      CONTINUE
                        END IF
                     ELSE
                        IF( iuplo.EQ.1 ) THEN
*
*                       Set the first IZERO rows and columns to zero.
*
                           ioff = 0
                           DO 70 j = 1, n
                              i2 = min( j, izero )
                              DO 60 i = 1, i2
                                 a( ioff+i ) = zero
   60                         CONTINUE
                              ioff = ioff + lda
   70                      CONTINUE
                        ELSE
*
*                       Set the first IZERO rows and columns to zero.
*
                           ioff = 0
                           DO 90 j = 1, n
                              i1 = max( j, izero )
                              DO 80 i = i1, n
                                 a( ioff+i ) = zero
   80                         CONTINUE
                              ioff = ioff + lda
   90                      CONTINUE
                        END IF
                     END IF
                  ELSE
                     izero = 0
                  END IF
               ELSE
*
*                 IMAT = NTYPES:  Use a special block diagonal matrix to
*                 test alternate code for the 2-by-2 blocks.
*
                  CALL zlatsy( uplo, n, a, lda, iseed )
               END IF
*
               DO 150 ifact = 1, nfact
*
*                 Do first for FACT = 'F', then for other values.
*
                  fact = facts( ifact )
*
*                 Compute the condition number for comparison with
*                 the value returned by ZSYSVX_ROOK.
*
                  IF( zerot ) THEN
                     IF( ifact.EQ.1 )
     $                  GO TO 150
                     rcondc = zero
*
                  ELSE IF( ifact.EQ.1 ) THEN
*
*                    Compute the 1-norm of A.
*
                     anorm = zlansy( '1', uplo, n, a, lda, rwork )
*
*                    Factor the matrix A.
*
 
                     CALL zlacpy( uplo, n, n, a, lda, afac, lda )
                     CALL zsytrf_rook( uplo, n, afac, lda, iwork, work,
     $                                 lwork, info )
*
*                    Compute inv(A) and take its norm.
*
                     CALL zlacpy( uplo, n, n, afac, lda, ainv, lda )
                     lwork = (n+nb+1)*(nb+3)
                     CALL zsytri_rook( uplo, n, ainv, lda, iwork,
     $                                 work, info )
                     ainvnm = zlansy( '1', uplo, n, ainv, lda, rwork )
*
*                    Compute the 1-norm condition number of A.
*
                     IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                        rcondc = one
                     ELSE
                        rcondc = ( one / anorm ) / ainvnm
                     END IF
                  END IF
*
*                 Form an exact solution and set the right hand side.
*
                  srnamt = 'ZLARHS'
                  CALL zlarhs( matpath, xtype, uplo, ' ', n, n, kl, ku,
     $                         nrhs, a, lda, xact, lda, b, lda, iseed,
     $                         info )
                  xtype = 'C'
*
*                 --- Test ZSYSV_ROOK  ---
*
                  IF( ifact.EQ.2 ) THEN
                     CALL zlacpy( uplo, n, n, a, lda, afac, lda )
                     CALL zlacpy( 'Full', n, nrhs, b, lda, x, lda )
*
*                    Factor the matrix and solve the system using
*                    ZSYSV_ROOK.
*
                     srnamt = 'ZSYSV_ROOK'
                     CALL zsysv_rook( uplo, n, nrhs, afac, lda, iwork,
     $                                x, lda, work, lwork, info )
*
*                    Adjust the expected value of INFO to account for
*                    pivoting.
*
                     k = izero
                     IF( k.GT.0 ) THEN
  100                   CONTINUE
                        IF( iwork( k ).LT.0 ) THEN
                           IF( iwork( k ).NE.-k ) THEN
                              k = -iwork( k )
                              GO TO 100
                           END IF
                        ELSE IF( iwork( k ).NE.k ) THEN
                           k = iwork( k )
                           GO TO 100
                        END IF
                     END IF
*
*                    Check error code from ZSYSV_ROOK and handle error.
*
                     IF( info.NE.k ) THEN
                        CALL alaerh( path, 'ZSYSV_ROOK', info, k, uplo,
     $                               n, n, -1, -1, nrhs, imat, nfail,
     $                               nerrs, nout )
                        GO TO 120
                     ELSE IF( info.NE.0 ) THEN
                        GO TO 120
                     END IF
*
*+    TEST 1      Reconstruct matrix from factors and compute
*                 residual.
*
                     CALL zsyt01_rook( uplo, n, a, lda, afac, lda,
     $                                 iwork, ainv, lda, rwork,
     $                                 result( 1 ) )
*
*+    TEST 2      Compute residual of the computed solution.
*
                     CALL zlacpy( 'Full', n, nrhs, b, lda, work, lda )
                     CALL zsyt02( uplo, n, nrhs, a, lda, x, lda, work,
     $                            lda, rwork, result( 2 ) )
*
*+    TEST 3
*                 Check solution from generated exact solution.
*
                     CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 3 ) )
                     nt = 3
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 110 k = 1, nt
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL aladhd( nout, path )
                           WRITE( nout, fmt = 9999 )'ZSYSV_ROOK', uplo,
     $                            n, imat, k, result( k )
                           nfail = nfail + 1
                        END IF
  110                CONTINUE
                     nrun = nrun + nt
  120                CONTINUE
                  END IF
*
  150          CONTINUE
*
  160       CONTINUE
  170    CONTINUE
  180 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasvm( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( 1x, a, ', UPLO=''', a1, ''', N =', i5, ', type ', i2,
     $      ', test ', i2, ', ratio =', g12.5 )
      RETURN
*
*     End of ZDRVSY_ROOK
*

Here is the call graph for this function:

Here is the caller graph for this function: