LAPACK  3.10.0
LAPACK: Linear Algebra PACKage
ctbcon.f
Go to the documentation of this file.
1 *> \brief \b CTBCON
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CTBCON + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ctbcon.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ctbcon.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ctbcon.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CTBCON( NORM, UPLO, DIAG, N, KD, AB, LDAB, RCOND, WORK,
22 * RWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER DIAG, NORM, UPLO
26 * INTEGER INFO, KD, LDAB, N
27 * REAL RCOND
28 * ..
29 * .. Array Arguments ..
30 * REAL RWORK( * )
31 * COMPLEX AB( LDAB, * ), WORK( * )
32 * ..
33 *
34 *
35 *> \par Purpose:
36 * =============
37 *>
38 *> \verbatim
39 *>
40 *> CTBCON estimates the reciprocal of the condition number of a
41 *> triangular band matrix A, in either the 1-norm or the infinity-norm.
42 *>
43 *> The norm of A is computed and an estimate is obtained for
44 *> norm(inv(A)), then the reciprocal of the condition number is
45 *> computed as
46 *> RCOND = 1 / ( norm(A) * norm(inv(A)) ).
47 *> \endverbatim
48 *
49 * Arguments:
50 * ==========
51 *
52 *> \param[in] NORM
53 *> \verbatim
54 *> NORM is CHARACTER*1
55 *> Specifies whether the 1-norm condition number or the
56 *> infinity-norm condition number is required:
57 *> = '1' or 'O': 1-norm;
58 *> = 'I': Infinity-norm.
59 *> \endverbatim
60 *>
61 *> \param[in] UPLO
62 *> \verbatim
63 *> UPLO is CHARACTER*1
64 *> = 'U': A is upper triangular;
65 *> = 'L': A is lower triangular.
66 *> \endverbatim
67 *>
68 *> \param[in] DIAG
69 *> \verbatim
70 *> DIAG is CHARACTER*1
71 *> = 'N': A is non-unit triangular;
72 *> = 'U': A is unit triangular.
73 *> \endverbatim
74 *>
75 *> \param[in] N
76 *> \verbatim
77 *> N is INTEGER
78 *> The order of the matrix A. N >= 0.
79 *> \endverbatim
80 *>
81 *> \param[in] KD
82 *> \verbatim
83 *> KD is INTEGER
84 *> The number of superdiagonals or subdiagonals of the
85 *> triangular band matrix A. KD >= 0.
86 *> \endverbatim
87 *>
88 *> \param[in] AB
89 *> \verbatim
90 *> AB is COMPLEX array, dimension (LDAB,N)
91 *> The upper or lower triangular band matrix A, stored in the
92 *> first kd+1 rows of the array. The j-th column of A is stored
93 *> in the j-th column of the array AB as follows:
94 *> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
95 *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd).
96 *> If DIAG = 'U', the diagonal elements of A are not referenced
97 *> and are assumed to be 1.
98 *> \endverbatim
99 *>
100 *> \param[in] LDAB
101 *> \verbatim
102 *> LDAB is INTEGER
103 *> The leading dimension of the array AB. LDAB >= KD+1.
104 *> \endverbatim
105 *>
106 *> \param[out] RCOND
107 *> \verbatim
108 *> RCOND is REAL
109 *> The reciprocal of the condition number of the matrix A,
110 *> computed as RCOND = 1/(norm(A) * norm(inv(A))).
111 *> \endverbatim
112 *>
113 *> \param[out] WORK
114 *> \verbatim
115 *> WORK is COMPLEX array, dimension (2*N)
116 *> \endverbatim
117 *>
118 *> \param[out] RWORK
119 *> \verbatim
120 *> RWORK is REAL array, dimension (N)
121 *> \endverbatim
122 *>
123 *> \param[out] INFO
124 *> \verbatim
125 *> INFO is INTEGER
126 *> = 0: successful exit
127 *> < 0: if INFO = -i, the i-th argument had an illegal value
128 *> \endverbatim
129 *
130 * Authors:
131 * ========
132 *
133 *> \author Univ. of Tennessee
134 *> \author Univ. of California Berkeley
135 *> \author Univ. of Colorado Denver
136 *> \author NAG Ltd.
137 *
138 *> \ingroup complexOTHERcomputational
139 *
140 * =====================================================================
141  SUBROUTINE ctbcon( NORM, UPLO, DIAG, N, KD, AB, LDAB, RCOND, WORK,
142  $ RWORK, INFO )
143 *
144 * -- LAPACK computational routine --
145 * -- LAPACK is a software package provided by Univ. of Tennessee, --
146 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
147 *
148 * .. Scalar Arguments ..
149  CHARACTER DIAG, NORM, UPLO
150  INTEGER INFO, KD, LDAB, N
151  REAL RCOND
152 * ..
153 * .. Array Arguments ..
154  REAL RWORK( * )
155  COMPLEX AB( LDAB, * ), WORK( * )
156 * ..
157 *
158 * =====================================================================
159 *
160 * .. Parameters ..
161  REAL ONE, ZERO
162  parameter( one = 1.0e+0, zero = 0.0e+0 )
163 * ..
164 * .. Local Scalars ..
165  LOGICAL NOUNIT, ONENRM, UPPER
166  CHARACTER NORMIN
167  INTEGER IX, KASE, KASE1
168  REAL AINVNM, ANORM, SCALE, SMLNUM, XNORM
169  COMPLEX ZDUM
170 * ..
171 * .. Local Arrays ..
172  INTEGER ISAVE( 3 )
173 * ..
174 * .. External Functions ..
175  LOGICAL LSAME
176  INTEGER ICAMAX
177  REAL CLANTB, SLAMCH
178  EXTERNAL lsame, icamax, clantb, slamch
179 * ..
180 * .. External Subroutines ..
181  EXTERNAL clacn2, clatbs, csrscl, xerbla
182 * ..
183 * .. Intrinsic Functions ..
184  INTRINSIC abs, aimag, max, real
185 * ..
186 * .. Statement Functions ..
187  REAL CABS1
188 * ..
189 * .. Statement Function definitions ..
190  cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
191 * ..
192 * .. Executable Statements ..
193 *
194 * Test the input parameters.
195 *
196  info = 0
197  upper = lsame( uplo, 'U' )
198  onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
199  nounit = lsame( diag, 'N' )
200 *
201  IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
202  info = -1
203  ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
204  info = -2
205  ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
206  info = -3
207  ELSE IF( n.LT.0 ) THEN
208  info = -4
209  ELSE IF( kd.LT.0 ) THEN
210  info = -5
211  ELSE IF( ldab.LT.kd+1 ) THEN
212  info = -7
213  END IF
214  IF( info.NE.0 ) THEN
215  CALL xerbla( 'CTBCON', -info )
216  RETURN
217  END IF
218 *
219 * Quick return if possible
220 *
221  IF( n.EQ.0 ) THEN
222  rcond = one
223  RETURN
224  END IF
225 *
226  rcond = zero
227  smlnum = slamch( 'Safe minimum' )*real( max( n, 1 ) )
228 *
229 * Compute the 1-norm of the triangular matrix A or A**H.
230 *
231  anorm = clantb( norm, uplo, diag, n, kd, ab, ldab, rwork )
232 *
233 * Continue only if ANORM > 0.
234 *
235  IF( anorm.GT.zero ) THEN
236 *
237 * Estimate the 1-norm of the inverse of A.
238 *
239  ainvnm = zero
240  normin = 'N'
241  IF( onenrm ) THEN
242  kase1 = 1
243  ELSE
244  kase1 = 2
245  END IF
246  kase = 0
247  10 CONTINUE
248  CALL clacn2( n, work( n+1 ), work, ainvnm, kase, isave )
249  IF( kase.NE.0 ) THEN
250  IF( kase.EQ.kase1 ) THEN
251 *
252 * Multiply by inv(A).
253 *
254  CALL clatbs( uplo, 'No transpose', diag, normin, n, kd,
255  $ ab, ldab, work, scale, rwork, info )
256  ELSE
257 *
258 * Multiply by inv(A**H).
259 *
260  CALL clatbs( uplo, 'Conjugate transpose', diag, normin,
261  $ n, kd, ab, ldab, work, scale, rwork, info )
262  END IF
263  normin = 'Y'
264 *
265 * Multiply by 1/SCALE if doing so will not cause overflow.
266 *
267  IF( scale.NE.one ) THEN
268  ix = icamax( n, work, 1 )
269  xnorm = cabs1( work( ix ) )
270  IF( scale.LT.xnorm*smlnum .OR. scale.EQ.zero )
271  $ GO TO 20
272  CALL csrscl( n, scale, work, 1 )
273  END IF
274  GO TO 10
275  END IF
276 *
277 * Compute the estimate of the reciprocal condition number.
278 *
279  IF( ainvnm.NE.zero )
280  $ rcond = ( one / anorm ) / ainvnm
281  END IF
282 *
283  20 CONTINUE
284  RETURN
285 *
286 * End of CTBCON
287 *
288  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine csrscl(N, SA, SX, INCX)
CSRSCL multiplies a vector by the reciprocal of a real scalar.
Definition: csrscl.f:84
subroutine clatbs(UPLO, TRANS, DIAG, NORMIN, N, KD, AB, LDAB, X, SCALE, CNORM, INFO)
CLATBS solves a triangular banded system of equations.
Definition: clatbs.f:243
subroutine clacn2(N, V, X, EST, KASE, ISAVE)
CLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: clacn2.f:133
subroutine ctbcon(NORM, UPLO, DIAG, N, KD, AB, LDAB, RCOND, WORK, RWORK, INFO)
CTBCON
Definition: ctbcon.f:143