dlaqz1()

subroutine dlaqz1	(	double precision, dimension( lda, * ), intent(in)	a,
		integer, intent(in)	lda,
		double precision, dimension( ldb, * ), intent(in)	b,
		integer, intent(in)	ldb,
		double precision, intent(in)	sr1,
		double precision, intent(in)	sr2,
		double precision, intent(in)	si,
		double precision, intent(in)	beta1,
		double precision, intent(in)	beta2,
		double precision, dimension( * ), intent(out)	v )

DLAQZ1

Download DLAQZ1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!>      Given a 3-by-3 matrix pencil (A,B), DLAQZ1 sets v to a
!>      scalar multiple of the first column of the product
!>
!>      (*)  K = (A - (beta2*sr2 - i*si)*B)*B^(-1)*(beta1*A - (sr2 + i*si2)*B)*B^(-1).
!>
!>      It is assumed that either
!>
!>              1) sr1 = sr2
!>          or
!>              2) si = 0.
!>
!>      This is useful for starting double implicit shift bulges
!>      in the QZ algorithm.
!> 

Parameters

[in]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> The 3-by-3 matrix A in (*). !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of A as declared in !> the calling procedure. !>
[in]	B	!> B is DOUBLE PRECISION array, dimension (LDB,N) !> The 3-by-3 matrix B in (*). !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of B as declared in !> the calling procedure. !>
[in]	SR1	!> SR1 is DOUBLE PRECISION !>
[in]	SR2	!> SR2 is DOUBLE PRECISION !>
[in]	SI	!> SI is DOUBLE PRECISION !>
[in]	BETA1	!> BETA1 is DOUBLE PRECISION !>
[in]	BETA2	!> BETA2 is DOUBLE PRECISION !>
[out]	V	!> V is DOUBLE PRECISION array, dimension (N) !> A scalar multiple of the first column of the !> matrix K in (*). !>

Author

Thijs Steel, KU Leuven

Date

May 2020

Definition at line 123 of file dlaqz1.f.

      IMPLICIT NONE
*
*     Arguments
      INTEGER, INTENT( IN ) :: LDA, LDB
      DOUBLE PRECISION, INTENT( IN ) :: A( LDA, * ), B( LDB, * ), SR1,
     $                  SR2, SI, BETA1, BETA2
      DOUBLE PRECISION, INTENT( OUT ) :: V( * )
*
*     Parameters
      DOUBLE PRECISION :: ZERO, ONE, HALF
      parameter( zero = 0.0d0, one = 1.0d0, half = 0.5d0 )
*
*     Local scalars
      DOUBLE PRECISION :: W( 2 ), SAFMIN, SAFMAX, SCALE1, SCALE2
*
*     External Functions
      DOUBLE PRECISION, EXTERNAL :: DLAMCH
      LOGICAL, EXTERNAL :: DISNAN
*
      safmin = dlamch( 'SAFE MINIMUM' )
      safmax = one/safmin
*
*     Calculate first shifted vector
*
      w( 1 ) = beta1*a( 1, 1 )-sr1*b( 1, 1 )
      w( 2 ) = beta1*a( 2, 1 )-sr1*b( 2, 1 )
      scale1 = sqrt( abs( w( 1 ) ) ) * sqrt( abs( w( 2 ) ) )
      IF( scale1 .GE. safmin .AND. scale1 .LE. safmax ) THEN
         w( 1 ) = w( 1 )/scale1
         w( 2 ) = w( 2 )/scale1
      END IF
*
*     Solve linear system
*
      w( 2 ) = w( 2 )/b( 2, 2 )
      w( 1 ) = ( w( 1 )-b( 1, 2 )*w( 2 ) )/b( 1, 1 )
      scale2 = sqrt( abs( w( 1 ) ) ) * sqrt( abs( w( 2 ) ) )
      IF( scale2 .GE. safmin .AND. scale2 .LE. safmax ) THEN
         w( 1 ) = w( 1 )/scale2
         w( 2 ) = w( 2 )/scale2
      END IF
*
*     Apply second shift
*
      v( 1 ) = beta2*( a( 1, 1 )*w( 1 )+a( 1, 2 )*w( 2 ) )-sr2*( b( 1,
     $   1 )*w( 1 )+b( 1, 2 )*w( 2 ) )
      v( 2 ) = beta2*( a( 2, 1 )*w( 1 )+a( 2, 2 )*w( 2 ) )-sr2*( b( 2,
     $   1 )*w( 1 )+b( 2, 2 )*w( 2 ) )
      v( 3 ) = beta2*( a( 3, 1 )*w( 1 )+a( 3, 2 )*w( 2 ) )-sr2*( b( 3,
     $   1 )*w( 1 )+b( 3, 2 )*w( 2 ) )
*
*     Account for imaginary part
*
      v( 1 ) = v( 1 )+si*si*b( 1, 1 )/scale1/scale2
*
*     Check for overflow
*
      IF( abs( v( 1 ) ).GT.safmax .OR. abs( v( 2 ) ) .GT. safmax .OR.
     $   abs( v( 3 ) ).GT.safmax .OR. disnan( v( 1 ) ) .OR.
     $   disnan( v( 2 ) ) .OR. disnan( v( 3 ) ) ) THEN
         v( 1 ) = zero
         v( 2 ) = zero
         v( 3 ) = zero
      END IF
*
*     End of DLAQZ1
*

Here is the caller graph for this function: