LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
stgsja.f
Go to the documentation of this file.
1 *> \brief \b STGSJA
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download STGSJA + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/stgsja.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/stgsja.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/stgsja.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE STGSJA( JOBU, JOBV, JOBQ, M, P, N, K, L, A, LDA, B,
22 * LDB, TOLA, TOLB, ALPHA, BETA, U, LDU, V, LDV,
23 * Q, LDQ, WORK, NCYCLE, INFO )
24 *
25 * .. Scalar Arguments ..
26 * CHARACTER JOBQ, JOBU, JOBV
27 * INTEGER INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N,
28 * $ NCYCLE, P
29 * REAL TOLA, TOLB
30 * ..
31 * .. Array Arguments ..
32 * REAL A( LDA, * ), ALPHA( * ), B( LDB, * ),
33 * $ BETA( * ), Q( LDQ, * ), U( LDU, * ),
34 * $ V( LDV, * ), WORK( * )
35 * ..
36 *
37 *
38 *> \par Purpose:
39 * =============
40 *>
41 *> \verbatim
42 *>
43 *> STGSJA computes the generalized singular value decomposition (GSVD)
44 *> of two real upper triangular (or trapezoidal) matrices A and B.
45 *>
46 *> On entry, it is assumed that matrices A and B have the following
47 *> forms, which may be obtained by the preprocessing subroutine SGGSVP
48 *> from a general M-by-N matrix A and P-by-N matrix B:
49 *>
50 *> N-K-L K L
51 *> A = K ( 0 A12 A13 ) if M-K-L >= 0;
52 *> L ( 0 0 A23 )
53 *> M-K-L ( 0 0 0 )
54 *>
55 *> N-K-L K L
56 *> A = K ( 0 A12 A13 ) if M-K-L < 0;
57 *> M-K ( 0 0 A23 )
58 *>
59 *> N-K-L K L
60 *> B = L ( 0 0 B13 )
61 *> P-L ( 0 0 0 )
62 *>
63 *> where the K-by-K matrix A12 and L-by-L matrix B13 are nonsingular
64 *> upper triangular; A23 is L-by-L upper triangular if M-K-L >= 0,
65 *> otherwise A23 is (M-K)-by-L upper trapezoidal.
66 *>
67 *> On exit,
68 *>
69 *> U**T *A*Q = D1*( 0 R ), V**T *B*Q = D2*( 0 R ),
70 *>
71 *> where U, V and Q are orthogonal matrices.
72 *> R is a nonsingular upper triangular matrix, and D1 and D2 are
73 *> ``diagonal'' matrices, which are of the following structures:
74 *>
75 *> If M-K-L >= 0,
76 *>
77 *> K L
78 *> D1 = K ( I 0 )
79 *> L ( 0 C )
80 *> M-K-L ( 0 0 )
81 *>
82 *> K L
83 *> D2 = L ( 0 S )
84 *> P-L ( 0 0 )
85 *>
86 *> N-K-L K L
87 *> ( 0 R ) = K ( 0 R11 R12 ) K
88 *> L ( 0 0 R22 ) L
89 *>
90 *> where
91 *>
92 *> C = diag( ALPHA(K+1), ... , ALPHA(K+L) ),
93 *> S = diag( BETA(K+1), ... , BETA(K+L) ),
94 *> C**2 + S**2 = I.
95 *>
96 *> R is stored in A(1:K+L,N-K-L+1:N) on exit.
97 *>
98 *> If M-K-L < 0,
99 *>
100 *> K M-K K+L-M
101 *> D1 = K ( I 0 0 )
102 *> M-K ( 0 C 0 )
103 *>
104 *> K M-K K+L-M
105 *> D2 = M-K ( 0 S 0 )
106 *> K+L-M ( 0 0 I )
107 *> P-L ( 0 0 0 )
108 *>
109 *> N-K-L K M-K K+L-M
110 *> ( 0 R ) = K ( 0 R11 R12 R13 )
111 *> M-K ( 0 0 R22 R23 )
112 *> K+L-M ( 0 0 0 R33 )
113 *>
114 *> where
115 *> C = diag( ALPHA(K+1), ... , ALPHA(M) ),
116 *> S = diag( BETA(K+1), ... , BETA(M) ),
117 *> C**2 + S**2 = I.
118 *>
119 *> R = ( R11 R12 R13 ) is stored in A(1:M, N-K-L+1:N) and R33 is stored
120 *> ( 0 R22 R23 )
121 *> in B(M-K+1:L,N+M-K-L+1:N) on exit.
122 *>
123 *> The computation of the orthogonal transformation matrices U, V or Q
124 *> is optional. These matrices may either be formed explicitly, or they
125 *> may be postmultiplied into input matrices U1, V1, or Q1.
126 *> \endverbatim
127 *
128 * Arguments:
129 * ==========
130 *
131 *> \param[in] JOBU
132 *> \verbatim
133 *> JOBU is CHARACTER*1
134 *> = 'U': U must contain an orthogonal matrix U1 on entry, and
135 *> the product U1*U is returned;
136 *> = 'I': U is initialized to the unit matrix, and the
137 *> orthogonal matrix U is returned;
138 *> = 'N': U is not computed.
139 *> \endverbatim
140 *>
141 *> \param[in] JOBV
142 *> \verbatim
143 *> JOBV is CHARACTER*1
144 *> = 'V': V must contain an orthogonal matrix V1 on entry, and
145 *> the product V1*V is returned;
146 *> = 'I': V is initialized to the unit matrix, and the
147 *> orthogonal matrix V is returned;
148 *> = 'N': V is not computed.
149 *> \endverbatim
150 *>
151 *> \param[in] JOBQ
152 *> \verbatim
153 *> JOBQ is CHARACTER*1
154 *> = 'Q': Q must contain an orthogonal matrix Q1 on entry, and
155 *> the product Q1*Q is returned;
156 *> = 'I': Q is initialized to the unit matrix, and the
157 *> orthogonal matrix Q is returned;
158 *> = 'N': Q is not computed.
159 *> \endverbatim
160 *>
161 *> \param[in] M
162 *> \verbatim
163 *> M is INTEGER
164 *> The number of rows of the matrix A. M >= 0.
165 *> \endverbatim
166 *>
167 *> \param[in] P
168 *> \verbatim
169 *> P is INTEGER
170 *> The number of rows of the matrix B. P >= 0.
171 *> \endverbatim
172 *>
173 *> \param[in] N
174 *> \verbatim
175 *> N is INTEGER
176 *> The number of columns of the matrices A and B. N >= 0.
177 *> \endverbatim
178 *>
179 *> \param[in] K
180 *> \verbatim
181 *> K is INTEGER
182 *> \endverbatim
183 *>
184 *> \param[in] L
185 *> \verbatim
186 *> L is INTEGER
187 *>
188 *> K and L specify the subblocks in the input matrices A and B:
189 *> A23 = A(K+1:MIN(K+L,M),N-L+1:N) and B13 = B(1:L,N-L+1:N)
190 *> of A and B, whose GSVD is going to be computed by STGSJA.
191 *> See Further Details.
192 *> \endverbatim
193 *>
194 *> \param[in,out] A
195 *> \verbatim
196 *> A is REAL array, dimension (LDA,N)
197 *> On entry, the M-by-N matrix A.
198 *> On exit, A(N-K+1:N,1:MIN(K+L,M) ) contains the triangular
199 *> matrix R or part of R. See Purpose for details.
200 *> \endverbatim
201 *>
202 *> \param[in] LDA
203 *> \verbatim
204 *> LDA is INTEGER
205 *> The leading dimension of the array A. LDA >= max(1,M).
206 *> \endverbatim
207 *>
208 *> \param[in,out] B
209 *> \verbatim
210 *> B is REAL array, dimension (LDB,N)
211 *> On entry, the P-by-N matrix B.
212 *> On exit, if necessary, B(M-K+1:L,N+M-K-L+1:N) contains
213 *> a part of R. See Purpose for details.
214 *> \endverbatim
215 *>
216 *> \param[in] LDB
217 *> \verbatim
218 *> LDB is INTEGER
219 *> The leading dimension of the array B. LDB >= max(1,P).
220 *> \endverbatim
221 *>
222 *> \param[in] TOLA
223 *> \verbatim
224 *> TOLA is REAL
225 *> \endverbatim
226 *>
227 *> \param[in] TOLB
228 *> \verbatim
229 *> TOLB is REAL
230 *>
231 *> TOLA and TOLB are the convergence criteria for the Jacobi-
232 *> Kogbetliantz iteration procedure. Generally, they are the
233 *> same as used in the preprocessing step, say
234 *> TOLA = max(M,N)*norm(A)*MACHEPS,
235 *> TOLB = max(P,N)*norm(B)*MACHEPS.
236 *> \endverbatim
237 *>
238 *> \param[out] ALPHA
239 *> \verbatim
240 *> ALPHA is REAL array, dimension (N)
241 *> \endverbatim
242 *>
243 *> \param[out] BETA
244 *> \verbatim
245 *> BETA is REAL array, dimension (N)
246 *>
247 *> On exit, ALPHA and BETA contain the generalized singular
248 *> value pairs of A and B;
249 *> ALPHA(1:K) = 1,
250 *> BETA(1:K) = 0,
251 *> and if M-K-L >= 0,
252 *> ALPHA(K+1:K+L) = diag(C),
253 *> BETA(K+1:K+L) = diag(S),
254 *> or if M-K-L < 0,
255 *> ALPHA(K+1:M)= C, ALPHA(M+1:K+L)= 0
256 *> BETA(K+1:M) = S, BETA(M+1:K+L) = 1.
257 *> Furthermore, if K+L < N,
258 *> ALPHA(K+L+1:N) = 0 and
259 *> BETA(K+L+1:N) = 0.
260 *> \endverbatim
261 *>
262 *> \param[in,out] U
263 *> \verbatim
264 *> U is REAL array, dimension (LDU,M)
265 *> On entry, if JOBU = 'U', U must contain a matrix U1 (usually
266 *> the orthogonal matrix returned by SGGSVP).
267 *> On exit,
268 *> if JOBU = 'I', U contains the orthogonal matrix U;
269 *> if JOBU = 'U', U contains the product U1*U.
270 *> If JOBU = 'N', U is not referenced.
271 *> \endverbatim
272 *>
273 *> \param[in] LDU
274 *> \verbatim
275 *> LDU is INTEGER
276 *> The leading dimension of the array U. LDU >= max(1,M) if
277 *> JOBU = 'U'; LDU >= 1 otherwise.
278 *> \endverbatim
279 *>
280 *> \param[in,out] V
281 *> \verbatim
282 *> V is REAL array, dimension (LDV,P)
283 *> On entry, if JOBV = 'V', V must contain a matrix V1 (usually
284 *> the orthogonal matrix returned by SGGSVP).
285 *> On exit,
286 *> if JOBV = 'I', V contains the orthogonal matrix V;
287 *> if JOBV = 'V', V contains the product V1*V.
288 *> If JOBV = 'N', V is not referenced.
289 *> \endverbatim
290 *>
291 *> \param[in] LDV
292 *> \verbatim
293 *> LDV is INTEGER
294 *> The leading dimension of the array V. LDV >= max(1,P) if
295 *> JOBV = 'V'; LDV >= 1 otherwise.
296 *> \endverbatim
297 *>
298 *> \param[in,out] Q
299 *> \verbatim
300 *> Q is REAL array, dimension (LDQ,N)
301 *> On entry, if JOBQ = 'Q', Q must contain a matrix Q1 (usually
302 *> the orthogonal matrix returned by SGGSVP).
303 *> On exit,
304 *> if JOBQ = 'I', Q contains the orthogonal matrix Q;
305 *> if JOBQ = 'Q', Q contains the product Q1*Q.
306 *> If JOBQ = 'N', Q is not referenced.
307 *> \endverbatim
308 *>
309 *> \param[in] LDQ
310 *> \verbatim
311 *> LDQ is INTEGER
312 *> The leading dimension of the array Q. LDQ >= max(1,N) if
313 *> JOBQ = 'Q'; LDQ >= 1 otherwise.
314 *> \endverbatim
315 *>
316 *> \param[out] WORK
317 *> \verbatim
318 *> WORK is REAL array, dimension (2*N)
319 *> \endverbatim
320 *>
321 *> \param[out] NCYCLE
322 *> \verbatim
323 *> NCYCLE is INTEGER
324 *> The number of cycles required for convergence.
325 *> \endverbatim
326 *>
327 *> \param[out] INFO
328 *> \verbatim
329 *> INFO is INTEGER
330 *> = 0: successful exit
331 *> < 0: if INFO = -i, the i-th argument had an illegal value.
332 *> = 1: the procedure does not converge after MAXIT cycles.
333 *> \endverbatim
334 *>
335 *> \verbatim
336 *> Internal Parameters
337 *> ===================
338 *>
339 *> MAXIT INTEGER
340 *> MAXIT specifies the total loops that the iterative procedure
341 *> may take. If after MAXIT cycles, the routine fails to
342 *> converge, we return INFO = 1.
343 *> \endverbatim
344 *
345 * Authors:
346 * ========
347 *
348 *> \author Univ. of Tennessee
349 *> \author Univ. of California Berkeley
350 *> \author Univ. of Colorado Denver
351 *> \author NAG Ltd.
352 *
353 *> \ingroup realOTHERcomputational
354 *
355 *> \par Further Details:
356 * =====================
357 *>
358 *> \verbatim
359 *>
360 *> STGSJA essentially uses a variant of Kogbetliantz algorithm to reduce
361 *> min(L,M-K)-by-L triangular (or trapezoidal) matrix A23 and L-by-L
362 *> matrix B13 to the form:
363 *>
364 *> U1**T *A13*Q1 = C1*R1; V1**T *B13*Q1 = S1*R1,
365 *>
366 *> where U1, V1 and Q1 are orthogonal matrix, and Z**T is the transpose
367 *> of Z. C1 and S1 are diagonal matrices satisfying
368 *>
369 *> C1**2 + S1**2 = I,
370 *>
371 *> and R1 is an L-by-L nonsingular upper triangular matrix.
372 *> \endverbatim
373 *>
374 * =====================================================================
375  SUBROUTINE stgsja( JOBU, JOBV, JOBQ, M, P, N, K, L, A, LDA, B,
376  $ LDB, TOLA, TOLB, ALPHA, BETA, U, LDU, V, LDV,
377  $ Q, LDQ, WORK, NCYCLE, INFO )
378 *
379 * -- LAPACK computational routine --
380 * -- LAPACK is a software package provided by Univ. of Tennessee, --
381 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
382 *
383 * .. Scalar Arguments ..
384  CHARACTER JOBQ, JOBU, JOBV
385  INTEGER INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N,
386  $ ncycle, p
387  REAL TOLA, TOLB
388 * ..
389 * .. Array Arguments ..
390  REAL A( LDA, * ), ALPHA( * ), B( LDB, * ),
391  $ BETA( * ), Q( LDQ, * ), U( LDU, * ),
392  $ v( ldv, * ), work( * )
393 * ..
394 *
395 * =====================================================================
396 *
397 * .. Parameters ..
398  INTEGER MAXIT
399  PARAMETER ( MAXIT = 40 )
400  REAL ZERO, ONE, HUGENUM
401  parameter( zero = 0.0e+0, one = 1.0e+0 )
402 * ..
403 * .. Local Scalars ..
404 *
405  LOGICAL INITQ, INITU, INITV, UPPER, WANTQ, WANTU, WANTV
406  INTEGER I, J, KCYCLE
407  REAL A1, A2, A3, B1, B2, B3, CSQ, CSU, CSV, ERROR,
408  $ gamma, rwk, snq, snu, snv, ssmin
409 * ..
410 * .. External Functions ..
411  LOGICAL LSAME
412  EXTERNAL LSAME
413 * ..
414 * .. External Subroutines ..
415  EXTERNAL scopy, slags2, slapll, slartg, slaset, srot,
416  $ sscal, xerbla
417 * ..
418 * .. Intrinsic Functions ..
419  INTRINSIC abs, max, min, huge
420  parameter( hugenum = huge(zero) )
421 * ..
422 * .. Executable Statements ..
423 *
424 * Decode and test the input parameters
425 *
426  initu = lsame( jobu, 'I' )
427  wantu = initu .OR. lsame( jobu, 'U' )
428 *
429  initv = lsame( jobv, 'I' )
430  wantv = initv .OR. lsame( jobv, 'V' )
431 *
432  initq = lsame( jobq, 'I' )
433  wantq = initq .OR. lsame( jobq, 'Q' )
434 *
435  info = 0
436  IF( .NOT.( initu .OR. wantu .OR. lsame( jobu, 'N' ) ) ) THEN
437  info = -1
438  ELSE IF( .NOT.( initv .OR. wantv .OR. lsame( jobv, 'N' ) ) ) THEN
439  info = -2
440  ELSE IF( .NOT.( initq .OR. wantq .OR. lsame( jobq, 'N' ) ) ) THEN
441  info = -3
442  ELSE IF( m.LT.0 ) THEN
443  info = -4
444  ELSE IF( p.LT.0 ) THEN
445  info = -5
446  ELSE IF( n.LT.0 ) THEN
447  info = -6
448  ELSE IF( lda.LT.max( 1, m ) ) THEN
449  info = -10
450  ELSE IF( ldb.LT.max( 1, p ) ) THEN
451  info = -12
452  ELSE IF( ldu.LT.1 .OR. ( wantu .AND. ldu.LT.m ) ) THEN
453  info = -18
454  ELSE IF( ldv.LT.1 .OR. ( wantv .AND. ldv.LT.p ) ) THEN
455  info = -20
456  ELSE IF( ldq.LT.1 .OR. ( wantq .AND. ldq.LT.n ) ) THEN
457  info = -22
458  END IF
459  IF( info.NE.0 ) THEN
460  CALL xerbla( 'STGSJA', -info )
461  RETURN
462  END IF
463 *
464 * Initialize U, V and Q, if necessary
465 *
466  IF( initu )
467  $ CALL slaset( 'Full', m, m, zero, one, u, ldu )
468  IF( initv )
469  $ CALL slaset( 'Full', p, p, zero, one, v, ldv )
470  IF( initq )
471  $ CALL slaset( 'Full', n, n, zero, one, q, ldq )
472 *
473 * Loop until convergence
474 *
475  upper = .false.
476  DO 40 kcycle = 1, maxit
477 *
478  upper = .NOT.upper
479 *
480  DO 20 i = 1, l - 1
481  DO 10 j = i + 1, l
482 *
483  a1 = zero
484  a2 = zero
485  a3 = zero
486  IF( k+i.LE.m )
487  $ a1 = a( k+i, n-l+i )
488  IF( k+j.LE.m )
489  $ a3 = a( k+j, n-l+j )
490 *
491  b1 = b( i, n-l+i )
492  b3 = b( j, n-l+j )
493 *
494  IF( upper ) THEN
495  IF( k+i.LE.m )
496  $ a2 = a( k+i, n-l+j )
497  b2 = b( i, n-l+j )
498  ELSE
499  IF( k+j.LE.m )
500  $ a2 = a( k+j, n-l+i )
501  b2 = b( j, n-l+i )
502  END IF
503 *
504  CALL slags2( upper, a1, a2, a3, b1, b2, b3, csu, snu,
505  $ csv, snv, csq, snq )
506 *
507 * Update (K+I)-th and (K+J)-th rows of matrix A: U**T *A
508 *
509  IF( k+j.LE.m )
510  $ CALL srot( l, a( k+j, n-l+1 ), lda, a( k+i, n-l+1 ),
511  $ lda, csu, snu )
512 *
513 * Update I-th and J-th rows of matrix B: V**T *B
514 *
515  CALL srot( l, b( j, n-l+1 ), ldb, b( i, n-l+1 ), ldb,
516  $ csv, snv )
517 *
518 * Update (N-L+I)-th and (N-L+J)-th columns of matrices
519 * A and B: A*Q and B*Q
520 *
521  CALL srot( min( k+l, m ), a( 1, n-l+j ), 1,
522  $ a( 1, n-l+i ), 1, csq, snq )
523 *
524  CALL srot( l, b( 1, n-l+j ), 1, b( 1, n-l+i ), 1, csq,
525  $ snq )
526 *
527  IF( upper ) THEN
528  IF( k+i.LE.m )
529  $ a( k+i, n-l+j ) = zero
530  b( i, n-l+j ) = zero
531  ELSE
532  IF( k+j.LE.m )
533  $ a( k+j, n-l+i ) = zero
534  b( j, n-l+i ) = zero
535  END IF
536 *
537 * Update orthogonal matrices U, V, Q, if desired.
538 *
539  IF( wantu .AND. k+j.LE.m )
540  $ CALL srot( m, u( 1, k+j ), 1, u( 1, k+i ), 1, csu,
541  $ snu )
542 *
543  IF( wantv )
544  $ CALL srot( p, v( 1, j ), 1, v( 1, i ), 1, csv, snv )
545 *
546  IF( wantq )
547  $ CALL srot( n, q( 1, n-l+j ), 1, q( 1, n-l+i ), 1, csq,
548  $ snq )
549 *
550  10 CONTINUE
551  20 CONTINUE
552 *
553  IF( .NOT.upper ) THEN
554 *
555 * The matrices A13 and B13 were lower triangular at the start
556 * of the cycle, and are now upper triangular.
557 *
558 * Convergence test: test the parallelism of the corresponding
559 * rows of A and B.
560 *
561  error = zero
562  DO 30 i = 1, min( l, m-k )
563  CALL scopy( l-i+1, a( k+i, n-l+i ), lda, work, 1 )
564  CALL scopy( l-i+1, b( i, n-l+i ), ldb, work( l+1 ), 1 )
565  CALL slapll( l-i+1, work, 1, work( l+1 ), 1, ssmin )
566  error = max( error, ssmin )
567  30 CONTINUE
568 *
569  IF( abs( error ).LE.min( tola, tolb ) )
570  $ GO TO 50
571  END IF
572 *
573 * End of cycle loop
574 *
575  40 CONTINUE
576 *
577 * The algorithm has not converged after MAXIT cycles.
578 *
579  info = 1
580  GO TO 100
581 *
582  50 CONTINUE
583 *
584 * If ERROR <= MIN(TOLA,TOLB), then the algorithm has converged.
585 * Compute the generalized singular value pairs (ALPHA, BETA), and
586 * set the triangular matrix R to array A.
587 *
588  DO 60 i = 1, k
589  alpha( i ) = one
590  beta( i ) = zero
591  60 CONTINUE
592 *
593  DO 70 i = 1, min( l, m-k )
594 *
595  a1 = a( k+i, n-l+i )
596  b1 = b( i, n-l+i )
597  gamma = b1 / a1
598 *
599  IF( (gamma.LE.hugenum).AND.(gamma.GE.-hugenum) ) THEN
600 *
601 * change sign if necessary
602 *
603  IF( gamma.LT.zero ) THEN
604  CALL sscal( l-i+1, -one, b( i, n-l+i ), ldb )
605  IF( wantv )
606  $ CALL sscal( p, -one, v( 1, i ), 1 )
607  END IF
608 *
609  CALL slartg( abs( gamma ), one, beta( k+i ), alpha( k+i ),
610  $ rwk )
611 *
612  IF( alpha( k+i ).GE.beta( k+i ) ) THEN
613  CALL sscal( l-i+1, one / alpha( k+i ), a( k+i, n-l+i ),
614  $ lda )
615  ELSE
616  CALL sscal( l-i+1, one / beta( k+i ), b( i, n-l+i ),
617  $ ldb )
618  CALL scopy( l-i+1, b( i, n-l+i ), ldb, a( k+i, n-l+i ),
619  $ lda )
620  END IF
621 *
622  ELSE
623 *
624  alpha( k+i ) = zero
625  beta( k+i ) = one
626  CALL scopy( l-i+1, b( i, n-l+i ), ldb, a( k+i, n-l+i ),
627  $ lda )
628 *
629  END IF
630 *
631  70 CONTINUE
632 *
633 * Post-assignment
634 *
635  DO 80 i = m + 1, k + l
636  alpha( i ) = zero
637  beta( i ) = one
638  80 CONTINUE
639 *
640  IF( k+l.LT.n ) THEN
641  DO 90 i = k + l + 1, n
642  alpha( i ) = zero
643  beta( i ) = zero
644  90 CONTINUE
645  END IF
646 *
647  100 CONTINUE
648  ncycle = kcycle
649  RETURN
650 *
651 * End of STGSJA
652 *
653  END
subroutine slaset(UPLO, M, N, ALPHA, BETA, A, LDA)
SLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition: slaset.f:110
subroutine slartg(f, g, c, s, r)
SLARTG generates a plane rotation with real cosine and real sine.
Definition: slartg.f90:113
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine slags2(UPPER, A1, A2, A3, B1, B2, B3, CSU, SNU, CSV, SNV, CSQ, SNQ)
SLAGS2 computes 2-by-2 orthogonal matrices U, V, and Q, and applies them to matrices A and B such tha...
Definition: slags2.f:152
subroutine slapll(N, X, INCX, Y, INCY, SSMIN)
SLAPLL measures the linear dependence of two vectors.
Definition: slapll.f:102
subroutine stgsja(JOBU, JOBV, JOBQ, M, P, N, K, L, A, LDA, B, LDB, TOLA, TOLB, ALPHA, BETA, U, LDU, V, LDV, Q, LDQ, WORK, NCYCLE, INFO)
STGSJA
Definition: stgsja.f:378
subroutine srot(N, SX, INCX, SY, INCY, C, S)
SROT
Definition: srot.f:92
subroutine scopy(N, SX, INCX, SY, INCY)
SCOPY
Definition: scopy.f:82
subroutine sscal(N, SA, SX, INCX)
SSCAL
Definition: sscal.f:79