sdrvpp.f

Go to the documentation of this file.

*> \brief \b SDRVPP
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SDRVPP( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR, NMAX,
*                          A, AFAC, ASAV, B, BSAV, X, XACT, S, WORK,
*                          RWORK, IWORK, NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NMAX, NN, NOUT, NRHS
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), NVAL( * )
*       REAL               A( * ), AFAC( * ), ASAV( * ), B( * ),
*      $                   BSAV( * ), RWORK( * ), S( * ), WORK( * ),
*      $                   X( * ), XACT( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SDRVPP tests the driver routines SPPSV and -SVX.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand side vectors to be generated for
*>          each linear system.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The maximum value permitted for N, used in dimensioning the
*>          work arrays.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is REAL array, dimension
*>                      (NMAX*(NMAX+1)/2)
*> \endverbatim
*>
*> \param[out] AFAC
*> \verbatim
*>          AFAC is REAL array, dimension
*>                      (NMAX*(NMAX+1)/2)
*> \endverbatim
*>
*> \param[out] ASAV
*> \verbatim
*>          ASAV is REAL array, dimension
*>                      (NMAX*(NMAX+1)/2)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] BSAV
*> \verbatim
*>          BSAV is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is REAL array, dimension (NMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension
*>                      (NMAX*max(3,NRHS))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (NMAX+2*NRHS)
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE sdrvpp( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR, NMAX,
     $                   A, AFAC, ASAV, B, BSAV, X, XACT, S, WORK,
     $                   RWORK, IWORK, NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NOUT, NRHS
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NVAL( * )
      REAL               A( * ), AFAC( * ), ASAV( * ), B( * ),
     $                   bsav( * ), rwork( * ), s( * ), work( * ),
     $                   x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      PARAMETER          ( ONE = 1.0e+0, zero = 0.0e+0 )
      INTEGER            NTYPES
      parameter( ntypes = 9 )
      INTEGER            NTESTS
      parameter( ntests = 6 )
*     ..
*     .. Local Scalars ..
      LOGICAL            EQUIL, NOFACT, PREFAC, ZEROT
      CHARACTER          DIST, EQUED, FACT, PACKIT, TYPE, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IEQUED, IFACT, IMAT, IN, INFO, IOFF, IUPLO,
     $                   izero, k, k1, kl, ku, lda, mode, n, nerrs,
     $                   nfact, nfail, nimat, npp, nrun, nt
      REAL               AINVNM, AMAX, ANORM, CNDNUM, RCOND, RCONDC,
     $                   ROLDC, SCOND
*     ..
*     .. Local Arrays ..
      CHARACTER          EQUEDS( 2 ), FACTS( 3 ), PACKS( 2 ), UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( NTESTS )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SGET06, SLANSP
      EXTERNAL           lsame, sget06, slansp
*     ..
*     .. External Subroutines ..
      EXTERNAL           aladhd, alaerh, alasvm, scopy, serrvx, sget04,
     $                   slacpy, slaqsp, slarhs, slaset, slatb4, slatms,
     $                   sppequ, sppsv, sppsvx, sppt01, sppt02, sppt05,
     $                   spptrf, spptri
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' / , facts / 'F', 'N', 'E' / ,
     $                   packs / 'C', 'R' / , equeds / 'N', 'Y' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'PP'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL serrvx( path, nout )
      infot = 0
*
*     Do for each value of N in NVAL
*
      DO 140 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         npp = n*( n+1 ) / 2
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 130 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 130
*
*           Skip types 3, 4, or 5 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.5
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 130
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 120 iuplo = 1, 2
               uplo = uplos( iuplo )
               packit = packs( iuplo )
*
*              Set up parameters with SLATB4 and generate a test matrix
*              with SLATMS.
*
               CALL slatb4( path, imat, n, n, TYPE, kl, ku, anorm, mode,
     $                      cndnum, dist )
               rcondc = one / cndnum
*
               srnamt = 'SLATMS'
               CALL slatms( n, n, dist, iseed, TYPE, rwork, mode,
     $                      cndnum, anorm, kl, ku, packit, a, lda, work,
     $                      info )
*
*              Check error code from SLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'SLATMS', info, 0, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
                  GO TO 120
               END IF
*
*              For types 3-5, zero one row and column of the matrix to
*              test that INFO is returned correctly.
*
               IF( zerot ) THEN
                  IF( imat.EQ.3 ) THEN
                     izero = 1
                  ELSE IF( imat.EQ.4 ) THEN
                     izero = n
                  ELSE
                     izero = n / 2 + 1
                  END IF
*
*                 Set row and column IZERO of A to 0.
*
                  IF( iuplo.EQ.1 ) THEN
                     ioff = ( izero-1 )*izero / 2
                     DO 20 i = 1, izero - 1
                        a( ioff+i ) = zero
   20                CONTINUE
                     ioff = ioff + izero
                     DO 30 i = izero, n
                        a( ioff ) = zero
                        ioff = ioff + i
   30                CONTINUE
                  ELSE
                     ioff = izero
                     DO 40 i = 1, izero - 1
                        a( ioff ) = zero
                        ioff = ioff + n - i
   40                CONTINUE
                     ioff = ioff - izero
                     DO 50 i = izero, n
                        a( ioff+i ) = zero
   50                CONTINUE
                  END IF
               ELSE
                  izero = 0
               END IF
*
*              Save a copy of the matrix A in ASAV.
*
               CALL scopy( npp, a, 1, asav, 1 )
*
               DO 110 iequed = 1, 2
                  equed = equeds( iequed )
                  IF( iequed.EQ.1 ) THEN
                     nfact = 3
                  ELSE
                     nfact = 1
                  END IF
*
                  DO 100 ifact = 1, nfact
                     fact = facts( ifact )
                     prefac = lsame( fact, 'F' )
                     nofact = lsame( fact, 'N' )
                     equil = lsame( fact, 'E' )
*
                     IF( zerot ) THEN
                        IF( prefac )
     $                     GO TO 100
                        rcondc = zero
*
                     ELSE IF( .NOT.lsame( fact, 'N' ) ) THEN
*
*                       Compute the condition number for comparison with
*                       the value returned by SPPSVX (FACT = 'N' reuses
*                       the condition number from the previous iteration
*                       with FACT = 'F').
*
                        CALL scopy( npp, asav, 1, afac, 1 )
                        IF( equil .OR. iequed.GT.1 ) THEN
*
*                          Compute row and column scale factors to
*                          equilibrate the matrix A.
*
                           CALL sppequ( uplo, n, afac, s, scond, amax,
     $                                  info )
                           IF( info.EQ.0 .AND. n.GT.0 ) THEN
                              IF( iequed.GT.1 )
     $                           scond = zero
*
*                             Equilibrate the matrix.
*
                              CALL slaqsp( uplo, n, afac, s, scond,
     $                                     amax, equed )
                           END IF
                        END IF
*
*                       Save the condition number of the
*                       non-equilibrated system for use in SGET04.
*
                        IF( equil )
     $                     roldc = rcondc
*
*                       Compute the 1-norm of A.
*
                        anorm = slansp( '1', uplo, n, afac, rwork )
*
*                       Factor the matrix A.
*
                        CALL spptrf( uplo, n, afac, info )
*
*                       Form the inverse of A.
*
                        CALL scopy( npp, afac, 1, a, 1 )
                        CALL spptri( uplo, n, a, info )
*
*                       Compute the 1-norm condition number of A.
*
                        ainvnm = slansp( '1', uplo, n, a, rwork )
                        IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                           rcondc = one
                        ELSE
                           rcondc = ( one / anorm ) / ainvnm
                        END IF
                     END IF
*
*                    Restore the matrix A.
*
                     CALL scopy( npp, asav, 1, a, 1 )
*
*                    Form an exact solution and set the right hand side.
*
                     srnamt = 'SLARHS'
                     CALL slarhs( path, xtype, uplo, ' ', n, n, kl, ku,
     $                            nrhs, a, lda, xact, lda, b, lda,
     $                            iseed, info )
                     xtype = 'C'
                     CALL slacpy( 'Full', n, nrhs, b, lda, bsav, lda )
*
                     IF( nofact ) THEN
*
*                       --- Test SPPSV  ---
*
*                       Compute the L*L' or U'*U factorization of the
*                       matrix and solve the system.
*
                        CALL scopy( npp, a, 1, afac, 1 )
                        CALL slacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                        srnamt = 'SPPSV '
                        CALL sppsv( uplo, n, nrhs, afac, x, lda, info )
*
*                       Check error code from SPPSV .
*
                        IF( info.NE.izero ) THEN
                           CALL alaerh( path, 'SPPSV ', info, izero,
     $                                  uplo, n, n, -1, -1, nrhs, imat,
     $                                  nfail, nerrs, nout )
                           GO TO 70
                        ELSE IF( info.NE.0 ) THEN
                           GO TO 70
                        END IF
*
*                       Reconstruct matrix from factors and compute
*                       residual.
*
                        CALL sppt01( uplo, n, a, afac, rwork,
     $                               result( 1 ) )
*
*                       Compute residual of the computed solution.
*
                        CALL slacpy( 'Full', n, nrhs, b, lda, work,
     $                               lda )
                        CALL sppt02( uplo, n, nrhs, a, x, lda, work,
     $                               lda, rwork, result( 2 ) )
*
*                       Check solution from generated exact solution.
*
                        CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 3 ) )
                        nt = 3
*
*                       Print information about the tests that did not
*                       pass the threshold.
*
                        DO 60 k = 1, nt
                           IF( result( k ).GE.thresh ) THEN
                              IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                           CALL aladhd( nout, path )
                              WRITE( nout, fmt = 9999 )'SPPSV ', uplo,
     $                           n, imat, k, result( k )
                              nfail = nfail + 1
                           END IF
   60                   CONTINUE
                        nrun = nrun + nt
   70                   CONTINUE
                     END IF
*
*                    --- Test SPPSVX ---
*
                     IF( .NOT.prefac .AND. npp.GT.0 )
     $                  CALL slaset( 'Full', npp, 1, zero, zero, afac,
     $                               npp )
                     CALL slaset( 'Full', n, nrhs, zero, zero, x, lda )
                     IF( iequed.GT.1 .AND. n.GT.0 ) THEN
*
*                       Equilibrate the matrix if FACT='F' and
*                       EQUED='Y'.
*
                        CALL slaqsp( uplo, n, a, s, scond, amax, equed )
                     END IF
*
*                    Solve the system and compute the condition number
*                    and error bounds using SPPSVX.
*
                     srnamt = 'SPPSVX'
                     CALL sppsvx( fact, uplo, n, nrhs, a, afac, equed,
     $                            s, b, lda, x, lda, rcond, rwork,
     $                            rwork( nrhs+1 ), work, iwork, info )
*
*                    Check the error code from SPPSVX.
*
                     IF( info.NE.izero ) THEN
                        CALL alaerh( path, 'SPPSVX', info, izero,
     $                               fact // uplo, n, n, -1, -1, nrhs,
     $                               imat, nfail, nerrs, nout )
                        GO TO 90
                     END IF
*
                     IF( info.EQ.0 ) THEN
                        IF( .NOT.prefac ) THEN
*
*                          Reconstruct matrix from factors and compute
*                          residual.
*
                           CALL sppt01( uplo, n, a, afac,
     $                                  rwork( 2*nrhs+1 ), result( 1 ) )
                           k1 = 1
                        ELSE
                           k1 = 2
                        END IF
*
*                       Compute residual of the computed solution.
*
                        CALL slacpy( 'Full', n, nrhs, bsav, lda, work,
     $                               lda )
                        CALL sppt02( uplo, n, nrhs, asav, x, lda, work,
     $                               lda, rwork( 2*nrhs+1 ),
     $                               result( 2 ) )
*
*                       Check solution from generated exact solution.
*
                        IF( nofact .OR. ( prefac .AND. lsame( equed,
     $                      'N' ) ) ) THEN
                           CALL sget04( n, nrhs, x, lda, xact, lda,
     $                                  rcondc, result( 3 ) )
                        ELSE
                           CALL sget04( n, nrhs, x, lda, xact, lda,
     $                                  roldc, result( 3 ) )
                        END IF
*
*                       Check the error bounds from iterative
*                       refinement.
*
                        CALL sppt05( uplo, n, nrhs, asav, b, lda, x,
     $                               lda, xact, lda, rwork,
     $                               rwork( nrhs+1 ), result( 4 ) )
                     ELSE
                        k1 = 6
                     END IF
*
*                    Compare RCOND from SPPSVX with the computed value
*                    in RCONDC.
*
                     result( 6 ) = sget06( rcond, rcondc )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 80 k = k1, 6
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL aladhd( nout, path )
                           IF( prefac ) THEN
                              WRITE( nout, fmt = 9997 )'SPPSVX', fact,
     $                           uplo, n, equed, imat, k, result( k )
                           ELSE
                              WRITE( nout, fmt = 9998 )'SPPSVX', fact,
     $                           uplo, n, imat, k, result( k )
                           END IF
                           nfail = nfail + 1
                        END IF
   80                CONTINUE
                     nrun = nrun + 7 - k1
   90                CONTINUE
  100             CONTINUE
  110          CONTINUE
  120       CONTINUE
  130    CONTINUE
  140 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasvm( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( 1x, a, ', UPLO=''', a1, ''', N =', i5, ', type ', i1,
     $      ', test(', i1, ')=', g12.5 )
 9998 FORMAT( 1x, a, ', FACT=''', a1, ''', UPLO=''', a1, ''', N=', i5,
     $      ', type ', i1, ', test(', i1, ')=', g12.5 )
 9997 FORMAT( 1x, a, ', FACT=''', a1, ''', UPLO=''', a1, ''', N=', i5,
     $      ', EQUED=''', a1, ''', type ', i1, ', test(', i1, ')=',
     $      g12.5 )
      RETURN
*
*     End of SDRVPP
*
      END