LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
zunmrq.f
Go to the documentation of this file.
1 *> \brief \b ZUNMRQ
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZUNMRQ + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zunmrq.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zunmrq.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zunmrq.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZUNMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22 * WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER SIDE, TRANS
26 * INTEGER INFO, K, LDA, LDC, LWORK, M, N
27 * ..
28 * .. Array Arguments ..
29 * COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> ZUNMRQ overwrites the general complex M-by-N matrix C with
39 *>
40 *> SIDE = 'L' SIDE = 'R'
41 *> TRANS = 'N': Q * C C * Q
42 *> TRANS = 'C': Q**H * C C * Q**H
43 *>
44 *> where Q is a complex unitary matrix defined as the product of k
45 *> elementary reflectors
46 *>
47 *> Q = H(1)**H H(2)**H . . . H(k)**H
48 *>
49 *> as returned by ZGERQF. Q is of order M if SIDE = 'L' and of order N
50 *> if SIDE = 'R'.
51 *> \endverbatim
52 *
53 * Arguments:
54 * ==========
55 *
56 *> \param[in] SIDE
57 *> \verbatim
58 *> SIDE is CHARACTER*1
59 *> = 'L': apply Q or Q**H from the Left;
60 *> = 'R': apply Q or Q**H from the Right.
61 *> \endverbatim
62 *>
63 *> \param[in] TRANS
64 *> \verbatim
65 *> TRANS is CHARACTER*1
66 *> = 'N': No transpose, apply Q;
67 *> = 'C': Conjugate transpose, apply Q**H.
68 *> \endverbatim
69 *>
70 *> \param[in] M
71 *> \verbatim
72 *> M is INTEGER
73 *> The number of rows of the matrix C. M >= 0.
74 *> \endverbatim
75 *>
76 *> \param[in] N
77 *> \verbatim
78 *> N is INTEGER
79 *> The number of columns of the matrix C. N >= 0.
80 *> \endverbatim
81 *>
82 *> \param[in] K
83 *> \verbatim
84 *> K is INTEGER
85 *> The number of elementary reflectors whose product defines
86 *> the matrix Q.
87 *> If SIDE = 'L', M >= K >= 0;
88 *> if SIDE = 'R', N >= K >= 0.
89 *> \endverbatim
90 *>
91 *> \param[in] A
92 *> \verbatim
93 *> A is COMPLEX*16 array, dimension
94 *> (LDA,M) if SIDE = 'L',
95 *> (LDA,N) if SIDE = 'R'
96 *> The i-th row must contain the vector which defines the
97 *> elementary reflector H(i), for i = 1,2,...,k, as returned by
98 *> ZGERQF in the last k rows of its array argument A.
99 *> \endverbatim
100 *>
101 *> \param[in] LDA
102 *> \verbatim
103 *> LDA is INTEGER
104 *> The leading dimension of the array A. LDA >= max(1,K).
105 *> \endverbatim
106 *>
107 *> \param[in] TAU
108 *> \verbatim
109 *> TAU is COMPLEX*16 array, dimension (K)
110 *> TAU(i) must contain the scalar factor of the elementary
111 *> reflector H(i), as returned by ZGERQF.
112 *> \endverbatim
113 *>
114 *> \param[in,out] C
115 *> \verbatim
116 *> C is COMPLEX*16 array, dimension (LDC,N)
117 *> On entry, the M-by-N matrix C.
118 *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
119 *> \endverbatim
120 *>
121 *> \param[in] LDC
122 *> \verbatim
123 *> LDC is INTEGER
124 *> The leading dimension of the array C. LDC >= max(1,M).
125 *> \endverbatim
126 *>
127 *> \param[out] WORK
128 *> \verbatim
129 *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
130 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
131 *> \endverbatim
132 *>
133 *> \param[in] LWORK
134 *> \verbatim
135 *> LWORK is INTEGER
136 *> The dimension of the array WORK.
137 *> If SIDE = 'L', LWORK >= max(1,N);
138 *> if SIDE = 'R', LWORK >= max(1,M).
139 *> For good performance, LWORK should generally be larger.
140 *>
141 *> If LWORK = -1, then a workspace query is assumed; the routine
142 *> only calculates the optimal size of the WORK array, returns
143 *> this value as the first entry of the WORK array, and no error
144 *> message related to LWORK is issued by XERBLA.
145 *> \endverbatim
146 *>
147 *> \param[out] INFO
148 *> \verbatim
149 *> INFO is INTEGER
150 *> = 0: successful exit
151 *> < 0: if INFO = -i, the i-th argument had an illegal value
152 *> \endverbatim
153 *
154 * Authors:
155 * ========
156 *
157 *> \author Univ. of Tennessee
158 *> \author Univ. of California Berkeley
159 *> \author Univ. of Colorado Denver
160 *> \author NAG Ltd.
161 *
162 *> \ingroup complex16OTHERcomputational
163 *
164 * =====================================================================
165  SUBROUTINE zunmrq( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
166  $ WORK, LWORK, INFO )
167 *
168 * -- LAPACK computational routine --
169 * -- LAPACK is a software package provided by Univ. of Tennessee, --
170 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
171 *
172 * .. Scalar Arguments ..
173  CHARACTER SIDE, TRANS
174  INTEGER INFO, K, LDA, LDC, LWORK, M, N
175 * ..
176 * .. Array Arguments ..
177  COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
178 * ..
179 *
180 * =====================================================================
181 *
182 * .. Parameters ..
183  INTEGER NBMAX, LDT, TSIZE
184  parameter( nbmax = 64, ldt = nbmax+1,
185  $ tsize = ldt*nbmax )
186 * ..
187 * .. Local Scalars ..
188  LOGICAL LEFT, LQUERY, NOTRAN
189  CHARACTER TRANST
190  INTEGER I, I1, I2, I3, IB, IINFO, IWT, LDWORK, LWKOPT,
191  $ mi, nb, nbmin, ni, nq, nw
192 * ..
193 * .. External Functions ..
194  LOGICAL LSAME
195  INTEGER ILAENV
196  EXTERNAL lsame, ilaenv
197 * ..
198 * .. External Subroutines ..
199  EXTERNAL xerbla, zlarfb, zlarft, zunmr2
200 * ..
201 * .. Intrinsic Functions ..
202  INTRINSIC max, min
203 * ..
204 * .. Executable Statements ..
205 *
206 * Test the input arguments
207 *
208  info = 0
209  left = lsame( side, 'L' )
210  notran = lsame( trans, 'N' )
211  lquery = ( lwork.EQ.-1 )
212 *
213 * NQ is the order of Q and NW is the minimum dimension of WORK
214 *
215  IF( left ) THEN
216  nq = m
217  nw = max( 1, n )
218  ELSE
219  nq = n
220  nw = max( 1, m )
221  END IF
222  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
223  info = -1
224  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
225  info = -2
226  ELSE IF( m.LT.0 ) THEN
227  info = -3
228  ELSE IF( n.LT.0 ) THEN
229  info = -4
230  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
231  info = -5
232  ELSE IF( lda.LT.max( 1, k ) ) THEN
233  info = -7
234  ELSE IF( ldc.LT.max( 1, m ) ) THEN
235  info = -10
236  ELSE IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
237  info = -12
238  END IF
239 *
240  IF( info.EQ.0 ) THEN
241 *
242 * Compute the workspace requirements
243 *
244  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
245  lwkopt = 1
246  ELSE
247  nb = min( nbmax, ilaenv( 1, 'ZUNMRQ', side // trans, m, n,
248  $ k, -1 ) )
249  lwkopt = nw*nb + tsize
250  END IF
251  work( 1 ) = lwkopt
252  END IF
253 *
254  IF( info.NE.0 ) THEN
255  CALL xerbla( 'ZUNMRQ', -info )
256  RETURN
257  ELSE IF( lquery ) THEN
258  RETURN
259  END IF
260 *
261 * Quick return if possible
262 *
263  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
264  RETURN
265  END IF
266 *
267  nbmin = 2
268  ldwork = nw
269  IF( nb.GT.1 .AND. nb.LT.k ) THEN
270  IF( lwork.LT.lwkopt ) THEN
271  nb = (lwork-tsize) / ldwork
272  nbmin = max( 2, ilaenv( 2, 'ZUNMRQ', side // trans, m, n, k,
273  $ -1 ) )
274  END IF
275  END IF
276 *
277  IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
278 *
279 * Use unblocked code
280 *
281  CALL zunmr2( side, trans, m, n, k, a, lda, tau, c, ldc, work,
282  $ iinfo )
283  ELSE
284 *
285 * Use blocked code
286 *
287  iwt = 1 + nw*nb
288  IF( ( left .AND. .NOT.notran ) .OR.
289  $ ( .NOT.left .AND. notran ) ) THEN
290  i1 = 1
291  i2 = k
292  i3 = nb
293  ELSE
294  i1 = ( ( k-1 ) / nb )*nb + 1
295  i2 = 1
296  i3 = -nb
297  END IF
298 *
299  IF( left ) THEN
300  ni = n
301  ELSE
302  mi = m
303  END IF
304 *
305  IF( notran ) THEN
306  transt = 'C'
307  ELSE
308  transt = 'N'
309  END IF
310 *
311  DO 10 i = i1, i2, i3
312  ib = min( nb, k-i+1 )
313 *
314 * Form the triangular factor of the block reflector
315 * H = H(i+ib-1) . . . H(i+1) H(i)
316 *
317  CALL zlarft( 'Backward', 'Rowwise', nq-k+i+ib-1, ib,
318  $ a( i, 1 ), lda, tau( i ), work( iwt ), ldt )
319  IF( left ) THEN
320 *
321 * H or H**H is applied to C(1:m-k+i+ib-1,1:n)
322 *
323  mi = m - k + i + ib - 1
324  ELSE
325 *
326 * H or H**H is applied to C(1:m,1:n-k+i+ib-1)
327 *
328  ni = n - k + i + ib - 1
329  END IF
330 *
331 * Apply H or H**H
332 *
333  CALL zlarfb( side, transt, 'Backward', 'Rowwise', mi, ni,
334  $ ib, a( i, 1 ), lda, work( iwt ), ldt, c, ldc,
335  $ work, ldwork )
336  10 CONTINUE
337  END IF
338  work( 1 ) = lwkopt
339  RETURN
340 *
341 * End of ZUNMRQ
342 *
343  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine zlarfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV, T, LDT, C, LDC, WORK, LDWORK)
ZLARFB applies a block reflector or its conjugate-transpose to a general rectangular matrix.
Definition: zlarfb.f:197
subroutine zlarft(DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT)
ZLARFT forms the triangular factor T of a block reflector H = I - vtvH
Definition: zlarft.f:163
subroutine zunmr2(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, INFO)
ZUNMR2 multiplies a general matrix by the unitary matrix from a RQ factorization determined by cgerqf...
Definition: zunmr2.f:159
subroutine zunmrq(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
ZUNMRQ
Definition: zunmrq.f:167