LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ zgelq2()

 subroutine zgelq2 ( integer m, integer n, complex*16, dimension( lda, * ) a, integer lda, complex*16, dimension( * ) tau, complex*16, dimension( * ) work, integer info )

ZGELQ2 computes the LQ factorization of a general rectangular matrix using an unblocked algorithm.

Purpose:
``` ZGELQ2 computes an LQ factorization of a complex m-by-n matrix A:

A = ( L 0 ) *  Q

where:

Q is a n-by-n orthogonal matrix;
L is a lower-triangular m-by-m matrix;
0 is a m-by-(n-m) zero matrix, if m < n.```
Parameters
 [in] M ``` M is INTEGER The number of rows of the matrix A. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrix A. N >= 0.``` [in,out] A ``` A is COMPLEX*16 array, dimension (LDA,N) On entry, the m by n matrix A. On exit, the elements on and below the diagonal of the array contain the m by min(m,n) lower trapezoidal matrix L (L is lower triangular if m <= n); the elements above the diagonal, with the array TAU, represent the unitary matrix Q as a product of elementary reflectors (see Further Details).``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).``` [out] TAU ``` TAU is COMPLEX*16 array, dimension (min(M,N)) The scalar factors of the elementary reflectors (see Further Details).``` [out] WORK ` WORK is COMPLEX*16 array, dimension (M)` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value```
Further Details:
```  The matrix Q is represented as a product of elementary reflectors

Q = H(k)**H . . . H(2)**H H(1)**H, where k = min(m,n).

Each H(i) has the form

H(i) = I - tau * v * v**H

where tau is a complex scalar, and v is a complex vector with
v(1:i-1) = 0 and v(i) = 1; conjg(v(i+1:n)) is stored on exit in
A(i,i+1:n), and tau in TAU(i).```

Definition at line 128 of file zgelq2.f.

129*
130* -- LAPACK computational routine --
131* -- LAPACK is a software package provided by Univ. of Tennessee, --
132* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
133*
134* .. Scalar Arguments ..
135 INTEGER INFO, LDA, M, N
136* ..
137* .. Array Arguments ..
138 COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
139* ..
140*
141* =====================================================================
142*
143* .. Parameters ..
144 COMPLEX*16 ONE
145 parameter( one = ( 1.0d+0, 0.0d+0 ) )
146* ..
147* .. Local Scalars ..
148 INTEGER I, K
149 COMPLEX*16 ALPHA
150* ..
151* .. External Subroutines ..
152 EXTERNAL xerbla, zlacgv, zlarf, zlarfg
153* ..
154* .. Intrinsic Functions ..
155 INTRINSIC max, min
156* ..
157* .. Executable Statements ..
158*
159* Test the input arguments
160*
161 info = 0
162 IF( m.LT.0 ) THEN
163 info = -1
164 ELSE IF( n.LT.0 ) THEN
165 info = -2
166 ELSE IF( lda.LT.max( 1, m ) ) THEN
167 info = -4
168 END IF
169 IF( info.NE.0 ) THEN
170 CALL xerbla( 'ZGELQ2', -info )
171 RETURN
172 END IF
173*
174 k = min( m, n )
175*
176 DO 10 i = 1, k
177*
178* Generate elementary reflector H(i) to annihilate A(i,i+1:n)
179*
180 CALL zlacgv( n-i+1, a( i, i ), lda )
181 alpha = a( i, i )
182 CALL zlarfg( n-i+1, alpha, a( i, min( i+1, n ) ), lda,
183 \$ tau( i ) )
184 IF( i.LT.m ) THEN
185*
186* Apply H(i) to A(i+1:m,i:n) from the right
187*
188 a( i, i ) = one
189 CALL zlarf( 'Right', m-i, n-i+1, a( i, i ), lda, tau( i ),
190 \$ a( i+1, i ), lda, work )
191 END IF
192 a( i, i ) = alpha
193 CALL zlacgv( n-i+1, a( i, i ), lda )
194 10 CONTINUE
195 RETURN
196*
197* End of ZGELQ2
198*
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine zlacgv(n, x, incx)
ZLACGV conjugates a complex vector.
Definition zlacgv.f:74
subroutine zlarf(side, m, n, v, incv, tau, c, ldc, work)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition zlarf.f:128
subroutine zlarfg(n, alpha, x, incx, tau)
ZLARFG generates an elementary reflector (Householder matrix).
Definition zlarfg.f:106
Here is the call graph for this function:
Here is the caller graph for this function: