LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ dtgsja()

 subroutine dtgsja ( character jobu, character jobv, character jobq, integer m, integer p, integer n, integer k, integer l, double precision, dimension( lda, * ) a, integer lda, double precision, dimension( ldb, * ) b, integer ldb, double precision tola, double precision tolb, double precision, dimension( * ) alpha, double precision, dimension( * ) beta, double precision, dimension( ldu, * ) u, integer ldu, double precision, dimension( ldv, * ) v, integer ldv, double precision, dimension( ldq, * ) q, integer ldq, double precision, dimension( * ) work, integer ncycle, integer info )

DTGSJA

Purpose:
``` DTGSJA computes the generalized singular value decomposition (GSVD)
of two real upper triangular (or trapezoidal) matrices A and B.

On entry, it is assumed that matrices A and B have the following
forms, which may be obtained by the preprocessing subroutine DGGSVP
from a general M-by-N matrix A and P-by-N matrix B:

N-K-L  K    L
A =    K ( 0    A12  A13 ) if M-K-L >= 0;
L ( 0     0   A23 )
M-K-L ( 0     0    0  )

N-K-L  K    L
A =  K ( 0    A12  A13 ) if M-K-L < 0;
M-K ( 0     0   A23 )

N-K-L  K    L
B =  L ( 0     0   B13 )
P-L ( 0     0    0  )

where the K-by-K matrix A12 and L-by-L matrix B13 are nonsingular
upper triangular; A23 is L-by-L upper triangular if M-K-L >= 0,
otherwise A23 is (M-K)-by-L upper trapezoidal.

On exit,

U**T *A*Q = D1*( 0 R ),    V**T *B*Q = D2*( 0 R ),

where U, V and Q are orthogonal matrices.
R is a nonsingular upper triangular matrix, and D1 and D2 are
``diagonal'' matrices, which are of the following structures:

If M-K-L >= 0,

K  L
D1 =     K ( I  0 )
L ( 0  C )
M-K-L ( 0  0 )

K  L
D2 = L   ( 0  S )
P-L ( 0  0 )

N-K-L  K    L
( 0 R ) = K (  0   R11  R12 ) K
L (  0    0   R22 ) L

where

C = diag( ALPHA(K+1), ... , ALPHA(K+L) ),
S = diag( BETA(K+1),  ... , BETA(K+L) ),
C**2 + S**2 = I.

R is stored in A(1:K+L,N-K-L+1:N) on exit.

If M-K-L < 0,

K M-K K+L-M
D1 =   K ( I  0    0   )
M-K ( 0  C    0   )

K M-K K+L-M
D2 =   M-K ( 0  S    0   )
K+L-M ( 0  0    I   )
P-L ( 0  0    0   )

N-K-L  K   M-K  K+L-M
( 0 R ) =    K ( 0    R11  R12  R13  )
M-K ( 0     0   R22  R23  )
K+L-M ( 0     0    0   R33  )

where
C = diag( ALPHA(K+1), ... , ALPHA(M) ),
S = diag( BETA(K+1),  ... , BETA(M) ),
C**2 + S**2 = I.

R = ( R11 R12 R13 ) is stored in A(1:M, N-K-L+1:N) and R33 is stored
(  0  R22 R23 )
in B(M-K+1:L,N+M-K-L+1:N) on exit.

The computation of the orthogonal transformation matrices U, V or Q
is optional.  These matrices may either be formed explicitly, or they
may be postmultiplied into input matrices U1, V1, or Q1.```
Parameters
 [in] JOBU ``` JOBU is CHARACTER*1 = 'U': U must contain an orthogonal matrix U1 on entry, and the product U1*U is returned; = 'I': U is initialized to the unit matrix, and the orthogonal matrix U is returned; = 'N': U is not computed.``` [in] JOBV ``` JOBV is CHARACTER*1 = 'V': V must contain an orthogonal matrix V1 on entry, and the product V1*V is returned; = 'I': V is initialized to the unit matrix, and the orthogonal matrix V is returned; = 'N': V is not computed.``` [in] JOBQ ``` JOBQ is CHARACTER*1 = 'Q': Q must contain an orthogonal matrix Q1 on entry, and the product Q1*Q is returned; = 'I': Q is initialized to the unit matrix, and the orthogonal matrix Q is returned; = 'N': Q is not computed.``` [in] M ``` M is INTEGER The number of rows of the matrix A. M >= 0.``` [in] P ``` P is INTEGER The number of rows of the matrix B. P >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrices A and B. N >= 0.``` [in] K ` K is INTEGER` [in] L ``` L is INTEGER K and L specify the subblocks in the input matrices A and B: A23 = A(K+1:MIN(K+L,M),N-L+1:N) and B13 = B(1:L,N-L+1:N) of A and B, whose GSVD is going to be computed by DTGSJA. See Further Details.``` [in,out] A ``` A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the M-by-N matrix A. On exit, A(N-K+1:N,1:MIN(K+L,M) ) contains the triangular matrix R or part of R. See Purpose for details.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).``` [in,out] B ``` B is DOUBLE PRECISION array, dimension (LDB,N) On entry, the P-by-N matrix B. On exit, if necessary, B(M-K+1:L,N+M-K-L+1:N) contains a part of R. See Purpose for details.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,P).``` [in] TOLA ` TOLA is DOUBLE PRECISION` [in] TOLB ``` TOLB is DOUBLE PRECISION TOLA and TOLB are the convergence criteria for the Jacobi- Kogbetliantz iteration procedure. Generally, they are the same as used in the preprocessing step, say TOLA = max(M,N)*norm(A)*MAZHEPS, TOLB = max(P,N)*norm(B)*MAZHEPS.``` [out] ALPHA ` ALPHA is DOUBLE PRECISION array, dimension (N)` [out] BETA ``` BETA is DOUBLE PRECISION array, dimension (N) On exit, ALPHA and BETA contain the generalized singular value pairs of A and B; ALPHA(1:K) = 1, BETA(1:K) = 0, and if M-K-L >= 0, ALPHA(K+1:K+L) = diag(C), BETA(K+1:K+L) = diag(S), or if M-K-L < 0, ALPHA(K+1:M)= C, ALPHA(M+1:K+L)= 0 BETA(K+1:M) = S, BETA(M+1:K+L) = 1. Furthermore, if K+L < N, ALPHA(K+L+1:N) = 0 and BETA(K+L+1:N) = 0.``` [in,out] U ``` U is DOUBLE PRECISION array, dimension (LDU,M) On entry, if JOBU = 'U', U must contain a matrix U1 (usually the orthogonal matrix returned by DGGSVP). On exit, if JOBU = 'I', U contains the orthogonal matrix U; if JOBU = 'U', U contains the product U1*U. If JOBU = 'N', U is not referenced.``` [in] LDU ``` LDU is INTEGER The leading dimension of the array U. LDU >= max(1,M) if JOBU = 'U'; LDU >= 1 otherwise.``` [in,out] V ``` V is DOUBLE PRECISION array, dimension (LDV,P) On entry, if JOBV = 'V', V must contain a matrix V1 (usually the orthogonal matrix returned by DGGSVP). On exit, if JOBV = 'I', V contains the orthogonal matrix V; if JOBV = 'V', V contains the product V1*V. If JOBV = 'N', V is not referenced.``` [in] LDV ``` LDV is INTEGER The leading dimension of the array V. LDV >= max(1,P) if JOBV = 'V'; LDV >= 1 otherwise.``` [in,out] Q ``` Q is DOUBLE PRECISION array, dimension (LDQ,N) On entry, if JOBQ = 'Q', Q must contain a matrix Q1 (usually the orthogonal matrix returned by DGGSVP). On exit, if JOBQ = 'I', Q contains the orthogonal matrix Q; if JOBQ = 'Q', Q contains the product Q1*Q. If JOBQ = 'N', Q is not referenced.``` [in] LDQ ``` LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N) if JOBQ = 'Q'; LDQ >= 1 otherwise.``` [out] WORK ` WORK is DOUBLE PRECISION array, dimension (2*N)` [out] NCYCLE ``` NCYCLE is INTEGER The number of cycles required for convergence.``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value. = 1: the procedure does not converge after MAXIT cycles.```
```  Internal Parameters
===================

MAXIT   INTEGER
MAXIT specifies the total loops that the iterative procedure
may take. If after MAXIT cycles, the routine fails to
converge, we return INFO = 1.```
Further Details:
```  DTGSJA essentially uses a variant of Kogbetliantz algorithm to reduce
min(L,M-K)-by-L triangular (or trapezoidal) matrix A23 and L-by-L
matrix B13 to the form:

U1**T *A13*Q1 = C1*R1; V1**T *B13*Q1 = S1*R1,

where U1, V1 and Q1 are orthogonal matrix, and Z**T is the transpose
of Z.  C1 and S1 are diagonal matrices satisfying

C1**2 + S1**2 = I,

and R1 is an L-by-L nonsingular upper triangular matrix.```

Definition at line 375 of file dtgsja.f.

378*
379* -- LAPACK computational routine --
380* -- LAPACK is a software package provided by Univ. of Tennessee, --
381* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
382*
383* .. Scalar Arguments ..
384 CHARACTER JOBQ, JOBU, JOBV
385 INTEGER INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N,
386 \$ NCYCLE, P
387 DOUBLE PRECISION TOLA, TOLB
388* ..
389* .. Array Arguments ..
390 DOUBLE PRECISION A( LDA, * ), ALPHA( * ), B( LDB, * ),
391 \$ BETA( * ), Q( LDQ, * ), U( LDU, * ),
392 \$ V( LDV, * ), WORK( * )
393* ..
394*
395* =====================================================================
396*
397* .. Parameters ..
398 INTEGER MAXIT
399 parameter( maxit = 40 )
400 DOUBLE PRECISION ZERO, ONE, HUGENUM
401 parameter( zero = 0.0d+0, one = 1.0d+0 )
402* ..
403* .. Local Scalars ..
404*
405 LOGICAL INITQ, INITU, INITV, UPPER, WANTQ, WANTU, WANTV
406 INTEGER I, J, KCYCLE
407 DOUBLE PRECISION A1, A2, A3, B1, B2, B3, CSQ, CSU, CSV, ERROR,
408 \$ GAMMA, RWK, SNQ, SNU, SNV, SSMIN
409* ..
410* .. External Functions ..
411 LOGICAL LSAME
412 EXTERNAL lsame
413* ..
414* .. External Subroutines ..
415 EXTERNAL dcopy, dlags2, dlapll, dlartg, dlaset, drot,
416 \$ dscal, xerbla
417* ..
418* .. Intrinsic Functions ..
419 INTRINSIC abs, max, min, huge
420 parameter( hugenum = huge(zero) )
421* ..
422* .. Executable Statements ..
423*
424* Decode and test the input parameters
425*
426 initu = lsame( jobu, 'I' )
427 wantu = initu .OR. lsame( jobu, 'U' )
428*
429 initv = lsame( jobv, 'I' )
430 wantv = initv .OR. lsame( jobv, 'V' )
431*
432 initq = lsame( jobq, 'I' )
433 wantq = initq .OR. lsame( jobq, 'Q' )
434*
435 info = 0
436 IF( .NOT.( initu .OR. wantu .OR. lsame( jobu, 'N' ) ) ) THEN
437 info = -1
438 ELSE IF( .NOT.( initv .OR. wantv .OR. lsame( jobv, 'N' ) ) ) THEN
439 info = -2
440 ELSE IF( .NOT.( initq .OR. wantq .OR. lsame( jobq, 'N' ) ) ) THEN
441 info = -3
442 ELSE IF( m.LT.0 ) THEN
443 info = -4
444 ELSE IF( p.LT.0 ) THEN
445 info = -5
446 ELSE IF( n.LT.0 ) THEN
447 info = -6
448 ELSE IF( lda.LT.max( 1, m ) ) THEN
449 info = -10
450 ELSE IF( ldb.LT.max( 1, p ) ) THEN
451 info = -12
452 ELSE IF( ldu.LT.1 .OR. ( wantu .AND. ldu.LT.m ) ) THEN
453 info = -18
454 ELSE IF( ldv.LT.1 .OR. ( wantv .AND. ldv.LT.p ) ) THEN
455 info = -20
456 ELSE IF( ldq.LT.1 .OR. ( wantq .AND. ldq.LT.n ) ) THEN
457 info = -22
458 END IF
459 IF( info.NE.0 ) THEN
460 CALL xerbla( 'DTGSJA', -info )
461 RETURN
462 END IF
463*
464* Initialize U, V and Q, if necessary
465*
466 IF( initu )
467 \$ CALL dlaset( 'Full', m, m, zero, one, u, ldu )
468 IF( initv )
469 \$ CALL dlaset( 'Full', p, p, zero, one, v, ldv )
470 IF( initq )
471 \$ CALL dlaset( 'Full', n, n, zero, one, q, ldq )
472*
473* Loop until convergence
474*
475 upper = .false.
476 DO 40 kcycle = 1, maxit
477*
478 upper = .NOT.upper
479*
480 DO 20 i = 1, l - 1
481 DO 10 j = i + 1, l
482*
483 a1 = zero
484 a2 = zero
485 a3 = zero
486 IF( k+i.LE.m )
487 \$ a1 = a( k+i, n-l+i )
488 IF( k+j.LE.m )
489 \$ a3 = a( k+j, n-l+j )
490*
491 b1 = b( i, n-l+i )
492 b3 = b( j, n-l+j )
493*
494 IF( upper ) THEN
495 IF( k+i.LE.m )
496 \$ a2 = a( k+i, n-l+j )
497 b2 = b( i, n-l+j )
498 ELSE
499 IF( k+j.LE.m )
500 \$ a2 = a( k+j, n-l+i )
501 b2 = b( j, n-l+i )
502 END IF
503*
504 CALL dlags2( upper, a1, a2, a3, b1, b2, b3, csu, snu,
505 \$ csv, snv, csq, snq )
506*
507* Update (K+I)-th and (K+J)-th rows of matrix A: U**T *A
508*
509 IF( k+j.LE.m )
510 \$ CALL drot( l, a( k+j, n-l+1 ), lda, a( k+i, n-l+1 ),
511 \$ lda, csu, snu )
512*
513* Update I-th and J-th rows of matrix B: V**T *B
514*
515 CALL drot( l, b( j, n-l+1 ), ldb, b( i, n-l+1 ), ldb,
516 \$ csv, snv )
517*
518* Update (N-L+I)-th and (N-L+J)-th columns of matrices
519* A and B: A*Q and B*Q
520*
521 CALL drot( min( k+l, m ), a( 1, n-l+j ), 1,
522 \$ a( 1, n-l+i ), 1, csq, snq )
523*
524 CALL drot( l, b( 1, n-l+j ), 1, b( 1, n-l+i ), 1, csq,
525 \$ snq )
526*
527 IF( upper ) THEN
528 IF( k+i.LE.m )
529 \$ a( k+i, n-l+j ) = zero
530 b( i, n-l+j ) = zero
531 ELSE
532 IF( k+j.LE.m )
533 \$ a( k+j, n-l+i ) = zero
534 b( j, n-l+i ) = zero
535 END IF
536*
537* Update orthogonal matrices U, V, Q, if desired.
538*
539 IF( wantu .AND. k+j.LE.m )
540 \$ CALL drot( m, u( 1, k+j ), 1, u( 1, k+i ), 1, csu,
541 \$ snu )
542*
543 IF( wantv )
544 \$ CALL drot( p, v( 1, j ), 1, v( 1, i ), 1, csv, snv )
545*
546 IF( wantq )
547 \$ CALL drot( n, q( 1, n-l+j ), 1, q( 1, n-l+i ), 1, csq,
548 \$ snq )
549*
550 10 CONTINUE
551 20 CONTINUE
552*
553 IF( .NOT.upper ) THEN
554*
555* The matrices A13 and B13 were lower triangular at the start
556* of the cycle, and are now upper triangular.
557*
558* Convergence test: test the parallelism of the corresponding
559* rows of A and B.
560*
561 error = zero
562 DO 30 i = 1, min( l, m-k )
563 CALL dcopy( l-i+1, a( k+i, n-l+i ), lda, work, 1 )
564 CALL dcopy( l-i+1, b( i, n-l+i ), ldb, work( l+1 ), 1 )
565 CALL dlapll( l-i+1, work, 1, work( l+1 ), 1, ssmin )
566 error = max( error, ssmin )
567 30 CONTINUE
568*
569 IF( abs( error ).LE.min( tola, tolb ) )
570 \$ GO TO 50
571 END IF
572*
573* End of cycle loop
574*
575 40 CONTINUE
576*
577* The algorithm has not converged after MAXIT cycles.
578*
579 info = 1
580 GO TO 100
581*
582 50 CONTINUE
583*
584* If ERROR <= MIN(TOLA,TOLB), then the algorithm has converged.
585* Compute the generalized singular value pairs (ALPHA, BETA), and
586* set the triangular matrix R to array A.
587*
588 DO 60 i = 1, k
589 alpha( i ) = one
590 beta( i ) = zero
591 60 CONTINUE
592*
593 DO 70 i = 1, min( l, m-k )
594*
595 a1 = a( k+i, n-l+i )
596 b1 = b( i, n-l+i )
597 gamma = b1 / a1
598*
599 IF( (gamma.LE.hugenum).AND.(gamma.GE.-hugenum) ) THEN
600*
601* change sign if necessary
602*
603 IF( gamma.LT.zero ) THEN
604 CALL dscal( l-i+1, -one, b( i, n-l+i ), ldb )
605 IF( wantv )
606 \$ CALL dscal( p, -one, v( 1, i ), 1 )
607 END IF
608*
609 CALL dlartg( abs( gamma ), one, beta( k+i ), alpha( k+i ),
610 \$ rwk )
611*
612 IF( alpha( k+i ).GE.beta( k+i ) ) THEN
613 CALL dscal( l-i+1, one / alpha( k+i ), a( k+i, n-l+i ),
614 \$ lda )
615 ELSE
616 CALL dscal( l-i+1, one / beta( k+i ), b( i, n-l+i ),
617 \$ ldb )
618 CALL dcopy( l-i+1, b( i, n-l+i ), ldb, a( k+i, n-l+i ),
619 \$ lda )
620 END IF
621*
622 ELSE
623*
624 alpha( k+i ) = zero
625 beta( k+i ) = one
626 CALL dcopy( l-i+1, b( i, n-l+i ), ldb, a( k+i, n-l+i ),
627 \$ lda )
628*
629 END IF
630*
631 70 CONTINUE
632*
633* Post-assignment
634*
635 DO 80 i = m + 1, k + l
636 alpha( i ) = zero
637 beta( i ) = one
638 80 CONTINUE
639*
640 IF( k+l.LT.n ) THEN
641 DO 90 i = k + l + 1, n
642 alpha( i ) = zero
643 beta( i ) = zero
644 90 CONTINUE
645 END IF
646*
647 100 CONTINUE
648 ncycle = kcycle
649 RETURN
650*
651* End of DTGSJA
652*
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine dcopy(n, dx, incx, dy, incy)
DCOPY
Definition dcopy.f:82
subroutine dlags2(upper, a1, a2, a3, b1, b2, b3, csu, snu, csv, snv, csq, snq)
DLAGS2 computes 2-by-2 orthogonal matrices U, V, and Q, and applies them to matrices A and B such tha...
Definition dlags2.f:152
subroutine dlapll(n, x, incx, y, incy, ssmin)
DLAPLL measures the linear dependence of two vectors.
Definition dlapll.f:102
subroutine dlartg(f, g, c, s, r)
DLARTG generates a plane rotation with real cosine and real sine.
Definition dlartg.f90:111
subroutine dlaset(uplo, m, n, alpha, beta, a, lda)
DLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition dlaset.f:110
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
subroutine drot(n, dx, incx, dy, incy, c, s)
DROT
Definition drot.f:92
subroutine dscal(n, da, dx, incx)
DSCAL
Definition dscal.f:79
Here is the call graph for this function:
Here is the caller graph for this function: