LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
chegst.f
Go to the documentation of this file.
1 *> \brief \b CHEGST
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CHEGST + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/chegst.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/chegst.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/chegst.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CHEGST( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER UPLO
25 * INTEGER INFO, ITYPE, LDA, LDB, N
26 * ..
27 * .. Array Arguments ..
28 * COMPLEX A( LDA, * ), B( LDB, * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> CHEGST reduces a complex Hermitian-definite generalized
38 *> eigenproblem to standard form.
39 *>
40 *> If ITYPE = 1, the problem is A*x = lambda*B*x,
41 *> and A is overwritten by inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H)
42 *>
43 *> If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
44 *> B*A*x = lambda*x, and A is overwritten by U*A*U**H or L**H*A*L.
45 *>
46 *> B must have been previously factorized as U**H*U or L*L**H by CPOTRF.
47 *> \endverbatim
48 *
49 * Arguments:
50 * ==========
51 *
52 *> \param[in] ITYPE
53 *> \verbatim
54 *> ITYPE is INTEGER
55 *> = 1: compute inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H);
56 *> = 2 or 3: compute U*A*U**H or L**H*A*L.
57 *> \endverbatim
58 *>
59 *> \param[in] UPLO
60 *> \verbatim
61 *> UPLO is CHARACTER*1
62 *> = 'U': Upper triangle of A is stored and B is factored as
63 *> U**H*U;
64 *> = 'L': Lower triangle of A is stored and B is factored as
65 *> L*L**H.
66 *> \endverbatim
67 *>
68 *> \param[in] N
69 *> \verbatim
70 *> N is INTEGER
71 *> The order of the matrices A and B. N >= 0.
72 *> \endverbatim
73 *>
74 *> \param[in,out] A
75 *> \verbatim
76 *> A is COMPLEX array, dimension (LDA,N)
77 *> On entry, the Hermitian matrix A. If UPLO = 'U', the leading
78 *> N-by-N upper triangular part of A contains the upper
79 *> triangular part of the matrix A, and the strictly lower
80 *> triangular part of A is not referenced. If UPLO = 'L', the
81 *> leading N-by-N lower triangular part of A contains the lower
82 *> triangular part of the matrix A, and the strictly upper
83 *> triangular part of A is not referenced.
84 *>
85 *> On exit, if INFO = 0, the transformed matrix, stored in the
86 *> same format as A.
87 *> \endverbatim
88 *>
89 *> \param[in] LDA
90 *> \verbatim
91 *> LDA is INTEGER
92 *> The leading dimension of the array A. LDA >= max(1,N).
93 *> \endverbatim
94 *>
95 *> \param[in,out] B
96 *> \verbatim
97 *> B is COMPLEX array, dimension (LDB,N)
98 *> The triangular factor from the Cholesky factorization of B,
99 *> as returned by CPOTRF.
100 *> B is modified by the routine but restored on exit.
101 *> \endverbatim
102 *>
103 *> \param[in] LDB
104 *> \verbatim
105 *> LDB is INTEGER
106 *> The leading dimension of the array B. LDB >= max(1,N).
107 *> \endverbatim
108 *>
109 *> \param[out] INFO
110 *> \verbatim
111 *> INFO is INTEGER
112 *> = 0: successful exit
113 *> < 0: if INFO = -i, the i-th argument had an illegal value
114 *> \endverbatim
115 *
116 * Authors:
117 * ========
118 *
119 *> \author Univ. of Tennessee
120 *> \author Univ. of California Berkeley
121 *> \author Univ. of Colorado Denver
122 *> \author NAG Ltd.
123 *
124 *> \ingroup complexHEcomputational
125 *
126 * =====================================================================
127  SUBROUTINE chegst( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
128 *
129 * -- LAPACK computational routine --
130 * -- LAPACK is a software package provided by Univ. of Tennessee, --
131 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
132 *
133 * .. Scalar Arguments ..
134  CHARACTER UPLO
135  INTEGER INFO, ITYPE, LDA, LDB, N
136 * ..
137 * .. Array Arguments ..
138  COMPLEX A( LDA, * ), B( LDB, * )
139 * ..
140 *
141 * =====================================================================
142 *
143 * .. Parameters ..
144  REAL ONE
145  parameter( one = 1.0e+0 )
146  COMPLEX CONE, HALF
147  parameter( cone = ( 1.0e+0, 0.0e+0 ),
148  $ half = ( 0.5e+0, 0.0e+0 ) )
149 * ..
150 * .. Local Scalars ..
151  LOGICAL UPPER
152  INTEGER K, KB, NB
153 * ..
154 * .. External Subroutines ..
155  EXTERNAL chegs2, chemm, cher2k, ctrmm, ctrsm, xerbla
156 * ..
157 * .. Intrinsic Functions ..
158  INTRINSIC max, min
159 * ..
160 * .. External Functions ..
161  LOGICAL LSAME
162  INTEGER ILAENV
163  EXTERNAL lsame, ilaenv
164 * ..
165 * .. Executable Statements ..
166 *
167 * Test the input parameters.
168 *
169  info = 0
170  upper = lsame( uplo, 'U' )
171  IF( itype.LT.1 .OR. itype.GT.3 ) THEN
172  info = -1
173  ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
174  info = -2
175  ELSE IF( n.LT.0 ) THEN
176  info = -3
177  ELSE IF( lda.LT.max( 1, n ) ) THEN
178  info = -5
179  ELSE IF( ldb.LT.max( 1, n ) ) THEN
180  info = -7
181  END IF
182  IF( info.NE.0 ) THEN
183  CALL xerbla( 'CHEGST', -info )
184  RETURN
185  END IF
186 *
187 * Quick return if possible
188 *
189  IF( n.EQ.0 )
190  $ RETURN
191 *
192 * Determine the block size for this environment.
193 *
194  nb = ilaenv( 1, 'CHEGST', uplo, n, -1, -1, -1 )
195 *
196  IF( nb.LE.1 .OR. nb.GE.n ) THEN
197 *
198 * Use unblocked code
199 *
200  CALL chegs2( itype, uplo, n, a, lda, b, ldb, info )
201  ELSE
202 *
203 * Use blocked code
204 *
205  IF( itype.EQ.1 ) THEN
206  IF( upper ) THEN
207 *
208 * Compute inv(U**H)*A*inv(U)
209 *
210  DO 10 k = 1, n, nb
211  kb = min( n-k+1, nb )
212 *
213 * Update the upper triangle of A(k:n,k:n)
214 *
215  CALL chegs2( itype, uplo, kb, a( k, k ), lda,
216  $ b( k, k ), ldb, info )
217  IF( k+kb.LE.n ) THEN
218  CALL ctrsm( 'Left', uplo, 'Conjugate transpose',
219  $ 'Non-unit', kb, n-k-kb+1, cone,
220  $ b( k, k ), ldb, a( k, k+kb ), lda )
221  CALL chemm( 'Left', uplo, kb, n-k-kb+1, -half,
222  $ a( k, k ), lda, b( k, k+kb ), ldb,
223  $ cone, a( k, k+kb ), lda )
224  CALL cher2k( uplo, 'Conjugate transpose', n-k-kb+1,
225  $ kb, -cone, a( k, k+kb ), lda,
226  $ b( k, k+kb ), ldb, one,
227  $ a( k+kb, k+kb ), lda )
228  CALL chemm( 'Left', uplo, kb, n-k-kb+1, -half,
229  $ a( k, k ), lda, b( k, k+kb ), ldb,
230  $ cone, a( k, k+kb ), lda )
231  CALL ctrsm( 'Right', uplo, 'No transpose',
232  $ 'Non-unit', kb, n-k-kb+1, cone,
233  $ b( k+kb, k+kb ), ldb, a( k, k+kb ),
234  $ lda )
235  END IF
236  10 CONTINUE
237  ELSE
238 *
239 * Compute inv(L)*A*inv(L**H)
240 *
241  DO 20 k = 1, n, nb
242  kb = min( n-k+1, nb )
243 *
244 * Update the lower triangle of A(k:n,k:n)
245 *
246  CALL chegs2( itype, uplo, kb, a( k, k ), lda,
247  $ b( k, k ), ldb, info )
248  IF( k+kb.LE.n ) THEN
249  CALL ctrsm( 'Right', uplo, 'Conjugate transpose',
250  $ 'Non-unit', n-k-kb+1, kb, cone,
251  $ b( k, k ), ldb, a( k+kb, k ), lda )
252  CALL chemm( 'Right', uplo, n-k-kb+1, kb, -half,
253  $ a( k, k ), lda, b( k+kb, k ), ldb,
254  $ cone, a( k+kb, k ), lda )
255  CALL cher2k( uplo, 'No transpose', n-k-kb+1, kb,
256  $ -cone, a( k+kb, k ), lda,
257  $ b( k+kb, k ), ldb, one,
258  $ a( k+kb, k+kb ), lda )
259  CALL chemm( 'Right', uplo, n-k-kb+1, kb, -half,
260  $ a( k, k ), lda, b( k+kb, k ), ldb,
261  $ cone, a( k+kb, k ), lda )
262  CALL ctrsm( 'Left', uplo, 'No transpose',
263  $ 'Non-unit', n-k-kb+1, kb, cone,
264  $ b( k+kb, k+kb ), ldb, a( k+kb, k ),
265  $ lda )
266  END IF
267  20 CONTINUE
268  END IF
269  ELSE
270  IF( upper ) THEN
271 *
272 * Compute U*A*U**H
273 *
274  DO 30 k = 1, n, nb
275  kb = min( n-k+1, nb )
276 *
277 * Update the upper triangle of A(1:k+kb-1,1:k+kb-1)
278 *
279  CALL ctrmm( 'Left', uplo, 'No transpose', 'Non-unit',
280  $ k-1, kb, cone, b, ldb, a( 1, k ), lda )
281  CALL chemm( 'Right', uplo, k-1, kb, half, a( k, k ),
282  $ lda, b( 1, k ), ldb, cone, a( 1, k ),
283  $ lda )
284  CALL cher2k( uplo, 'No transpose', k-1, kb, cone,
285  $ a( 1, k ), lda, b( 1, k ), ldb, one, a,
286  $ lda )
287  CALL chemm( 'Right', uplo, k-1, kb, half, a( k, k ),
288  $ lda, b( 1, k ), ldb, cone, a( 1, k ),
289  $ lda )
290  CALL ctrmm( 'Right', uplo, 'Conjugate transpose',
291  $ 'Non-unit', k-1, kb, cone, b( k, k ), ldb,
292  $ a( 1, k ), lda )
293  CALL chegs2( itype, uplo, kb, a( k, k ), lda,
294  $ b( k, k ), ldb, info )
295  30 CONTINUE
296  ELSE
297 *
298 * Compute L**H*A*L
299 *
300  DO 40 k = 1, n, nb
301  kb = min( n-k+1, nb )
302 *
303 * Update the lower triangle of A(1:k+kb-1,1:k+kb-1)
304 *
305  CALL ctrmm( 'Right', uplo, 'No transpose', 'Non-unit',
306  $ kb, k-1, cone, b, ldb, a( k, 1 ), lda )
307  CALL chemm( 'Left', uplo, kb, k-1, half, a( k, k ),
308  $ lda, b( k, 1 ), ldb, cone, a( k, 1 ),
309  $ lda )
310  CALL cher2k( uplo, 'Conjugate transpose', k-1, kb,
311  $ cone, a( k, 1 ), lda, b( k, 1 ), ldb,
312  $ one, a, lda )
313  CALL chemm( 'Left', uplo, kb, k-1, half, a( k, k ),
314  $ lda, b( k, 1 ), ldb, cone, a( k, 1 ),
315  $ lda )
316  CALL ctrmm( 'Left', uplo, 'Conjugate transpose',
317  $ 'Non-unit', kb, k-1, cone, b( k, k ), ldb,
318  $ a( k, 1 ), lda )
319  CALL chegs2( itype, uplo, kb, a( k, k ), lda,
320  $ b( k, k ), ldb, info )
321  40 CONTINUE
322  END IF
323  END IF
324  END IF
325  RETURN
326 *
327 * End of CHEGST
328 *
329  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine chemm(SIDE, UPLO, M, N, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
CHEMM
Definition: chemm.f:191
subroutine ctrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
CTRMM
Definition: ctrmm.f:177
subroutine ctrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
CTRSM
Definition: ctrsm.f:180
subroutine cher2k(UPLO, TRANS, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
CHER2K
Definition: cher2k.f:197
subroutine chegst(ITYPE, UPLO, N, A, LDA, B, LDB, INFO)
CHEGST
Definition: chegst.f:128
subroutine chegs2(ITYPE, UPLO, N, A, LDA, B, LDB, INFO)
CHEGS2 reduces a Hermitian definite generalized eigenproblem to standard form, using the factorizatio...
Definition: chegs2.f:128