dhst01()

subroutine dhst01	(	integer	n,
		integer	ilo,
		integer	ihi,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( ldh, * )	h,
		integer	ldh,
		double precision, dimension( ldq, * )	q,
		integer	ldq,
		double precision, dimension( lwork )	work,
		integer	lwork,
		double precision, dimension( 2 )	result
	)

DHST01

Purpose:

 DHST01 tests the reduction of a general matrix A to upper Hessenberg
 form:  A = Q*H*Q'.  Two test ratios are computed;

 RESULT(1) = norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
 RESULT(2) = norm( I - Q'*Q ) / ( N * EPS )

 The matrix Q is assumed to be given explicitly as it would be
 following DGEHRD + DORGHR.

 In this version, ILO and IHI are not used and are assumed to be 1 and
 N, respectively.

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	ILO	ILO is INTEGER
[in]	IHI	IHI is INTEGER A is assumed to be upper triangular in rows and columns 1:ILO-1 and IHI+1:N, so Q differs from the identity only in rows and columns ILO+1:IHI.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) The original n by n matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	H	H is DOUBLE PRECISION array, dimension (LDH,N) The upper Hessenberg matrix H from the reduction A = Q*H*Q' as computed by DGEHRD. H is assumed to be zero below the first subdiagonal.
[in]	LDH	LDH is INTEGER The leading dimension of the array H. LDH >= max(1,N).
[in]	Q	Q is DOUBLE PRECISION array, dimension (LDQ,N) The orthogonal matrix Q from the reduction A = Q*H*Q' as computed by DGEHRD + DORGHR.
[in]	LDQ	LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= 2*N*N.
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (2) RESULT(1) = norm( A - Q*H*Q' ) / ( norm(A) * N * EPS ) RESULT(2) = norm( I - Q'*Q ) / ( N * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 132 of file dhst01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            IHI, ILO, LDA, LDH, LDQ, LWORK, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), H( LDH, * ), Q( LDQ, * ),
     $                   RESULT( 2 ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            LDWORK
      DOUBLE PRECISION   ANORM, EPS, OVFL, SMLNUM, UNFL, WNORM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dlacpy, dort01
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         RETURN
      END IF
*
      unfl = dlamch( 'Safe minimum' )
      eps = dlamch( 'Precision' )
      ovfl = one / unfl
      smlnum = unfl*n / eps
*
*     Test 1:  Compute norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
*
*     Copy A to WORK
*
      ldwork = max( 1, n )
      CALL dlacpy( ' ', n, n, a, lda, work, ldwork )
*
*     Compute Q*H
*
      CALL dgemm( 'No transpose', 'No transpose', n, n, n, one, q, ldq,
     $            h, ldh, zero, work( ldwork*n+1 ), ldwork )
*
*     Compute A - Q*H*Q'
*
      CALL dgemm( 'No transpose', 'Transpose', n, n, n, -one,
     $            work( ldwork*n+1 ), ldwork, q, ldq, one, work,
     $            ldwork )
*
      anorm = max( dlange( '1', n, n, a, lda, work( ldwork*n+1 ) ),
     $        unfl )
      wnorm = dlange( '1', n, n, work, ldwork, work( ldwork*n+1 ) )
*
*     Note that RESULT(1) cannot overflow and is bounded by 1/(N*EPS)
*
      result( 1 ) = min( wnorm, anorm ) / max( smlnum, anorm*eps ) / n
*
*     Test 2:  Compute norm( I - Q'*Q ) / ( N * EPS )
*
      CALL dort01( 'Columns', n, n, q, ldq, work, lwork, result( 2 ) )
*
      RETURN
*
*     End of DHST01
*

Here is the call graph for this function:

Here is the caller graph for this function: