LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
csytrf.f
Go to the documentation of this file.
1*> \brief \b CSYTRF
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/csytrf.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/csytrf.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/csytrf.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE CSYTRF( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
22*
23* .. Scalar Arguments ..
24* CHARACTER UPLO
25* INTEGER INFO, LDA, LWORK, N
26* ..
27* .. Array Arguments ..
28* INTEGER IPIV( * )
29* COMPLEX A( LDA, * ), WORK( * )
30* ..
31*
32*
33*> \par Purpose:
34* =============
35*>
36*> \verbatim
37*>
38*> CSYTRF computes the factorization of a complex symmetric matrix A
39*> using the Bunch-Kaufman diagonal pivoting method. The form of the
40*> factorization is
41*>
42*> A = U*D*U**T or A = L*D*L**T
43*>
44*> where U (or L) is a product of permutation and unit upper (lower)
45*> triangular matrices, and D is symmetric and block diagonal with
46*> 1-by-1 and 2-by-2 diagonal blocks.
47*>
48*> This is the blocked version of the algorithm, calling Level 3 BLAS.
49*> \endverbatim
50*
51* Arguments:
52* ==========
53*
54*> \param[in] UPLO
55*> \verbatim
56*> UPLO is CHARACTER*1
57*> = 'U': Upper triangle of A is stored;
58*> = 'L': Lower triangle of A is stored.
59*> \endverbatim
60*>
61*> \param[in] N
62*> \verbatim
63*> N is INTEGER
64*> The order of the matrix A. N >= 0.
65*> \endverbatim
66*>
67*> \param[in,out] A
68*> \verbatim
69*> A is COMPLEX array, dimension (LDA,N)
70*> On entry, the symmetric matrix A. If UPLO = 'U', the leading
71*> N-by-N upper triangular part of A contains the upper
72*> triangular part of the matrix A, and the strictly lower
73*> triangular part of A is not referenced. If UPLO = 'L', the
74*> leading N-by-N lower triangular part of A contains the lower
75*> triangular part of the matrix A, and the strictly upper
76*> triangular part of A is not referenced.
77*>
78*> On exit, the block diagonal matrix D and the multipliers used
79*> to obtain the factor U or L (see below for further details).
80*> \endverbatim
81*>
82*> \param[in] LDA
83*> \verbatim
84*> LDA is INTEGER
85*> The leading dimension of the array A. LDA >= max(1,N).
86*> \endverbatim
87*>
88*> \param[out] IPIV
89*> \verbatim
90*> IPIV is INTEGER array, dimension (N)
91*> Details of the interchanges and the block structure of D.
92*> If IPIV(k) > 0, then rows and columns k and IPIV(k) were
93*> interchanged and D(k,k) is a 1-by-1 diagonal block.
94*> If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and
95*> columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k)
96*> is a 2-by-2 diagonal block. If UPLO = 'L' and IPIV(k) =
97*> IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were
98*> interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
99*> \endverbatim
100*>
101*> \param[out] WORK
102*> \verbatim
103*> WORK is COMPLEX array, dimension (MAX(1,LWORK))
104*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
105*> \endverbatim
106*>
107*> \param[in] LWORK
108*> \verbatim
109*> LWORK is INTEGER
110*> The length of WORK. LWORK >=1. For best performance
111*> LWORK >= N*NB, where NB is the block size returned by ILAENV.
112*>
113*> If LWORK = -1, then a workspace query is assumed; the routine
114*> only calculates the optimal size of the WORK array, returns
115*> this value as the first entry of the WORK array, and no error
116*> message related to LWORK is issued by XERBLA.
117*> \endverbatim
118*>
119*> \param[out] INFO
120*> \verbatim
121*> INFO is INTEGER
122*> = 0: successful exit
123*> < 0: if INFO = -i, the i-th argument had an illegal value
124*> > 0: if INFO = i, D(i,i) is exactly zero. The factorization
125*> has been completed, but the block diagonal matrix D is
126*> exactly singular, and division by zero will occur if it
127*> is used to solve a system of equations.
128*> \endverbatim
129*
130* Authors:
131* ========
132*
133*> \author Univ. of Tennessee
134*> \author Univ. of California Berkeley
135*> \author Univ. of Colorado Denver
136*> \author NAG Ltd.
137*
138*> \ingroup hetrf
139*
140*> \par Further Details:
141* =====================
142*>
143*> \verbatim
144*>
145*> If UPLO = 'U', then A = U*D*U**T, where
146*> U = P(n)*U(n)* ... *P(k)U(k)* ...,
147*> i.e., U is a product of terms P(k)*U(k), where k decreases from n to
148*> 1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
149*> and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
150*> defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
151*> that if the diagonal block D(k) is of order s (s = 1 or 2), then
152*>
153*> ( I v 0 ) k-s
154*> U(k) = ( 0 I 0 ) s
155*> ( 0 0 I ) n-k
156*> k-s s n-k
157*>
158*> If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
159*> If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
160*> and A(k,k), and v overwrites A(1:k-2,k-1:k).
161*>
162*> If UPLO = 'L', then A = L*D*L**T, where
163*> L = P(1)*L(1)* ... *P(k)*L(k)* ...,
164*> i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
165*> n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
166*> and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
167*> defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
168*> that if the diagonal block D(k) is of order s (s = 1 or 2), then
169*>
170*> ( I 0 0 ) k-1
171*> L(k) = ( 0 I 0 ) s
172*> ( 0 v I ) n-k-s+1
173*> k-1 s n-k-s+1
174*>
175*> If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
176*> If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
177*> and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).
178*> \endverbatim
179*>
180* =====================================================================
181 SUBROUTINE csytrf( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
182*
183* -- LAPACK computational routine --
184* -- LAPACK is a software package provided by Univ. of Tennessee, --
185* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
186*
187* .. Scalar Arguments ..
188 CHARACTER UPLO
189 INTEGER INFO, LDA, LWORK, N
190* ..
191* .. Array Arguments ..
192 INTEGER IPIV( * )
193 COMPLEX A( LDA, * ), WORK( * )
194* ..
195*
196* =====================================================================
197*
198* .. Local Scalars ..
199 LOGICAL LQUERY, UPPER
200 INTEGER IINFO, IWS, J, K, KB, LDWORK, LWKOPT, NB, NBMIN
201* ..
202* .. External Functions ..
203 LOGICAL LSAME
204 INTEGER ILAENV
205 REAL SROUNDUP_LWORK
206 EXTERNAL lsame, ilaenv, sroundup_lwork
207* ..
208* .. External Subroutines ..
209 EXTERNAL clasyf, csytf2, xerbla
210* ..
211* .. Intrinsic Functions ..
212 INTRINSIC max
213* ..
214* .. Executable Statements ..
215*
216* Test the input parameters.
217*
218 info = 0
219 upper = lsame( uplo, 'U' )
220 lquery = ( lwork.EQ.-1 )
221 IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
222 info = -1
223 ELSE IF( n.LT.0 ) THEN
224 info = -2
225 ELSE IF( lda.LT.max( 1, n ) ) THEN
226 info = -4
227 ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
228 info = -7
229 END IF
230*
231 IF( info.EQ.0 ) THEN
232*
233* Determine the block size
234*
235 nb = ilaenv( 1, 'CSYTRF', uplo, n, -1, -1, -1 )
236 lwkopt = max( 1, n*nb )
237 work( 1 ) = sroundup_lwork(lwkopt)
238 END IF
239*
240 IF( info.NE.0 ) THEN
241 CALL xerbla( 'CSYTRF', -info )
242 RETURN
243 ELSE IF( lquery ) THEN
244 RETURN
245 END IF
246*
247 nbmin = 2
248 ldwork = n
249 IF( nb.GT.1 .AND. nb.LT.n ) THEN
250 iws = ldwork*nb
251 IF( lwork.LT.iws ) THEN
252 nb = max( lwork / ldwork, 1 )
253 nbmin = max( 2, ilaenv( 2, 'CSYTRF', uplo, n, -1, -1, -1 ) )
254 END IF
255 ELSE
256 iws = 1
257 END IF
258 IF( nb.LT.nbmin )
259 \$ nb = n
260*
261 IF( upper ) THEN
262*
263* Factorize A as U*D*U**T using the upper triangle of A
264*
265* K is the main loop index, decreasing from N to 1 in steps of
266* KB, where KB is the number of columns factorized by CLASYF;
267* KB is either NB or NB-1, or K for the last block
268*
269 k = n
270 10 CONTINUE
271*
272* If K < 1, exit from loop
273*
274 IF( k.LT.1 )
275 \$ GO TO 40
276*
277 IF( k.GT.nb ) THEN
278*
279* Factorize columns k-kb+1:k of A and use blocked code to
280* update columns 1:k-kb
281*
282 CALL clasyf( uplo, k, nb, kb, a, lda, ipiv, work, n, iinfo )
283 ELSE
284*
285* Use unblocked code to factorize columns 1:k of A
286*
287 CALL csytf2( uplo, k, a, lda, ipiv, iinfo )
288 kb = k
289 END IF
290*
291* Set INFO on the first occurrence of a zero pivot
292*
293 IF( info.EQ.0 .AND. iinfo.GT.0 )
294 \$ info = iinfo
295*
296* Decrease K and return to the start of the main loop
297*
298 k = k - kb
299 GO TO 10
300*
301 ELSE
302*
303* Factorize A as L*D*L**T using the lower triangle of A
304*
305* K is the main loop index, increasing from 1 to N in steps of
306* KB, where KB is the number of columns factorized by CLASYF;
307* KB is either NB or NB-1, or N-K+1 for the last block
308*
309 k = 1
310 20 CONTINUE
311*
312* If K > N, exit from loop
313*
314 IF( k.GT.n )
315 \$ GO TO 40
316*
317 IF( k.LE.n-nb ) THEN
318*
319* Factorize columns k:k+kb-1 of A and use blocked code to
320* update columns k+kb:n
321*
322 CALL clasyf( uplo, n-k+1, nb, kb, a( k, k ), lda, ipiv( k ),
323 \$ work, n, iinfo )
324 ELSE
325*
326* Use unblocked code to factorize columns k:n of A
327*
328 CALL csytf2( uplo, n-k+1, a( k, k ), lda, ipiv( k ), iinfo )
329 kb = n - k + 1
330 END IF
331*
332* Set INFO on the first occurrence of a zero pivot
333*
334 IF( info.EQ.0 .AND. iinfo.GT.0 )
335 \$ info = iinfo + k - 1
336*
338*
339 DO 30 j = k, k + kb - 1
340 IF( ipiv( j ).GT.0 ) THEN
341 ipiv( j ) = ipiv( j ) + k - 1
342 ELSE
343 ipiv( j ) = ipiv( j ) - k + 1
344 END IF
345 30 CONTINUE
346*
347* Increase K and return to the start of the main loop
348*
349 k = k + kb
350 GO TO 20
351*
352 END IF
353*
354 40 CONTINUE
355 work( 1 ) = sroundup_lwork(lwkopt)
356 RETURN
357*
358* End of CSYTRF
359*
360 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine csytf2(uplo, n, a, lda, ipiv, info)
CSYTF2 computes the factorization of a real symmetric indefinite matrix, using the diagonal pivoting ...
Definition csytf2.f:191
subroutine csytrf(uplo, n, a, lda, ipiv, work, lwork, info)
CSYTRF
Definition csytrf.f:182
subroutine clasyf(uplo, n, nb, kb, a, lda, ipiv, w, ldw, info)
CLASYF computes a partial factorization of a complex symmetric matrix using the Bunch-Kaufman diagona...
Definition clasyf.f:177