LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
zhpevd.f
Go to the documentation of this file.
1*> \brief <b> ZHPEVD computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices</b>
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download ZHPEVD + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zhpevd.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zhpevd.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zhpevd.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE ZHPEVD( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, LWORK,
22* RWORK, LRWORK, IWORK, LIWORK, INFO )
23*
24* .. Scalar Arguments ..
25* CHARACTER JOBZ, UPLO
26* INTEGER INFO, LDZ, LIWORK, LRWORK, LWORK, N
27* ..
28* .. Array Arguments ..
29* INTEGER IWORK( * )
30* DOUBLE PRECISION RWORK( * ), W( * )
31* COMPLEX*16 AP( * ), WORK( * ), Z( LDZ, * )
32* ..
33*
34*
35*> \par Purpose:
36* =============
37*>
38*> \verbatim
39*>
40*> ZHPEVD computes all the eigenvalues and, optionally, eigenvectors of
41*> a complex Hermitian matrix A in packed storage. If eigenvectors are
42*> desired, it uses a divide and conquer algorithm.
43*>
44*> \endverbatim
45*
46* Arguments:
47* ==========
48*
49*> \param[in] JOBZ
50*> \verbatim
51*> JOBZ is CHARACTER*1
52*> = 'N': Compute eigenvalues only;
53*> = 'V': Compute eigenvalues and eigenvectors.
54*> \endverbatim
55*>
56*> \param[in] UPLO
57*> \verbatim
58*> UPLO is CHARACTER*1
59*> = 'U': Upper triangle of A is stored;
60*> = 'L': Lower triangle of A is stored.
61*> \endverbatim
62*>
63*> \param[in] N
64*> \verbatim
65*> N is INTEGER
66*> The order of the matrix A. N >= 0.
67*> \endverbatim
68*>
69*> \param[in,out] AP
70*> \verbatim
71*> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
72*> On entry, the upper or lower triangle of the Hermitian matrix
73*> A, packed columnwise in a linear array. The j-th column of A
74*> is stored in the array AP as follows:
75*> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
76*> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
77*>
78*> On exit, AP is overwritten by values generated during the
79*> reduction to tridiagonal form. If UPLO = 'U', the diagonal
80*> and first superdiagonal of the tridiagonal matrix T overwrite
81*> the corresponding elements of A, and if UPLO = 'L', the
82*> diagonal and first subdiagonal of T overwrite the
83*> corresponding elements of A.
84*> \endverbatim
85*>
86*> \param[out] W
87*> \verbatim
88*> W is DOUBLE PRECISION array, dimension (N)
89*> If INFO = 0, the eigenvalues in ascending order.
90*> \endverbatim
91*>
92*> \param[out] Z
93*> \verbatim
94*> Z is COMPLEX*16 array, dimension (LDZ, N)
95*> If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal
96*> eigenvectors of the matrix A, with the i-th column of Z
97*> holding the eigenvector associated with W(i).
98*> If JOBZ = 'N', then Z is not referenced.
99*> \endverbatim
100*>
101*> \param[in] LDZ
102*> \verbatim
103*> LDZ is INTEGER
104*> The leading dimension of the array Z. LDZ >= 1, and if
105*> JOBZ = 'V', LDZ >= max(1,N).
106*> \endverbatim
107*>
108*> \param[out] WORK
109*> \verbatim
110*> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
111*> On exit, if INFO = 0, WORK(1) returns the required LWORK.
112*> \endverbatim
113*>
114*> \param[in] LWORK
115*> \verbatim
116*> LWORK is INTEGER
117*> The dimension of array WORK.
118*> If N <= 1, LWORK must be at least 1.
119*> If JOBZ = 'N' and N > 1, LWORK must be at least N.
120*> If JOBZ = 'V' and N > 1, LWORK must be at least 2*N.
121*>
122*> If LWORK = -1, then a workspace query is assumed; the routine
123*> only calculates the required sizes of the WORK, RWORK and
124*> IWORK arrays, returns these values as the first entries of
125*> the WORK, RWORK and IWORK arrays, and no error message
126*> related to LWORK or LRWORK or LIWORK is issued by XERBLA.
127*> \endverbatim
128*>
129*> \param[out] RWORK
130*> \verbatim
131*> RWORK is DOUBLE PRECISION array, dimension (MAX(1,LRWORK))
132*> On exit, if INFO = 0, RWORK(1) returns the required LRWORK.
133*> \endverbatim
134*>
135*> \param[in] LRWORK
136*> \verbatim
137*> LRWORK is INTEGER
138*> The dimension of array RWORK.
139*> If N <= 1, LRWORK must be at least 1.
140*> If JOBZ = 'N' and N > 1, LRWORK must be at least N.
141*> If JOBZ = 'V' and N > 1, LRWORK must be at least
142*> 1 + 5*N + 2*N**2.
143*>
144*> If LRWORK = -1, then a workspace query is assumed; the
145*> routine only calculates the required sizes of the WORK, RWORK
146*> and IWORK arrays, returns these values as the first entries
147*> of the WORK, RWORK and IWORK arrays, and no error message
148*> related to LWORK or LRWORK or LIWORK is issued by XERBLA.
149*> \endverbatim
150*>
151*> \param[out] IWORK
152*> \verbatim
153*> IWORK is INTEGER array, dimension (MAX(1,LIWORK))
154*> On exit, if INFO = 0, IWORK(1) returns the required LIWORK.
155*> \endverbatim
156*>
157*> \param[in] LIWORK
158*> \verbatim
159*> LIWORK is INTEGER
160*> The dimension of array IWORK.
161*> If JOBZ = 'N' or N <= 1, LIWORK must be at least 1.
162*> If JOBZ = 'V' and N > 1, LIWORK must be at least 3 + 5*N.
163*>
164*> If LIWORK = -1, then a workspace query is assumed; the
165*> routine only calculates the required sizes of the WORK, RWORK
166*> and IWORK arrays, returns these values as the first entries
167*> of the WORK, RWORK and IWORK arrays, and no error message
168*> related to LWORK or LRWORK or LIWORK is issued by XERBLA.
169*> \endverbatim
170*>
171*> \param[out] INFO
172*> \verbatim
173*> INFO is INTEGER
174*> = 0: successful exit
175*> < 0: if INFO = -i, the i-th argument had an illegal value.
176*> > 0: if INFO = i, the algorithm failed to converge; i
177*> off-diagonal elements of an intermediate tridiagonal
178*> form did not converge to zero.
179*> \endverbatim
180*
181* Authors:
182* ========
183*
184*> \author Univ. of Tennessee
185*> \author Univ. of California Berkeley
186*> \author Univ. of Colorado Denver
187*> \author NAG Ltd.
188*
189*> \ingroup hpevd
190*
191* =====================================================================
192 SUBROUTINE zhpevd( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, LWORK,
193 $ RWORK, LRWORK, IWORK, LIWORK, INFO )
194*
195* -- LAPACK driver routine --
196* -- LAPACK is a software package provided by Univ. of Tennessee, --
197* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
198*
199* .. Scalar Arguments ..
200 CHARACTER JOBZ, UPLO
201 INTEGER INFO, LDZ, LIWORK, LRWORK, LWORK, N
202* ..
203* .. Array Arguments ..
204 INTEGER IWORK( * )
205 DOUBLE PRECISION RWORK( * ), W( * )
206 COMPLEX*16 AP( * ), WORK( * ), Z( LDZ, * )
207* ..
208*
209* =====================================================================
210*
211* .. Parameters ..
212 DOUBLE PRECISION ZERO, ONE
213 parameter( zero = 0.0d+0, one = 1.0d+0 )
214 COMPLEX*16 CONE
215 parameter( cone = ( 1.0d+0, 0.0d+0 ) )
216* ..
217* .. Local Scalars ..
218 LOGICAL LQUERY, WANTZ
219 INTEGER IINFO, IMAX, INDE, INDRWK, INDTAU, INDWRK,
220 $ iscale, liwmin, llrwk, llwrk, lrwmin, lwmin
221 DOUBLE PRECISION ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
222 $ smlnum
223* ..
224* .. External Functions ..
225 LOGICAL LSAME
226 DOUBLE PRECISION DLAMCH, ZLANHP
227 EXTERNAL lsame, dlamch, zlanhp
228* ..
229* .. External Subroutines ..
230 EXTERNAL dscal, dsterf, xerbla, zdscal, zhptrd, zstedc,
231 $ zupmtr
232* ..
233* .. Intrinsic Functions ..
234 INTRINSIC sqrt
235* ..
236* .. Executable Statements ..
237*
238* Test the input parameters.
239*
240 wantz = lsame( jobz, 'V' )
241 lquery = ( lwork.EQ.-1 .OR. lrwork.EQ.-1 .OR. liwork.EQ.-1 )
242*
243 info = 0
244 IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
245 info = -1
246 ELSE IF( .NOT.( lsame( uplo, 'L' ) .OR. lsame( uplo, 'U' ) ) )
247 $ THEN
248 info = -2
249 ELSE IF( n.LT.0 ) THEN
250 info = -3
251 ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
252 info = -7
253 END IF
254*
255 IF( info.EQ.0 ) THEN
256 IF( n.LE.1 ) THEN
257 lwmin = 1
258 liwmin = 1
259 lrwmin = 1
260 ELSE
261 IF( wantz ) THEN
262 lwmin = 2*n
263 lrwmin = 1 + 5*n + 2*n**2
264 liwmin = 3 + 5*n
265 ELSE
266 lwmin = n
267 lrwmin = n
268 liwmin = 1
269 END IF
270 END IF
271 work( 1 ) = lwmin
272 rwork( 1 ) = lrwmin
273 iwork( 1 ) = liwmin
274*
275 IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
276 info = -9
277 ELSE IF( lrwork.LT.lrwmin .AND. .NOT.lquery ) THEN
278 info = -11
279 ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
280 info = -13
281 END IF
282 END IF
283*
284 IF( info.NE.0 ) THEN
285 CALL xerbla( 'ZHPEVD', -info )
286 RETURN
287 ELSE IF( lquery ) THEN
288 RETURN
289 END IF
290*
291* Quick return if possible
292*
293 IF( n.EQ.0 )
294 $ RETURN
295*
296 IF( n.EQ.1 ) THEN
297 w( 1 ) = dble( ap( 1 ) )
298 IF( wantz )
299 $ z( 1, 1 ) = cone
300 RETURN
301 END IF
302*
303* Get machine constants.
304*
305 safmin = dlamch( 'Safe minimum' )
306 eps = dlamch( 'Precision' )
307 smlnum = safmin / eps
308 bignum = one / smlnum
309 rmin = sqrt( smlnum )
310 rmax = sqrt( bignum )
311*
312* Scale matrix to allowable range, if necessary.
313*
314 anrm = zlanhp( 'M', uplo, n, ap, rwork )
315 iscale = 0
316 IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
317 iscale = 1
318 sigma = rmin / anrm
319 ELSE IF( anrm.GT.rmax ) THEN
320 iscale = 1
321 sigma = rmax / anrm
322 END IF
323 IF( iscale.EQ.1 ) THEN
324 CALL zdscal( ( n*( n+1 ) ) / 2, sigma, ap, 1 )
325 END IF
326*
327* Call ZHPTRD to reduce Hermitian packed matrix to tridiagonal form.
328*
329 inde = 1
330 indtau = 1
331 indrwk = inde + n
332 indwrk = indtau + n
333 llwrk = lwork - indwrk + 1
334 llrwk = lrwork - indrwk + 1
335 CALL zhptrd( uplo, n, ap, w, rwork( inde ), work( indtau ),
336 $ iinfo )
337*
338* For eigenvalues only, call DSTERF. For eigenvectors, first call
339* ZUPGTR to generate the orthogonal matrix, then call ZSTEDC.
340*
341 IF( .NOT.wantz ) THEN
342 CALL dsterf( n, w, rwork( inde ), info )
343 ELSE
344 CALL zstedc( 'I', n, w, rwork( inde ), z, ldz, work( indwrk ),
345 $ llwrk, rwork( indrwk ), llrwk, iwork, liwork,
346 $ info )
347 CALL zupmtr( 'L', uplo, 'N', n, n, ap, work( indtau ), z, ldz,
348 $ work( indwrk ), iinfo )
349 END IF
350*
351* If matrix was scaled, then rescale eigenvalues appropriately.
352*
353 IF( iscale.EQ.1 ) THEN
354 IF( info.EQ.0 ) THEN
355 imax = n
356 ELSE
357 imax = info - 1
358 END IF
359 CALL dscal( imax, one / sigma, w, 1 )
360 END IF
361*
362 work( 1 ) = lwmin
363 rwork( 1 ) = lrwmin
364 iwork( 1 ) = liwmin
365 RETURN
366*
367* End of ZHPEVD
368*
369 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine zhpevd(jobz, uplo, n, ap, w, z, ldz, work, lwork, rwork, lrwork, iwork, liwork, info)
ZHPEVD computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrice...
Definition zhpevd.f:194
subroutine zhptrd(uplo, n, ap, d, e, tau, info)
ZHPTRD
Definition zhptrd.f:151
subroutine dscal(n, da, dx, incx)
DSCAL
Definition dscal.f:79
subroutine zdscal(n, da, zx, incx)
ZDSCAL
Definition zdscal.f:78
subroutine zstedc(compz, n, d, e, z, ldz, work, lwork, rwork, lrwork, iwork, liwork, info)
ZSTEDC
Definition zstedc.f:206
subroutine dsterf(n, d, e, info)
DSTERF
Definition dsterf.f:86
subroutine zupmtr(side, uplo, trans, m, n, ap, tau, c, ldc, work, info)
ZUPMTR
Definition zupmtr.f:150