LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
clanhe.f
Go to the documentation of this file.
1 *> \brief \b CLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CLANHE + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clanhe.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clanhe.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clanhe.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * REAL FUNCTION CLANHE( NORM, UPLO, N, A, LDA, WORK )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER NORM, UPLO
25 * INTEGER LDA, N
26 * ..
27 * .. Array Arguments ..
28 * REAL WORK( * )
29 * COMPLEX A( LDA, * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> CLANHE returns the value of the one norm, or the Frobenius norm, or
39 *> the infinity norm, or the element of largest absolute value of a
40 *> complex hermitian matrix A.
41 *> \endverbatim
42 *>
43 *> \return CLANHE
44 *> \verbatim
45 *>
46 *> CLANHE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47 *> (
48 *> ( norm1(A), NORM = '1', 'O' or 'o'
49 *> (
50 *> ( normI(A), NORM = 'I' or 'i'
51 *> (
52 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53 *>
54 *> where norm1 denotes the one norm of a matrix (maximum column sum),
55 *> normI denotes the infinity norm of a matrix (maximum row sum) and
56 *> normF denotes the Frobenius norm of a matrix (square root of sum of
57 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] NORM
64 *> \verbatim
65 *> NORM is CHARACTER*1
66 *> Specifies the value to be returned in CLANHE as described
67 *> above.
68 *> \endverbatim
69 *>
70 *> \param[in] UPLO
71 *> \verbatim
72 *> UPLO is CHARACTER*1
73 *> Specifies whether the upper or lower triangular part of the
74 *> hermitian matrix A is to be referenced.
75 *> = 'U': Upper triangular part of A is referenced
76 *> = 'L': Lower triangular part of A is referenced
77 *> \endverbatim
78 *>
79 *> \param[in] N
80 *> \verbatim
81 *> N is INTEGER
82 *> The order of the matrix A. N >= 0. When N = 0, CLANHE is
83 *> set to zero.
84 *> \endverbatim
85 *>
86 *> \param[in] A
87 *> \verbatim
88 *> A is COMPLEX array, dimension (LDA,N)
89 *> The hermitian matrix A. If UPLO = 'U', the leading n by n
90 *> upper triangular part of A contains the upper triangular part
91 *> of the matrix A, and the strictly lower triangular part of A
92 *> is not referenced. If UPLO = 'L', the leading n by n lower
93 *> triangular part of A contains the lower triangular part of
94 *> the matrix A, and the strictly upper triangular part of A is
95 *> not referenced. Note that the imaginary parts of the diagonal
96 *> elements need not be set and are assumed to be zero.
97 *> \endverbatim
98 *>
99 *> \param[in] LDA
100 *> \verbatim
101 *> LDA is INTEGER
102 *> The leading dimension of the array A. LDA >= max(N,1).
103 *> \endverbatim
104 *>
105 *> \param[out] WORK
106 *> \verbatim
107 *> WORK is REAL array, dimension (MAX(1,LWORK)),
108 *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
109 *> WORK is not referenced.
110 *> \endverbatim
111 *
112 * Authors:
113 * ========
114 *
115 *> \author Univ. of Tennessee
116 *> \author Univ. of California Berkeley
117 *> \author Univ. of Colorado Denver
118 *> \author NAG Ltd.
119 *
120 *> \ingroup complexHEauxiliary
121 *
122 * =====================================================================
123  REAL function clanhe( norm, uplo, n, a, lda, work )
124 *
125 * -- LAPACK auxiliary routine --
126 * -- LAPACK is a software package provided by Univ. of Tennessee, --
127 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128 *
129  IMPLICIT NONE
130 * .. Scalar Arguments ..
131  CHARACTER norm, uplo
132  INTEGER lda, n
133 * ..
134 * .. Array Arguments ..
135  REAL work( * )
136  COMPLEX a( lda, * )
137 * ..
138 *
139 * =====================================================================
140 *
141 * .. Parameters ..
142  REAL one, zero
143  parameter( one = 1.0e+0, zero = 0.0e+0 )
144 * ..
145 * .. Local Scalars ..
146  INTEGER i, j
147  REAL absa, sum, value
148 * ..
149 * .. Local Arrays ..
150  REAL ssq( 2 ), colssq( 2 )
151 * ..
152 * .. External Functions ..
153  LOGICAL lsame, sisnan
154  EXTERNAL lsame, sisnan
155 * ..
156 * .. External Subroutines ..
157  EXTERNAL classq, scombssq
158 * ..
159 * .. Intrinsic Functions ..
160  INTRINSIC abs, real, sqrt
161 * ..
162 * .. Executable Statements ..
163 *
164  IF( n.EQ.0 ) THEN
165  VALUE = zero
166  ELSE IF( lsame( norm, 'M' ) ) THEN
167 *
168 * Find max(abs(A(i,j))).
169 *
170  VALUE = zero
171  IF( lsame( uplo, 'U' ) ) THEN
172  DO 20 j = 1, n
173  DO 10 i = 1, j - 1
174  sum = abs( a( i, j ) )
175  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
176  10 CONTINUE
177  sum = abs( real( a( j, j ) ) )
178  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
179  20 CONTINUE
180  ELSE
181  DO 40 j = 1, n
182  sum = abs( real( a( j, j ) ) )
183  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
184  DO 30 i = j + 1, n
185  sum = abs( a( i, j ) )
186  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
187  30 CONTINUE
188  40 CONTINUE
189  END IF
190  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
191  $ ( norm.EQ.'1' ) ) THEN
192 *
193 * Find normI(A) ( = norm1(A), since A is hermitian).
194 *
195  VALUE = zero
196  IF( lsame( uplo, 'U' ) ) THEN
197  DO 60 j = 1, n
198  sum = zero
199  DO 50 i = 1, j - 1
200  absa = abs( a( i, j ) )
201  sum = sum + absa
202  work( i ) = work( i ) + absa
203  50 CONTINUE
204  work( j ) = sum + abs( real( a( j, j ) ) )
205  60 CONTINUE
206  DO 70 i = 1, n
207  sum = work( i )
208  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
209  70 CONTINUE
210  ELSE
211  DO 80 i = 1, n
212  work( i ) = zero
213  80 CONTINUE
214  DO 100 j = 1, n
215  sum = work( j ) + abs( real( a( j, j ) ) )
216  DO 90 i = j + 1, n
217  absa = abs( a( i, j ) )
218  sum = sum + absa
219  work( i ) = work( i ) + absa
220  90 CONTINUE
221  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
222  100 CONTINUE
223  END IF
224  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
225 *
226 * Find normF(A).
227 * SSQ(1) is scale
228 * SSQ(2) is sum-of-squares
229 * For better accuracy, sum each column separately.
230 *
231  ssq( 1 ) = zero
232  ssq( 2 ) = one
233 *
234 * Sum off-diagonals
235 *
236  IF( lsame( uplo, 'U' ) ) THEN
237  DO 110 j = 2, n
238  colssq( 1 ) = zero
239  colssq( 2 ) = one
240  CALL classq( j-1, a( 1, j ), 1,
241  $ colssq( 1 ), colssq( 2 ) )
242  CALL scombssq( ssq, colssq )
243  110 CONTINUE
244  ELSE
245  DO 120 j = 1, n - 1
246  colssq( 1 ) = zero
247  colssq( 2 ) = one
248  CALL classq( n-j, a( j+1, j ), 1,
249  $ colssq( 1 ), colssq( 2 ) )
250  CALL scombssq( ssq, colssq )
251  120 CONTINUE
252  END IF
253  ssq( 2 ) = 2*ssq( 2 )
254 *
255 * Sum diagonal
256 *
257  DO 130 i = 1, n
258  IF( real( a( i, i ) ).NE.zero ) THEN
259  absa = abs( real( a( i, i ) ) )
260  IF( ssq( 1 ).LT.absa ) THEN
261  ssq( 2 ) = one + ssq( 2 )*( ssq( 1 ) / absa )**2
262  ssq( 1 ) = absa
263  ELSE
264  ssq( 2 ) = ssq( 2 ) + ( absa / ssq( 1 ) )**2
265  END IF
266  END IF
267  130 CONTINUE
268  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
269  END IF
270 *
271  clanhe = VALUE
272  RETURN
273 *
274 * End of CLANHE
275 *
276  END
subroutine scombssq(V1, V2)
SCOMBSSQ adds two scaled sum of squares quantities
Definition: scombssq.f:60
subroutine classq(n, x, incx, scl, sumsq)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f90:126
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
real function clanhe(NORM, UPLO, N, A, LDA, WORK)
CLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: clanhe.f:124