cheevr()

subroutine cheevr	(	character	jobz,
		character	range,
		character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		real	vl,
		real	vu,
		integer	il,
		integer	iu,
		real	abstol,
		integer	m,
		real, dimension( * )	w,
		complex, dimension( ldz, * )	z,
		integer	ldz,
		integer, dimension( * )	isuppz,
		complex, dimension( * )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		integer	lrwork,
		integer, dimension( * )	iwork,
		integer	liwork,
		integer	info )

CHEEVR computes the eigenvalues and, optionally, the left and/or right eigenvectors for HE matrices

Download CHEEVR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CHEEVR computes selected eigenvalues and, optionally, eigenvectors
!> of a complex Hermitian matrix A. Eigenvalues and eigenvectors can be
!> selected by specifying either a range of values or a range of indices
!> for the desired eigenvalues. Invocations with different choices for
!> these parameters may result in the computation of slightly different
!> eigenvalues and/or eigenvectors for the same matrix. The reason for
!> this behavior is that there exists a variety of algorithms (each
!> performing best for a particular set of options) with CHEEVR
!> attempting to select the best based on the various parameters. In all
!> cases, the computed values are accurate within the limits of finite
!> precision arithmetic.
!>
!> CHEEVR first reduces the matrix A to tridiagonal form T with a call
!> to CHETRD.  Then, whenever possible, CHEEVR calls CSTEMR to compute
!> the eigenspectrum using Relatively Robust Representations.  CSTEMR
!> computes eigenvalues by the dqds algorithm, while orthogonal
!> eigenvectors are computed from various  L D L^T representations
!> (also known as Relatively Robust Representations). Gram-Schmidt
!> orthogonalization is avoided as far as possible. More specifically,
!> the various steps of the algorithm are as follows.
!>
!> For each unreduced block (submatrix) of T,
!>    (a) Compute T - sigma I  = L D L^T, so that L and D
!>        define all the wanted eigenvalues to high relative accuracy.
!>        This means that small relative changes in the entries of D and L
!>        cause only small relative changes in the eigenvalues and
!>        eigenvectors. The standard (unfactored) representation of the
!>        tridiagonal matrix T does not have this property in general.
!>    (b) Compute the eigenvalues to suitable accuracy.
!>        If the eigenvectors are desired, the algorithm attains full
!>        accuracy of the computed eigenvalues only right before
!>        the corresponding vectors have to be computed, see steps c) and d).
!>    (c) For each cluster of close eigenvalues, select a new
!>        shift close to the cluster, find a new factorization, and refine
!>        the shifted eigenvalues to suitable accuracy.
!>    (d) For each eigenvalue with a large enough relative separation compute
!>        the corresponding eigenvector by forming a rank revealing twisted
!>        factorization. Go back to (c) for any clusters that remain.
!>
!> The desired accuracy of the output can be specified by the input
!> parameter ABSTOL.
!>
!> For more details, see CSTEMR's documentation and:
!> - Inderjit S. Dhillon and Beresford N. Parlett: 
!>   Linear Algebra and its Applications, 387(1), pp. 1-28, August 2004.
!> - Inderjit Dhillon and Beresford Parlett:  SIAM Journal on Matrix Analysis and Applications, Vol. 25,
!>   2004.  Also LAPACK Working Note 154.
!> - Inderjit Dhillon: ,
!>   Computer Science Division Technical Report No. UCB/CSD-97-971,
!>   UC Berkeley, May 1997.
!>
!>
!> Note 1 : CHEEVR calls CSTEMR when the full spectrum is requested
!> on machines which conform to the ieee-754 floating point standard.
!> CHEEVR calls SSTEBZ and CSTEIN on non-ieee machines and
!> when partial spectrum requests are made.
!>
!> Normal execution of CSTEMR may create NaNs and infinities and
!> hence may abort due to a floating point exception in environments
!> which do not handle NaNs and infinities in the ieee standard default
!> manner.
!> 

Parameters

[in]	JOBZ	!> JOBZ is CHARACTER*1 !> = 'N': Compute eigenvalues only; !> = 'V': Compute eigenvalues and eigenvectors. !> !> This parameter influences the choice of the algorithm and !> may alter the computed values. !>
[in]	RANGE	!> RANGE is CHARACTER*1 !> = 'A': all eigenvalues will be found. !> = 'V': all eigenvalues in the half-open interval (VL,VU] !> will be found. !> = 'I': the IL-th through IU-th eigenvalues will be found. !> For RANGE = 'V' or 'I' and IU - IL < N - 1, SSTEBZ and !> CSTEIN are called !> !> This parameter influences the choice of the algorithm and !> may alter the computed values. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangle of A is stored; !> = 'L': Lower triangle of A is stored. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA, N) !> On entry, the Hermitian matrix A. If UPLO = 'U', the !> leading N-by-N upper triangular part of A contains the !> upper triangular part of the matrix A. If UPLO = 'L', !> the leading N-by-N lower triangular part of A contains !> the lower triangular part of the matrix A. !> On exit, the lower triangle (if UPLO='L') or the upper !> triangle (if UPLO='U') of A, including the diagonal, is !> destroyed. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	VL	!> VL is REAL !> If RANGE='V', the lower bound of the interval to !> be searched for eigenvalues. VL < VU. !> Not referenced if RANGE = 'A' or 'I'. !>
[in]	VU	!> VU is REAL !> If RANGE='V', the upper bound of the interval to !> be searched for eigenvalues. VL < VU. !> Not referenced if RANGE = 'A' or 'I'. !>
[in]	IL	!> IL is INTEGER !> If RANGE='I', the index of the !> smallest eigenvalue to be returned. !> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0. !> Not referenced if RANGE = 'A' or 'V'. !>
[in]	IU	!> IU is INTEGER !> If RANGE='I', the index of the !> largest eigenvalue to be returned. !> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0. !> Not referenced if RANGE = 'A' or 'V'. !>
[in]	ABSTOL	!> ABSTOL is REAL !> The absolute error tolerance for the eigenvalues. !> An approximate eigenvalue is accepted as converged !> when it is determined to lie in an interval [a,b] !> of width less than or equal to !> !> ABSTOL + EPS * max( |a|,|b| ) , !> !> where EPS is the machine precision. If ABSTOL is less than !> or equal to zero, then EPS*|T| will be used in its place, !> where |T| is the 1-norm of the tridiagonal matrix obtained !> by reducing A to tridiagonal form. !> !> See by Demmel and !> Kahan, LAPACK Working Note #3. !> !> If high relative accuracy is important, set ABSTOL to !> SLAMCH( 'Safe minimum' ). Doing so will guarantee that !> eigenvalues are computed to high relative accuracy when !> possible in future releases. The current code does not !> make any guarantees about high relative accuracy, but !> future releases will. See J. Barlow and J. Demmel, !> , LAPACK Working Note #7, for a discussion !> of which matrices define their eigenvalues to high relative !> accuracy. !>
[out]	M	!> M is INTEGER !> The total number of eigenvalues found. 0 <= M <= N. !> If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1. !>
[out]	W	!> W is REAL array, dimension (N) !> The first M elements contain the selected eigenvalues in !> ascending order. !>
[out]	Z	!> Z is COMPLEX array, dimension (LDZ, max(1,M)) !> If JOBZ = 'V', then if INFO = 0, the first M columns of Z !> contain the orthonormal eigenvectors of the matrix A !> corresponding to the selected eigenvalues, with the i-th !> column of Z holding the eigenvector associated with W(i). !> If JOBZ = 'N', then Z is not referenced. !> Note: the user must ensure that at least max(1,M) columns are !> supplied in the array Z; if RANGE = 'V', the exact value of M !> is not known in advance and an upper bound must be used. !> Supplying N columns is always safe. !>
[in]	LDZ	!> LDZ is INTEGER !> The leading dimension of the array Z. LDZ >= 1, and if !> JOBZ = 'V', LDZ >= max(1,N). !>
[out]	ISUPPZ	!> ISUPPZ is INTEGER array, dimension ( 2*max(1,M) ) !> The support of the eigenvectors in Z, i.e., the indices !> indicating the nonzero elements in Z. The i-th eigenvector !> is nonzero only in elements ISUPPZ( 2*i-1 ) through !> ISUPPZ( 2*i ). This is an output of CSTEMR (tridiagonal !> matrix). The support of the eigenvectors of A is typically !> 1:N because of the unitary transformations applied by CUNMTR. !> Implemented only for RANGE = 'A' or 'I' and IU - IL = N - 1 !>
[out]	WORK	!> WORK is COMPLEX array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The length of the array WORK. !> If N <= 1, LWORK >= 1, else LWORK >= 2*N. !> For optimal efficiency, LWORK >= (NB+1)*N, !> where NB is the max of the blocksize for CHETRD and for !> CUNMTR as returned by ILAENV. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal sizes of the WORK, RWORK and !> IWORK arrays, returns these values as the first entries of !> the WORK, RWORK and IWORK arrays, and no error message !> related to LWORK or LRWORK or LIWORK is issued by XERBLA. !>
[out]	RWORK	!> RWORK is REAL array, dimension (MAX(1,LRWORK)) !> On exit, if INFO = 0, RWORK(1) returns the optimal !> (and minimal) LRWORK. !>
[in]	LRWORK	!> LRWORK is INTEGER !> The length of the array RWORK. !> If N <= 1, LRWORK >= 1, else LRWORK >= 24*N. !> !> If LRWORK = -1, then a workspace query is assumed; the !> routine only calculates the optimal sizes of the WORK, RWORK !> and IWORK arrays, returns these values as the first entries !> of the WORK, RWORK and IWORK arrays, and no error message !> related to LWORK or LRWORK or LIWORK is issued by XERBLA. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (MAX(1,LIWORK)) !> On exit, if INFO = 0, IWORK(1) returns the optimal !> (and minimal) LIWORK. !>
[in]	LIWORK	!> LIWORK is INTEGER !> The dimension of the array IWORK. !> If N <= 1, LIWORK >= 1, else LIWORK >= 10*N. !> !> If LIWORK = -1, then a workspace query is assumed; the !> routine only calculates the optimal sizes of the WORK, RWORK !> and IWORK arrays, returns these values as the first entries !> of the WORK, RWORK and IWORK arrays, and no error message !> related to LWORK or LRWORK or LIWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: Internal error !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Inderjit Dhillon, IBM Almaden, USA
Osni Marques, LBNL/NERSC, USA
Ken Stanley, Computer Science Division, University of California at Berkeley, USA
Jason Riedy, Computer Science Division, University of California at Berkeley, USA

Definition at line 369 of file cheevr.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBZ, RANGE, UPLO
      INTEGER            IL, INFO, IU, LDA, LDZ, LIWORK, LRWORK, LWORK,
     $                   M, N
      REAL               ABSTOL, VL, VU
*     ..
*     .. Array Arguments ..
      INTEGER            ISUPPZ( * ), IWORK( * )
      REAL               RWORK( * ), W( * )
      COMPLEX            A( LDA, * ), WORK( * ), Z( LDZ, * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TWO
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ALLEIG, INDEIG, LOWER, LQUERY, TEST, VALEIG,
     $                   WANTZ, TRYRAC
      CHARACTER          ORDER
      INTEGER            I, IEEEOK, IINFO, IMAX, INDIBL, INDIFL, INDISP,
     $                   INDIWO, INDRD, INDRDD, INDRE, INDREE, INDRWK,
     $                   INDTAU, INDWK, INDWKN, ISCALE, ITMP1, J, JJ,
     $                   LIWMIN, LLWORK, LLRWORK, LLWRKN, LRWMIN,
     $                   LWKOPT, LWMIN, NB, NSPLIT
      REAL               ABSTLL, ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN,
     $                   SIGMA, SMLNUM, TMP1, VLL, VUU
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      REAL               CLANSY, SLAMCH, SROUNDUP_LWORK
      EXTERNAL           lsame, ilaenv, clansy, slamch,
     $                   sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           chetrd, csscal, cstemr, cstein, cswap,
     $                   cunmtr,
     $                   scopy, sscal, sstebz, ssterf, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      ieeeok = ilaenv( 10, 'CHEEVR', 'N', 1, 2, 3, 4 )
*
      lower = lsame( uplo, 'L' )
      wantz = lsame( jobz, 'V' )
      alleig = lsame( range, 'A' )
      valeig = lsame( range, 'V' )
      indeig = lsame( range, 'I' )
*
      lquery = ( ( lwork.EQ.-1 ) .OR. ( lrwork.EQ.-1 ) .OR.
     $         ( liwork.EQ.-1 ) )
*
      IF( n.LE.1 ) THEN
         lwmin  = 1
         lrwmin = 1
         liwmin = 1
      ELSE
         lwmin  = 2*n
         lrwmin = 24*n
         liwmin = 10*n
      END IF
*
      info = 0
      IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
         info = -1
      ELSE IF( .NOT.( alleig .OR. valeig .OR. indeig ) ) THEN
         info = -2
      ELSE IF( .NOT.( lower .OR. lsame( uplo, 'U' ) ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -6
      ELSE
         IF( valeig ) THEN
            IF( n.GT.0 .AND. vu.LE.vl )
     $         info = -8
         ELSE IF( indeig ) THEN
            IF( il.LT.1 .OR. il.GT.max( 1, n ) ) THEN
               info = -9
            ELSE IF( iu.LT.min( n, il ) .OR. iu.GT.n ) THEN
               info = -10
            END IF
         END IF
      END IF
      IF( info.EQ.0 ) THEN
         IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
            info = -15
         END IF
      END IF
*
      IF( info.EQ.0 ) THEN
         nb = ilaenv( 1, 'CHETRD', uplo, n, -1, -1, -1 )
         nb = max( nb, ilaenv( 1, 'CUNMTR', uplo, n, -1, -1, -1 ) )
         lwkopt = max( ( nb+1 )*n, lwmin )
         work( 1 )  = sroundup_lwork( lwkopt )
         rwork( 1 ) = sroundup_lwork( lrwmin )
         iwork( 1 ) = liwmin
*
         IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
            info = -18
         ELSE IF( lrwork.LT.lrwmin .AND. .NOT.lquery ) THEN
            info = -20
         ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
            info = -22
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHEEVR', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      m = 0
      IF( n.EQ.0 ) THEN
         work( 1 ) = 1
         RETURN
      END IF
*
      IF( n.EQ.1 ) THEN
         work( 1 ) = 1
         IF( alleig .OR. indeig ) THEN
            m = 1
            w( 1 ) = real( a( 1, 1 ) )
         ELSE
            IF( vl.LT.real( a( 1, 1 ) ) .AND. vu.GE.real( a( 1, 1 ) ) )
     $           THEN
               m = 1
               w( 1 ) = real( a( 1, 1 ) )
            END IF
         END IF
         IF( wantz ) THEN
            z( 1, 1 ) = one
            isuppz( 1 ) = 1
            isuppz( 2 ) = 1
         END IF
         RETURN
      END IF
*
*     Get machine constants.
*
      safmin = slamch( 'Safe minimum' )
      eps = slamch( 'Precision' )
      smlnum = safmin / eps
      bignum = one / smlnum
      rmin = sqrt( smlnum )
      rmax = min( sqrt( bignum ), one / sqrt( sqrt( safmin ) ) )
*
*     Scale matrix to allowable range, if necessary.
*
      iscale = 0
      abstll = abstol
      IF (valeig) THEN
         vll = vl
         vuu = vu
      END IF
      anrm = clansy( 'M', uplo, n, a, lda, rwork )
      IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
         iscale = 1
         sigma = rmin / anrm
      ELSE IF( anrm.GT.rmax ) THEN
         iscale = 1
         sigma = rmax / anrm
      END IF
      IF( iscale.EQ.1 ) THEN
         IF( lower ) THEN
            DO 10 j = 1, n
               CALL csscal( n-j+1, sigma, a( j, j ), 1 )
   10       CONTINUE
         ELSE
            DO 20 j = 1, n
               CALL csscal( j, sigma, a( 1, j ), 1 )
   20       CONTINUE
         END IF
         IF( abstol.GT.0 )
     $      abstll = abstol*sigma
         IF( valeig ) THEN
            vll = vl*sigma
            vuu = vu*sigma
         END IF
      END IF
 
*     Initialize indices into workspaces.  Note: The IWORK indices are
*     used only if SSTERF or CSTEMR fail.
 
*     WORK(INDTAU:INDTAU+N-1) stores the complex scalar factors of the
*     elementary reflectors used in CHETRD.
      indtau = 1
*     INDWK is the starting offset of the remaining complex workspace,
*     and LLWORK is the remaining complex workspace size.
      indwk = indtau + n
      llwork = lwork - indwk + 1
 
*     RWORK(INDRD:INDRD+N-1) stores the real tridiagonal's diagonal
*     entries.
      indrd = 1
*     RWORK(INDRE:INDRE+N-1) stores the off-diagonal entries of the
*     tridiagonal matrix from CHETRD.
      indre = indrd + n
*     RWORK(INDRDD:INDRDD+N-1) is a copy of the diagonal entries over
*     -written by CSTEMR (the SSTERF path copies the diagonal to W).
      indrdd = indre + n
*     RWORK(INDREE:INDREE+N-1) is a copy of the off-diagonal entries over
*     -written while computing the eigenvalues in SSTERF and CSTEMR.
      indree = indrdd + n
*     INDRWK is the starting offset of the left-over real workspace, and
*     LLRWORK is the remaining workspace size.
      indrwk = indree + n
      llrwork = lrwork - indrwk + 1
 
*     IWORK(INDIBL:INDIBL+M-1) corresponds to IBLOCK in SSTEBZ and
*     stores the block indices of each of the M<=N eigenvalues.
      indibl = 1
*     IWORK(INDISP:INDISP+NSPLIT-1) corresponds to ISPLIT in SSTEBZ and
*     stores the starting and finishing indices of each block.
      indisp = indibl + n
*     IWORK(INDIFL:INDIFL+N-1) stores the indices of eigenvectors
*     that corresponding to eigenvectors that fail to converge in
*     SSTEIN.  This information is discarded; if any fail, the driver
*     returns INFO > 0.
      indifl = indisp + n
*     INDIWO is the offset of the remaining integer workspace.
      indiwo = indifl + n
 
*
*     Call CHETRD to reduce Hermitian matrix to tridiagonal form.
*
      CALL chetrd( uplo, n, a, lda, rwork( indrd ), rwork( indre ),
     $             work( indtau ), work( indwk ), llwork, iinfo )
*
*     If all eigenvalues are desired
*     then call SSTERF or CSTEMR and CUNMTR.
*
      test = .false.
      IF( indeig ) THEN
         IF( il.EQ.1 .AND. iu.EQ.n ) THEN
            test = .true.
         END IF
      END IF
      IF( ( alleig.OR.test ) .AND. ( ieeeok.EQ.1 ) ) THEN
         IF( .NOT.wantz ) THEN
            CALL scopy( n, rwork( indrd ), 1, w, 1 )
            CALL scopy( n-1, rwork( indre ), 1, rwork( indree ), 1 )
            CALL ssterf( n, w, rwork( indree ), info )
         ELSE
            CALL scopy( n-1, rwork( indre ), 1, rwork( indree ), 1 )
            CALL scopy( n, rwork( indrd ), 1, rwork( indrdd ), 1 )
*
            IF (abstol .LE. two*real( n )*eps) THEN
               tryrac = .true.
            ELSE
               tryrac = .false.
            END IF
            CALL cstemr( jobz, 'A', n, rwork( indrdd ),
     $                   rwork( indree ), vl, vu, il, iu, m, w,
     $                   z, ldz, n, isuppz, tryrac,
     $                   rwork( indrwk ), llrwork,
     $                   iwork, liwork, info )
*
*           Apply unitary matrix used in reduction to tridiagonal
*           form to eigenvectors returned by CSTEMR.
*
            IF( wantz .AND. info.EQ.0 ) THEN
               indwkn = indwk
               llwrkn = lwork - indwkn + 1
               CALL cunmtr( 'L', uplo, 'N', n, m, a, lda,
     $                      work( indtau ), z, ldz, work( indwkn ),
     $                      llwrkn, iinfo )
            END IF
         END IF
*
*
         IF( info.EQ.0 ) THEN
            m = n
            GO TO 30
         END IF
         info = 0
      END IF
*
*     Otherwise, call SSTEBZ and, if eigenvectors are desired, CSTEIN.
*     Also call SSTEBZ and CSTEIN if CSTEMR fails.
*
      IF( wantz ) THEN
         order = 'B'
      ELSE
         order = 'E'
      END IF
 
      CALL sstebz( range, order, n, vll, vuu, il, iu, abstll,
     $             rwork( indrd ), rwork( indre ), m, nsplit, w,
     $             iwork( indibl ), iwork( indisp ), rwork( indrwk ),
     $             iwork( indiwo ), info )
*
      IF( wantz ) THEN
         CALL cstein( n, rwork( indrd ), rwork( indre ), m, w,
     $                iwork( indibl ), iwork( indisp ), z, ldz,
     $                rwork( indrwk ), iwork( indiwo ), iwork( indifl ),
     $                info )
*
*        Apply unitary matrix used in reduction to tridiagonal
*        form to eigenvectors returned by CSTEIN.
*
         indwkn = indwk
         llwrkn = lwork - indwkn + 1
         CALL cunmtr( 'L', uplo, 'N', n, m, a, lda, work( indtau ),
     $                z,
     $                ldz, work( indwkn ), llwrkn, iinfo )
      END IF
*
*     If matrix was scaled, then rescale eigenvalues appropriately.
*
   30 CONTINUE
      IF( iscale.EQ.1 ) THEN
         IF( info.EQ.0 ) THEN
            imax = m
         ELSE
            imax = info - 1
         END IF
         CALL sscal( imax, one / sigma, w, 1 )
      END IF
*
*     If eigenvalues are not in order, then sort them, along with
*     eigenvectors.
*
      IF( wantz ) THEN
         DO 50 j = 1, m - 1
            i = 0
            tmp1 = w( j )
            DO 40 jj = j + 1, m
               IF( w( jj ).LT.tmp1 ) THEN
                  i = jj
                  tmp1 = w( jj )
               END IF
   40       CONTINUE
*
            IF( i.NE.0 ) THEN
               itmp1 = iwork( indibl+i-1 )
               w( i ) = w( j )
               iwork( indibl+i-1 ) = iwork( indibl+j-1 )
               w( j ) = tmp1
               iwork( indibl+j-1 ) = itmp1
               CALL cswap( n, z( 1, i ), 1, z( 1, j ), 1 )
            END IF
   50    CONTINUE
      END IF
*
*     Set WORK(1) to optimal workspace size.
*
      work( 1 )  = sroundup_lwork( lwkopt )
      rwork( 1 ) = sroundup_lwork( lrwmin )
      iwork( 1 ) = liwmin
*
      RETURN
*
*     End of CHEEVR
*

Here is the call graph for this function:

Here is the caller graph for this function: