chegv()

subroutine chegv	(	integer	itype,
		character	jobz,
		character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( * )	w,
		complex, dimension( * )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		integer	info )

CHEGV

Download CHEGV + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CHEGV computes all the eigenvalues, and optionally, the eigenvectors
!> of a complex generalized Hermitian-definite eigenproblem, of the form
!> A*x=(lambda)*B*x,  A*Bx=(lambda)*x,  or B*A*x=(lambda)*x.
!> Here A and B are assumed to be Hermitian and B is also
!> positive definite.
!> 

Parameters

[in]	ITYPE	!> ITYPE is INTEGER !> Specifies the problem type to be solved: !> = 1: A*x = (lambda)*B*x !> = 2: A*B*x = (lambda)*x !> = 3: B*A*x = (lambda)*x !>
[in]	JOBZ	!> JOBZ is CHARACTER*1 !> = 'N': Compute eigenvalues only; !> = 'V': Compute eigenvalues and eigenvectors. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangles of A and B are stored; !> = 'L': Lower triangles of A and B are stored. !>
[in]	N	!> N is INTEGER !> The order of the matrices A and B. N >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA, N) !> On entry, the Hermitian matrix A. If UPLO = 'U', the !> leading N-by-N upper triangular part of A contains the !> upper triangular part of the matrix A. If UPLO = 'L', !> the leading N-by-N lower triangular part of A contains !> the lower triangular part of the matrix A. !> !> On exit, if JOBZ = 'V', then if INFO = 0, A contains the !> matrix Z of eigenvectors. The eigenvectors are normalized !> as follows: !> if ITYPE = 1 or 2, Z**H*B*Z = I; !> if ITYPE = 3, Z**H*inv(B)*Z = I. !> If JOBZ = 'N', then on exit the upper triangle (if UPLO='U') !> or the lower triangle (if UPLO='L') of A, including the !> diagonal, is destroyed. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in,out]	B	!> B is COMPLEX array, dimension (LDB, N) !> On entry, the Hermitian positive definite matrix B. !> If UPLO = 'U', the leading N-by-N upper triangular part of B !> contains the upper triangular part of the matrix B. !> If UPLO = 'L', the leading N-by-N lower triangular part of B !> contains the lower triangular part of the matrix B. !> !> On exit, if INFO <= N, the part of B containing the matrix is !> overwritten by the triangular factor U or L from the Cholesky !> factorization B = U**H*U or B = L*L**H. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	W	!> W is REAL array, dimension (N) !> If INFO = 0, the eigenvalues in ascending order. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The length of the array WORK. LWORK >= max(1,2*N-1). !> For optimal efficiency, LWORK >= (NB+1)*N, !> where NB is the blocksize for CHETRD returned by ILAENV. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	RWORK	!> RWORK is REAL array, dimension (max(1, 3*N-2)) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: CPOTRF or CHEEV returned an error code: !> <= N: if INFO = i, CHEEV failed to converge; !> i off-diagonal elements of an intermediate !> tridiagonal form did not converge to zero; !> > N: if INFO = N + i, for 1 <= i <= N, then the leading !> principal minor of order i of B is not positive. !> The factorization of B could not be completed and !> no eigenvalues or eigenvectors were computed. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 177 of file chegv.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBZ, UPLO
      INTEGER            INFO, ITYPE, LDA, LDB, LWORK, N
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * ), W( * )
      COMPLEX            A( LDA, * ), B( LDB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE
      parameter( one = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, UPPER, WANTZ
      CHARACTER          TRANS
      INTEGER            LWKOPT, NB, NEIG
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      REAL               SROUNDUP_LWORK
      EXTERNAL           ilaenv, lsame, sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           cheev, chegst, cpotrf, ctrmm, ctrsm,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      wantz = lsame( jobz, 'V' )
      upper = lsame( uplo, 'U' )
      lquery = ( lwork.EQ. -1 )
*
      info = 0
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
         info = -2
      ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -6
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      END IF
*
      IF( info.EQ.0 ) THEN
         nb = ilaenv( 1, 'CHETRD', uplo, n, -1, -1, -1 )
         lwkopt = max( 1, ( nb + 1 )*n )
         work( 1 ) = sroundup_lwork(lwkopt)
*
         IF( lwork.LT.max( 1, 2*n-1 ) .AND. .NOT.lquery ) THEN
            info = -11
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHEGV ', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Form a Cholesky factorization of B.
*
      CALL cpotrf( uplo, n, b, ldb, info )
      IF( info.NE.0 ) THEN
         info = n + info
         RETURN
      END IF
*
*     Transform problem to standard eigenvalue problem and solve.
*
      CALL chegst( itype, uplo, n, a, lda, b, ldb, info )
      CALL cheev( jobz, uplo, n, a, lda, w, work, lwork, rwork,
     $            info )
*
      IF( wantz ) THEN
*
*        Backtransform eigenvectors to the original problem.
*
         neig = n
         IF( info.GT.0 )
     $      neig = info - 1
         IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
*
*           For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
*           backtransform eigenvectors: x = inv(L)**H*y or inv(U)*y
*
            IF( upper ) THEN
               trans = 'N'
            ELSE
               trans = 'C'
            END IF
*
            CALL ctrsm( 'Left', uplo, trans, 'Non-unit', n, neig,
     $                  one,
     $                  b, ldb, a, lda )
*
         ELSE IF( itype.EQ.3 ) THEN
*
*           For B*A*x=(lambda)*x;
*           backtransform eigenvectors: x = L*y or U**H*y
*
            IF( upper ) THEN
               trans = 'C'
            ELSE
               trans = 'N'
            END IF
*
            CALL ctrmm( 'Left', uplo, trans, 'Non-unit', n, neig,
     $                  one,
     $                  b, ldb, a, lda )
         END IF
      END IF
*
      work( 1 ) = sroundup_lwork(lwkopt)
*
      RETURN
*
*     End of CHEGV
*

Here is the call graph for this function:

Here is the caller graph for this function: